vba 時刻の検索をしたい。

Question

前提・実現したいこと

Excelのvbaで、「ユーザフォームのリストボックスで選択された日付と時刻をsheet2で検索(行または列番号の取得)する」ということをしたいです。
多くの時刻は検索できるのですが、特定の時刻だけ検索できず、理由と解決方法が知りたいです。
vba始めて1週間の初心者なので、詳しく教えていただけると助かります。
よろしくお願いします。
以下、コードと詳しい説明です。

具体的には、
リストボックスの値【日付,時刻,ID,セルのaddress,選択されたlistboxのindex】を配列に格納し、それを引数(num2)とした関数を作っています。
そして、num2(0)の日付(令和3年7月5日のような表記)とnum(1)の時刻(12:00のような表記)はString型だと思うので、CDateで変換し、match関数で検索するということをしています。
日付は、7月5日からエンドレスに作成してあり、時刻は、12:10～16:00まで10分刻みで作成しています。
検索したい箇所は、それぞれ日付(7月5日のような表記)はsheet2の9行目、時刻(12:00のような表記)はsheet2のC列(9～80行)です。
sheet2の時刻9行～80行は、「12:10, 12:10, 12:10, 12:20, 12:20, 12:20, ・・・, 16:00, 16:00, 16:00」というように同じ時刻を3回ずつ表記してあり、初めにmatchした値(行番号)を取得できれば良いです。
作ったプログラムでは何故か、「12:20, 13:10, 13:50, 14,40, 15,20」の時刻だけ検索できません。他の時刻は検索できます。
日付も検索出来ています。(日付はエンドレスの為、全て検索できるのか不安です。)

以下がコードになります。

発生している問題・エラーメッセージ

エラーメッセージは表示されていません。

該当のソースコード

Private Function del_func2(num2)'num2は配列で、「日付, 時刻, ID, セルのaddress(sheet1), 選択されたlistboxのindex」
    Dim sht_2, sht_1 As Worksheet
    Dim msg2
    Set sht_1 = Sheets(1)
    Set sht_2 = Sheets(2)
    sht_2.Activate'ここでsheet2を作業できるようにしています。
    '###################################
    '#　日付の行検索
    '###################################
    Dim row_num As Variant
    On Error Resume Next
    row_num = WorksheetFunction.Match(CLng(CDate(num2(0))), Rows(Cells(1, 1).End(xlDown).Row + 1), 0) '日付の列を格納sheet2
    On Error GoTo 0
    If row_num = 0 Then
        MsgBox "sheet2に日付がなく、" & vbCrLf & "削除出来ませんでした。" & vbCrLf & "プログラムを強制終了します。"
        sht_1.Activate
        End
    End If
    '###################################
    '#　時間の行検索
    '###################################
    Dim col_time
    On Error Resume Next
    col_time = Application.WorksheetFunction.Match(CDbl(CDate(num2(1))), Range("C9:C80"), 0) '時刻の行を格納sheet2
    On Error GoTo 0
    If col_time = 0 Then
        MsgBox "sheet2に時間がなく、" & vbCrLf & "削除出来ませんでした。" & vbCrLf & "プログラムを強制終了します。"
        sht_1.Activate
        End
    End If
    'MsgBox col_time
End Function

試したこと

CDbl(CDate(num2(1))とRange("C9:C80")の型と表記の判定を行いました。
型は両方Double型(vartypeで確認出力5)で、表記は「12:00」のような表記(msgboxで目視で確認)でした。
一応、「CDbl(CDate(num2(1)) is Range(対応するセル)」と「CDbl(CDate(num2(1)) is Range(対応するセル)」を行いましたがどちらもFALSEでした。

補足情報（FW/ツールのバージョンなど）

ユーザーフォームのリストボックスはこんな感じです。
num2(0)に日付
num2(1)に時刻
num2(2)にID
num2(3)に選択されたIDが位置するsheet1のaddress(画像では非表示)
num2(4)に選択されたリストボックスのindex(画像では非表示)

sheet2はこのような表示になっています。

説明下手で申し訳ございませんが、何卒よろしくお願い致します。

Comments

[hatena19]

On Error Resume Next
の行をコメントアウトして実行してみてくだいさい。
それでエラーが出たらそのエラーメッセージを追記してください。

[hatena19]

あと、Range("C9:C80") の書式設定はどうなってますか。

[cheese0609]

ご連絡ありがとうございます。
検索できない特定の時刻のみ、
「WorksheetFunctionクラスのMatchプロパティを取得できません。」
とエラーが出ます。

[cheese0609]

Range("C9:C80") の書式設定について、書式設定は「時刻の13:30」というものを設定しています

Answer 1

検証してみました。

提示の画像のようにシートに時刻を入力して、
下記のコードを実行。

'C12セルの値 12:20
Debug.Print Range("C12") = CDbl(CDate("12:20"))
'結果はFalse

'C21セルの値 12:50
Debug.Print Range("C21") = CDbl(CDate("12:50"))
'結果はTrue

同様に「12:20, 13:10, 13:50, 14,40, 15,20」の時刻でも試してみましたが、Falseになりました。

CDblで倍精度浮動小数点数に変換してますが、浮動小数点数には誤差がつきものですので、厳密な比較には向かないというのはプログラミングのあるあるです。

Match関数では日付/時刻型では検索できないのでCDblでの変換は必須なので、Match関数はあきらめてループで処理するぐらいしかなさそうです。あるいはFindメソッドでもいけるかも。

Findメソッドのコード例

    '###################################
    '#　時間の行検索
    '###################################
    Dim rng As Range
    set rng = Range("C9:C80").Find(CDate(num2(1)))
    If Rng Is Nothing Then
        MsgBox "sheet2に時間がなく、" & vbCrLf & "削除出来ませんでした。" & vbCrLf & "プログラムを強制終了します。"
        sht_1.Activate
        Exit Function 'Endで強制終了は危険なのでExitに変更
    End If

---

ループ処理で検索する方法のコード例

    Dim rng As Range, flg As Boolean
    For Each rng In Range("C9:C24")
        If Format(rng.Value, "hh:mm") = "12:30" Then
            flg = True
            Exit For
        End If
    Next
    If flg = False Then
      MsgBox "sheet2に時間がなく、" & vbCrLf & "削除出来ませんでした。" & vbCrLf & "プログラムを強制終了します。"
        sht_1.Activate
        Exit Function
    End If

Comments

[cheese0609]

hatena19様
回答ありがとうございます。

Match関数は諦めようと思います。
そして、Findメソッドですが、以前試したところこちらでも時刻の検索は出来ないように思えます。
ご提示頂きましたFindメソッドのコード例で試してみても、検索出来ませんでした。
rng is nothingの処理が実行されてしまいます。
時刻検索自体出来ないのでしょうか・・・？

[cheese0609]

すみません。
説明不足でした。

Findメソッドでは前回の検索条件が適応されてしまう(？)ようなので、
①ご指摘頂いたコード
➁Find(CDate(num2(1)), LookIn:=xlValues, LookAt:=xlPart)
③Find(CDate(num2(1)), LookIn:=xlValues, LookAt:=xlWhole)
の3つで試しました。
どれも、rng is nothingの処理になってしまいました。

[hatena19]

Find(num2(1), LookIn:=xlValues, LookAt:=xlWhole)
だとどうでしょう。

[cheese0609]

hatena19様
何度もありがとうございます。

Find(num2(1), LookIn:=xlValues, LookAt:=xlWhole)
で検索することができました。
また、色々試していたところ、
Find(Format(CDate(num2(1)), "hh:mm"), LookIn:=xlValues, LookAt:=xlWhole)
でも検索できました。

色々とありがとうございました。
このシステムは、地元の病院でコロナワクチンの予約システムとして使用させて頂きます。
本当に、ありがとうございました。

[hatena19]

うまくいってよかったですね。
参考までに、ループで検索する方法も追記しておきました。

[cheese0609]

とても参考になります。
ありがとうございました。

Answer 2

確証はありませんが、シートの時間をオートフィルで埋めたのであれば、一度各セルで[F2][Enter]とするといいかもしれません。

それか、いっそのこと、シートの「時間」の列の書式を文字列にするのはどうでしょう。