VBA：オートフィル

Question

前提・実現したいこと

①シート名に「2021」と入っているシート名のみ処理をしたい
②↑のシートの表に「東京」の値が含まれているセルの行を別シートにオートフィルしたい

該当のソースコード

Sub test()

Dim i

    For i = 1 To Worksheets.Count
        If InStr(Worksheets(i).Name, "2021") > 0 Then
        
            Worksheets(i).Select
    
    '9列目の東京でフィルタ
    Worksheets(i).Range("A1").AutoFilter 9, "東京"
    'シートを追加
    Worksheets.Add after:=ActiveSheet
    'フィルタしたデータを、別シートに転記
    Worksheets(i).Range("A1").CurrentRegion.Copy ActiveSheet.Range("A1")
    
    'フィルタを解除
    Worksheets(i).Range("A1").AutoFilter
    
        End If
        
    Next
    
End Sub

試したこと

2021と含まれているシートは合計3シートあって、
東京でオートフィルしたシートを3シート追加したいのですが、
2シートのみ作成はされるのですが、2シート作成した時点で
End Sub に行ってしまいます。

繰り返し処理がうまくされていないのでしょうか？
エラーは特にでていないのでどこが間違っているのか教えていただきたいです。

Comments

[hex309]

「オートフィル」ではなく、「オートフィルタ」ですね。

Answer 1

Forループの中でWorksheetの数が増えるからだと思います。
Addの追加先をWorksheet.CountのAfterにするとかすればどうでしょう。

    Dim ws As Worksheet
    For Each ws In Worksheets
        If ws.Name Like "*2021*" Then
            With ws.Range("A1")
                .AutoFilter 9, "東京"
                .CurrentRegion.Copy Worksheets.Add(After:=Worksheets(Worksheets.Count)).Range("A1")
                .AutoFilter
            End With
        End If
    Next

Comments

[aaaskw123123]

回答ありがとうございます。無事動かすことができました。
あと、この追加シートに名前を付けたい場合はどうすればいいでしょうか...
繰り返し質問をしてしまい、申し訳ないです。

[jinoji]

sheetをAddした直後はそのシートがアクティブなはずなので、その時点で
ActiveSheet.Name = "xxx"
とするのはどうでしょう。

Answer 2

対象のワークシート名の「2021」が全角だったりしませんか？
もしそうであれば、以下のように半角にしてからチェックすればよろしいかと

If InStr(StrConv(Worksheets(i).Name, vbNarrow), "2021") > 0 Then

Comments

[aaaskw123123]

回答ありがとうございます。試して見たのですが、やはり2枚目のシートでEnd subに行ってしまうので違う問題なようです…。

[hex309]

考えにくいですね。
以下のコードで、チェック対象と実際に処理対象になったシート名をイミディエイトウィンドウに出力してみて、結果を貼り付けていただけないでしょうか？

Sub Test2()
Dim i

For i = 1 To Worksheets.Count
Debug.Print "チェック：" & Worksheets(i).Name
If InStr(Worksheets(i).Name, "2021") > 0 Then
Debug.Print "対象" & Worksheets(i).Name
End If
Next
End Sub

[hex309]

おそらくjinojiさんの回答の通りですね。失礼いたしました。

[hex309]

もしくは、For Eachを使ってこんな感じでしょうか。
Dim temp As Worksheet
For Each temp In Worksheets
If InStr(temp.Name, "2021") > 0 Then
temp.Select

[aaaskw123123]

ご丁寧にありがとうございます。
また、違う書き方も参考になりました。