二つのシートのキー番号から値を突合させたい

Question

シート1のA列（Ａ5からスタート)、シート2のＬ列(Ｌ3からスタート)にそれぞれkey番号があります。
シート1のA列のkey番号とシート2のＬ列のkey番号が一致したら、シート1のＺ列にシート2のＬ列で一致した行のAV列の値を入力したいです。

Dim t As Long , k As Long
Dim ws1 As Worksheet ,
ws2 As Worksheet
Set ws1 = Worksheets("Sheet1")
Set ws2 = Worksheets("Sheet2")
For t = 5 to xlw(最後まで)
For k = 3 to xlw(最後まで)

If ws1.Range("A" & t).Value
=ws2.Range("Ｌ" & k).Value Then

ws1.Range("z5" & t).Value
= ws2.Range("AV" & k).Value
Exit For
z = z+5
End If
Next

Next

#ws1.Rangeは数値がでていますが
ws2.RangeはRengeメゾットは失敗しました。Worksheetオブジェクトと記載されています。
すみません、どなた様か教えていただきたいです。iPhoneから入力しているためまたミスしていたら教えてください。

Comments

[neconekocat]

コードはMarkdownの記法に従って書いてください。
コードの挿入ってボタン押したら出てきます。
あとこのコードですが、自分が書いたものをそのままコピペしてください。
Dim ws1 = Worksheetみたいなデタラメなコードが通るわけ無いですよね。

[makox0105]

xlwの値は何ですか？
またBB列じゃなくAV列ですか？
wr2.rangeじゃなく、ws2.rangeですよね？
正しいコードを載せてください。

[neconekocat]

スマホから入力してるからまともなコードが書けないというのであれば、PCで書ける環境になってから編集してください。
かなりデタラメなコードですが、少なくともこのコードを(ある程度)正しく書き直した場合、ws2.Rangeのエラーは起きません。
あなたが正しいコードを提示しない限り回答は不可能です。

[makox0105]

上記の方と同様です。エラーは起きないと思います。

Answer 1

Sub org()
    Dim t As Long, k As Long
    Dim ws1 As Worksheet, ws2  As Worksheet
    Set ws1 = Worksheets("Sheet1")
    Set ws2 = Worksheets("Sheet2")    
    For t = 5 To ws1.Range("A" & Rows.Count).End(xlUp).Row
        For k = 3 To ws2.Range("L" & Rows.Count).End(xlUp).Row
            If ws1.Range("A" & t).Value = ws2.Range("L" & k).Value Then
                ws1.Range("Z" & t).Value = ws2.Range("AV" & k).Value
                Exit For
            End If
        Next
    Next
End Sub

Sub Sample()
    Dim t As Long, k As Long
    Dim ws1 As Worksheet, ws2  As Worksheet
    Set ws1 = Worksheets("Sheet1")
    Set ws2 = Worksheets("Sheet2")
    Dim dic 'As Scripting.Dictionary
    Set dic = CreateObject("Scripting.Dictionary")
    With ws2
        For k = 3 To .Range("L" & .Rows.Count).End(xlUp).Row
            dic(.Range("L" & k).Value) = .Range("AV" & k).Value
        Next
    End With
    With ws1
        For t = 5 To .Range("A" & .Rows.Count).End(xlUp).Row
            .Range("Z" & t).Value = dic(.Range("A" & t).Value)
        Next
    End With
End Sub

Comments

[yum28]

お忙しいところありがとうございます。全然飛ばなかったセルが飛びました。すみません、あと一つ教えて頂きたいのですが、Ｚ5から、8飛ばしで最後の行までこの計算式を飛ばしたいのですが、その場合はどんな式になりますか？

[jinoji]

For t = 5 To .Range("A" & .Rows.Count).End(xlUp).Row Step 8
みたいなことですかね。

[yum28]

早急な対応ありがとうございます。飛びました。感動してます。
一週間できなくて初めて質問しました。本当にありがとうございます。