Arduinoで実数型を文字列に変更したいがシリアルモニタで表示すると文字化けしてしまう。

Question

いつもお世話になっております。
体温センサ(ADT7410)から取得した値(float型)をsprintfで文字列に変換してシリアルモニタに表示したいのですが文字化けして?になってしまいます。

脈拍センサも同時に測定しているためコードが見づらくなってしまい申し訳ありませんmm

#include <Wire.h>                 //I2C通信のライブラリ  
 
int adt7410I2CAddress = 0x48;     //温度センサのアドレス
int SensorOutPin = 0; // パルスセンサー出力をアナログピンの0番指定
int Signal;           // analogReadで読み取る値の格納変数
char buff[24];
 
void setup(void) {               // 初期化
  Serial.begin(9600);            //シリアル通信開始
  Wire.begin();                  //I2C通信開始
}
 
void loop(void) {
  uint16_t uiVal; //2バイト(16ビット)の領域
  float fVal;
  int iVal;
 
  Wire.requestFrom(adt7410I2CAddress, 2);   //2バイト要求
 
  uiVal = (uint8_t)Wire.read() << 8;   // 1バイト読み出しで上位にシフト
  uiVal |= Wire.read();                 // 1バイト読み出して下位にセット
 
  uiVal >>= 3;                          // シフトで13bit化
 
  if (uiVal & 0x1000) {                // 13ビットで符号判定
    iVal = uiVal - 0x2000;             // マイナスの時 (10進数で8192)
  }
  else {
    iVal = uiVal;                      //プラスの時
  }

  Signal = analogRead(SensorOutPin); // パルスセンサの値を読み込み
 
  fVal = (double)iVal / 16.0;           // 温度換算(摂氏)
  
  sprintf(buff,"%f,%d",fVal,Signal); //sprintfで文字列に変換、二つの変数を結合
  Serial.println(buff);
  delay(1000);                         //1秒待つ
}

Arduinoのシリアルモニタ(左側が体温、右側が脈拍の値となります)

?,536
?,508
?,512
?,502
?,522
?,510
?,519
?,491

実行環境

Arduino IDE 1.8.15
Arduino UNO
体温センサ ADT7410

試したこと

そのままfloat型で表示した場合はちゃんとした値が表示されています。
心拍と脈拍の値を同時にSerial.printlnで出力したい為、sprintfで文字列にして結合させようと考えております。

Comments

[itagagaki]

「そのままfloat型で表示した場合」とは具体的にどういうコードでどういう操作をしたのですか？

Answer 1

Arduino UNOというか、avr-libcのsprintf()は、浮動小数点数を扱えません。

そのかわり、dtostf()という関数が用意されています。sprintf()とは異なり、複数の変数を同時に扱うことはできませんが。

Comments

[cyoncooo]

丁寧なご対応ありがとうございます。勉強になります。

Answer 2

printfとかscanfを自分で実装してみよう、と考えてみるとわかると思いますが、
これらを実装しようとするとかなり膨大なコード量となります
ということで、ワンチップCPUとか組み込み系のたぐいの環境では、

• printf,scanfなどのフォーマット系
• ファイル操作系
• malloc,freeなどのメモリ操作系

の関数は使えない、と思っておいたほうがよろしいかと思います

Comments

[thkana]

> これらを実装しようとするとかなり膨大なコード量となります
ということではなくて、マイコンでは入出力デバイスが規定されていないあたりの事情でしょう。
最近(といってもここ10年来)では、putc() / getc()のような1文字入出力を用意してやればprintf/scanfを使えるようになっているライブラリが多いと思います。

Heap領域をとらないのはまた別の話ですが。

[y_waiwai]

まあ、イマドキはワンチップといえども大容量なものがでてきてるんで、もちろん例外はありますね

ましかし、ArduinoUnoのCPUでは、このRAM容量を考えると、フルスペックのprintfの実装は非現実的かと思います

[thkana]

思うのは勝手ですが、少なくともArduino UNO(gcc)ではprintfは実装されています。

[y_waiwai]

うん、しかし、使えない、と思っていたほうがいい、ってのはそういうことですねー

[thkana]

おっと、UNOではprintf()はコンパイル通るけど中身なしかな?(追いきれてない) ESP32あたりだとデフォルトでprintf()もSerail.printf()とかも使えるんですけど、まぁそれはメモリたっぷりというのはあるとして。

少なくとも、質問を読めば使っているのはsprintf()であってそれは普通に使えるし、printfが使えないのはメモリ云々じゃない(さすがに%fは外してあるにしても)ってことで。

[y_waiwai]

ま、まあ、メモリのせいじゃない、と思うのは勝手なので、それでかまいませんよ。

[thkana]

メモリのせいだ、と思うのも勝手ですね。

ちょいと調べたら、printfのつなぎ方もわかりました( https://garretlab.web.fc2.com/arduino/reverse_lookup/ あたり)。
#include <stdio.h>

static FILE uartout;

static int uart_putchar(char c, FILE *stream) {
return Serial.write(c);
}

void setup(void) {
Serial.begin(9600);
fdev_setup_stream (&uartout, uart_putchar, NULL, _FDEV_SETUP_WRITE);
stdout = &uartout;

printf("Hello world\n");
}

void loop(void) {
}

最大32256バイトのフラッシュメモリのうち、スケッチが1598バイト（4%）を使っています。
最大2048バイトのRAMのうち、グローバル変数が216バイト（10%）を使っていて、ローカル変数で1832バイト使うことができます。

このメモリ使用量が「非現実的」かどうかは状況と解釈しだいです。
たったこれだけのプログラムに1.5KBも使うなんて...とも言えるでしょう。
Arduinoだし、メモリを余らせても仕方がないので使える範囲では贅沢に使おう、という考えもあるでしょう。それぞれ思ったところで行動すればいいですね。

(昔、SH-3のC++でiostreamを試しに使ってみたら一気にROM200KBぐらい持っていかれて、さすがに「非現実的」と思ったことはありました)

[cyoncooo]

丁寧なご対応ありがとうございます！勉強になりましたありがとうございます。

Answer 3

Arduino Unoのprintf系は書式指定%fに対応していなかったように思います。

Serial.print(fVal);
Serial.print(',');
Serial.println(Signal);

とでもしてみてください。

---

追記
avr-libcのサイトに、
__For floating-point conversions, if you link default or minimized version of vfprintf(), the symbol ? will be output and double argument will be skiped. __
という記述があります。また、
__If the full functionality including the floating point conversions is required, the following options should be used:
-Wl,-u,vfprintf -lprintf_flt -lm __
ともあります。私は試していませんが、このコンパイル(リンク)オプションを付け加えてみてはいかがでしょうか(Arduino IDE環境でオプションをつけるのがまた面倒だったはずですが)。

Comments

[cyoncooo]

ご指摘いただいた通りprintとprintlnを使うことで無事解決できましたありがとうございます。