【VBA】選択セルの結合 行で複数セル一括同じ処理

Question

VBAで行いたいことは、下記の手順です。

①セル内で選択した範囲をセルの結合する。(選択するセルは行だけです)
②結合した左上のセルを取得して、各決まった複数列の該当セルを結合する。(この際に、①で選択行の個数に併せて結合します)

②での残りのセルの結合する列は決まっており、①での選択範囲次第で行の個数が変わるだけです。

例えば、B2：B5まで選択します。そのあとC2：C5・G2：G5、H2:H5も結合という流れです。C,G,Hは決まっています。

そこで、下記のコードを作ったのですが、「繰り返し処理」内のコードだとセルが決まっていますが、決まっていない場合の処理の繰り返し方法がわかりません。

ヒントをいただけないでしょうか。

'選択範囲の結合
Selection.Merge

'選択セルの取得
Dim l As Long
l = Selection.Row
l = Selection.Column

Dim s As String
s = Selection.Address

'残りのセルの選択


'繰り返し処理
Union(Range(Cells(1, "A"), Cells(4, "C")), Range(Cells(6, "E"), Cells(10, "G"))).Select

End Sub
コード

Answer 1

解決済みですが、ご参考までに。

Sub MergeSample()
    Dim Sel As Range
    Set Sel = Selection
    Sel.Merge
    
    Dim r As Range
    For Each r In Intersect(Sel.EntireRow, Range("G:G,H:H,J:J")).Columns
        r.Merge
    Next    
End Sub

Answer 2

こんな感じでしょうか？

Sub MergeSample()
    Dim Origin As Range
    Set Origin = Selection
    
    Dim vAddress As String
    vAddress = Origin.Address(True, False)
    Dim StartRow As Long
    Dim EndRow As Long
    
    StartRow = Split(Split(vAddress, ":")(0), "$")(1)
    EndRow = Split(Split(vAddress, ":")(1), "$")(1)
    
    Dim Target As Variant
    Target = Array("G", "H", "J")
    
    Dim i As Long
    For i = LBound(Target) To UBound(Target)
        Range(Target(i) & StartRow & ":" & Target(i) & EndRow).Merge
    Next
End Sub

Comments

[sh444]

ありがとうございます！！
選択したセルの結合も追加でコードを加えたのですが、エラーにならずに利用できました＾＾
お手数おかけいたしました。