【Excel VBA】色付きセルの件数を集計できる自作関数を作りたい

Question

前提・実現したいこと

色付きセル（セル内には様々な文字が入力されている）を集計しています。
さらにその集計結果を他のカラムの内容ごとに振り分けなければいけません。

このような一覧を

このように集計したいです。

「状況」の列にはいろいろな文字が入っているので、信用できるのは色だけなのです。
お力を貸していただけると幸いです。

試したこと

「状況」の列がオレンジ且つ「部門」の列が集計した表の「部門」名と同じ
という条件の関数を作成すればいいのではないかと考えましたが、見当違いのようで結果は0件になってしまいました。

計算範囲：集計したい列（ここでは上の画像の「状況」の列）を選択
条件色セル：任意の色（ここではオレンジ）のセルを別に用意しておく
計算範囲2：集計したい列（ここでは上の画像の「部門」の列）を選択
条件セル：集計結果を振り分けるキーワード（ここでは下の画像の各部門セル）を選択

Function CountColor(計算範囲, 条件色セル, 計算範囲2, 条件セル)
Application Volatile
'
CountColor = 0
'
For y = 1 To 計算範囲.Columns.Count
    For x = 1 To 計算範囲.Rows.Count
        If 計算範囲.Rows(x).Columns(y).Tnterior.ColorIndex = 条件色セル.Tnterior.ColorIndex Then
            For i = 1 To 計算範囲2.Columns.Count
                If 計算範囲2.Rows(x).Columns(i).Value = 条件セル.Value Then
                    CountColor = CountColor + 1
                End If
            Next i
        End If
    Next x
Next y
End Function

補足情報

Windows10のPCでExcel2016を使用しています。

Comments

[mdj]

『「状況」の列にはいろいろな文字が入っているので』ということは、現状のvalueだとほぼ合わないように思うので、正規表現（RegExp）を調べてもらうと良いかと思います。

[jinoji]

とりあえず、Application Volatile を Application.Volatile にして、
Tnterior を Interior にして、
.ColorIndex を .Color に変えたらどうにかなりますかね。

[nsym]

mdj 様
ありがとうございます。
このようなオブジェクトがあったのですね。
初めて見ましたが、かなり使いやすそうです。

[nsym]

jinoji 様
ありがとうございます。
細かな記述のミスが……！
また、ColorIndexとColorについて調べてみたら、こんなに違いがあるのですね。
これからはColorの方を使用するようにします。

Answer 1

とりあえずこれでどうでしょう。

Function CountColor(計算範囲 As Range, 条件色セル As Range, 計算範囲2 As Range, 条件セル As Range)
    Application.Volatile
    '
    CountColor = 0
    '
    Dim y, x, i
    For y = 1 To 計算範囲.Columns.Count
        For x = 1 To 計算範囲.Rows.Count
            If 計算範囲.Rows(x).Columns(y).Interior.Color = 条件色セル.Interior.Color Then
                For i = 1 To 計算範囲2.Columns.Count
                    If 計算範囲2.Rows(x).Columns(i).Value = 条件セル.Value Then
                        CountColor = CountColor + 1
                    End If
                Next i
            End If
        Next x
    Next y
End Function

Comments

[nsym]

jinoji 様
ありがとうございます。
いただいたコードで求めていた動きが実現できました……！
丁寧に添削してくださり、本当にありがとうございました。