バッチファイルでCSVの中身を置換したい

Question

windowsバッチで下記のbefore.csvからafter.csvのように変換をしたいと考えています。
if文のところの実装方法で躓いてしまいました。

そもそも、windowsバッチでこの処理は向いていない気もしてきたのですが、
実現可能でしょうか?
ご教授いただけると幸いです。
よろしくお願いいたします。

rem test.bat

rem 定義
set BEFORE_CSV=before.csv
set AFTER_CSV=after.csv
set BEFORE_STRING_TOKYO=東京
set AFTER_STRING_TOKYO=東京,1,2
set BEFORE_STRING_OSAKA=大阪
set AFTER_STRING_OSAKA=大阪,10,20

for /f "tokens=1 eol=#" %%a in (%BEFORE_CSV%) do (
  set line=%%a
  if csvの一つ目の要素が東京だったら do (echo !!line:%BEFORE_STRING_TOKYO%=%AFTER_STRING_TOKYO%!!>>%AFTER_CSV%)
  if csvの一つ目の要素が大阪だったら do (echo !!line:%BEFORE_STRING_OSAKA%=%AFTER_STRING_OSAKA%!!>>%AFTER_CSV%)
)

#before.csv
東京,3,4
大阪,30,40

#after.csv
東京,1,2,3,4
大阪,10,20,30,40

追記
上記の処理で「csvの一つ目の要素が東京だったら 」としていた箇所を
「AFTER_XXXのCSVの一つ目の値とBEFORE_XXXの要素が一致している場合」
として汎用的に処理を書きたいと思っています。
下記のイメージで出来ると思ったのですが、
サブルーチンからうまく値を取得できません。
たびたび申し訳ございませんが、ご教授いただければ幸いです。
(AFTER_XXXはconfファイルへ外だしする予定の為、名称が変わった場合に改修を容易にしたいという背景です。)

rem test.bat

～中略～
call :returnFirstColumn %AFTER_TOKYO% TOKYO
call :returnFirstColumn %AFTER_OSAKA% OSAKA
～中略～
    if "%%b"=="%TOKYO%" (
～中略～
rem csvの1項目目を取得する
:returnFirstColumn
setlocal

for /f "delims=," %%i in ("%1") do (
  set val=%%i
)
endlocal && set %2=!val!
exit /b

Answer 1

いろいろ文法的におかしい点があります。ifのdoとか。

文字列を、特定文字で区切るには、"で囲んでfor /f "delims=,"の機能を使います。

@echo off
setlocal enabledelayedexpansion
rem 定義
set BEFORE_CSV=before.csv
set AFTER_CSV=after.csv
set BEFORE_STRING_TOKYO=東京
set AFTER_STRING_TOKYO=東京,1,2
set BEFORE_STRING_OSAKA=大阪
set AFTER_STRING_OSAKA=大阪,10,20

(
for /f "delims= eol=#" %%a in (%BEFORE_CSV%) do (
  set line=%%a
  for /f "delims=," %%b in ("%%a") do (
    if "%%b"=="東京" (
      echo !line:%BEFORE_STRING_TOKYO%=%AFTER_STRING_TOKYO%!
    ) else if "%%b"=="大阪" (
      echo !line:%BEFORE_STRING_OSAKA%=%AFTER_STRING_OSAKA%!
    ) else (
      echo %%a
    )
  )
)
)>%AFTER_CSV%

Comments

[anko__]

ご回答ありがとうございます。
とても助かりました。
変数を文字列に変換できることすら知らず、苦戦しておりました。

質問を追記させていただいたので、
お時間ありましたらご回答いただけると幸いです。