Access VBA ADO SQL LIKE で検索

Question

フルパスの値からフォルダを開くVBAを運用しています。
指定フォルダを開いたら、閲覧数をカウントしたくて新規でプロシージャを作成致しました。
フォルダ名・フォルダの中身は完全一致だが、フォルダの位置が違うパターンがあり、テーブルではそれぞれ登録されています。
フォルダ名が一致したフォルダは全て同一とみなしてカウントしたく作成しましたが、Likeで上手くHITしません。
ワイルドカードは、*と%を試しましたが、結果は変わらずでした。

フォルダ名は
[A会社(A)]「B」(20210724)【☆】サンプルA
といったパターンがほとんどです。

Public Sub BrowsingCount(target As String)
    Dim rs As ADODB.Recordset
    Dim cn As ADODB.Connection
    Dim sql As String
    Dim target_count As Long
    Set rs = New ADODB.Recordset
    Set cn = CurrentProject.Connection
    
    target = Mid(target, InStrRev(target, "\"))
    target = Replace(target, "]", "[]]", , 1)
    target = Replace(target, "[", "[[]", , 1)
    
    
    sql = "SELECT フルパス,閲覧数 FROM T_タイトル WHERE [フルパス] LIKE '*" & target & " ' ;"

    rs.Open sql, cn, adOpenKeyset, adLockOptimistic
        If rs.EOF = True Then Exit Sub
        target_count = Nz(rs("閲覧数"), 0)
        Do Until rs.EOF = True
            rs("閲覧数") = target_count + 1
            rs.Update
            rs.MoveNext
        Loop
    rs.Close
    
    Set rs = Nothing
    Set cn = Nothing
End Sub

2021/7/24 21:26追記
◆期待する動き
「C：\tempA[A会社(A)]「B」(20210724)【☆】サンプルA」
「C：\tempB[A会社(A)]「B」(20210724)【☆】サンプルA」
「C：\tempC[A会社(A)]「B」(20210724)【☆】サンプルA」
「C：\tempA[B会社(A)]「B」(20210724)【☆】サンプルC」
「C：\tempB[B会社(A)]「B」(20210724)【☆】サンプルA」
「C：\tempC[C会社(A)]「B」(20210724)【☆】サンプルA」
があるとして、
検索するキーワードが　「[A会社(A)]「B」(20210724)【☆】サンプルA」のときは、上から3個をHITさせたいです。

Comments

[nonoshu]

回答が集まりやすいように質問文をもう少し追記した方が良いと思います。
◆使用するデータベース
　Access内部のテーブル
　SQL-Server、Oracle?などですか？
◆期待する動き
　例：フルパスの値が「C：￥temp￥A会社(A)￥ファイル名.txt」 だったとして
　検索するキーワードが　「会社(A)」のときヒットさせたい
みたいな感じです。

[kyousuke8957]

編集致しました。

使用するデータベースについては、私の知識不足で理解出来ていなくて何を使用しているか分かりませんでした。

[nonoshu]

期待する動きはとてもわかりやすくなりました。
データベースの追記をお願いしたのは、
Access内部のテーブルの場合　LIKE検索では　＊（アスタリスク）
例えばSQL-Serverでは　％（パーセント）
というようにデータベースによって部分一致の識別子が異なるためです。

[sazi]

@odataikiさん
ワイルドカードが変わるのは接続先の種類ではなく、ADOやDAOなどの接続方法によるものです。
接続先は、「CurrentProject.Connection」になっていますのでAccessですね。

Answer 1

sql = "SELECT フルパス,閲覧数 FROM T_タイトル WHERE [フルパス] LIKE '*" & target & " ' ;"

上記の部分を下記に変更したらどうでしょう。

sql = "SELECT フルパス,閲覧数 FROM T_タイトル WHERE [フルパス] LIKE '%" & target & "';"

ADOの場合は、ワイルドカード文字は % (DAOの場合は *)

あと、修正前のコードだと、最後に半角空白が付いたものしか抽出されない。

追記

saziさんの回答を見て気づきましたが、ワイルドカードのエスケープも考慮する必要がありますね。
[は[[]でエスケープする必要があります。
]はエスケープする必要がないです。[]]とするとうまくいきません。

あと、targetに\が含まれないときエラーになるのでそれも対策しておいた方がいいかも。

    Dim l As Long
    l = InStrRev(target, "\")
    If l > 0 Then target = Mid(target, l)
'    target = Replace(target, "]", "[]]", , 1) 不要
    target = Replace(target, "[", "[[]", , 1)

    sql = "SELECT フルパス, 閲覧数 FROM テーブル2 WHERE [フルパス] LIKE '%" & target & "';"

Comments

[kyousuke8957]

sql = "SELECT フルパス,閲覧数 FROM T_タイトル WHERE [フルパス] LIKE '*" & target & " ' ;"
を
sql = "SELECT フルパス,閲覧数 FROM T_タイトル WHERE [フルパス] LIKE '%" & target & "';"
に変更したら、期待通りの動きになりました。

最後に空白が入っているのに気が付いていませんでした。

また']'の置き換えを削除して、MIDの対策も実装致しました。

エラー発生の可能性と対策案も教えて頂きありがとうございます。

Answer 2

デバッグしてみました。
どうやら]のエスケープがされないみたいですね。
これはADOでもDAOでも同じでした。
検索対象も含めて違う文字に置換するか、任意の1文字(_)に置き換えるとかでしょうか。

    target = Replace(target, "]", "_", , 1)
    target = Replace(target, "[", "[[]", , 1)

    sql = "SELECT フルパス, 閲覧数 FROM T_タイトル WHERE [フルパス] LIKE '%" & target & "%';"

Answer 3

使用するデータベースが何かわかりませんが、
Accessだとしたら下記のように末尾にもアスタリスクをつけるとHITするはずです。

sql = "SELECT フルパス,閲覧数 FROM T_タイトル WHERE [フルパス] LIKE '*" & target & "*';"

Comments

[kyousuke8957]

sql = "SELECT フルパス,閲覧数 FROM T_タイトル WHERE [フルパス] LIKE '*" & target & "*';"

としても、結果はHITしませんでした。

[nonoshu]

なるほど。アスタリスクを`％`にしてみてはどうでしょうか？
それでも駄目なら使用しているデータベースの特定が先決ですね