VBAを用いたワークシート間のRangeのコピー

Question

前提・実現したいこと

ある地点の複数年の降雨量が記録されたExcelブックがあり、年ごとにワークシートが分かれています。このうち2001年～2007年の７つのワークシートのデータを1つのワークシートにまとめたいと考えています。元のワークシートの表は縦軸が日、横軸が月で、B5セルから始まっています。まとめ用ワークシートの表は縦軸が日（1～365）、横軸が年とします。VBAでこの処理を行うコードを実行したところ、以下のエラーメッセージが発生しました。

発生している問題・エラーメッセージ

実行時エラー'1004':
'Range'メソッドは失敗しました: '_Worksheet'オブジェクト

対象行：.Range(.Cells(5, j + 2), .Cells(Days(j) + 4, j + 2)).Copy newWS.Range(newWS.Cells(LastRow + 1, i + 1)).Value

該当のソースコード

Option Explicit
Sub ws_compilation()

    Dim WS As Worksheet, newWS As Worksheet
    Dim WSname As Variant, Days As Variant
    Dim newWSname As String
    Dim i As Long, j As Long, LastRow As Long
    
    newWSname = "2001_2007"  '---まとめ用のシート名です
    '----同名シートを削除します
    For Each WS In Worksheets
        If WS.Name Like newWSname Then
            Application.DisplayAlerts = False
            WS.Delete
            Application.DisplayAlerts = True
        End If
    Next WS
    '----まとめ用シートを先頭へ追加します
    ActiveWorkbook.Worksheets.Add(before:=Worksheets(1)).Name = newWSname
    Set newWS = Worksheets(newWSname)
    '----コピーする順番にシート名を配列WSnameに登録します
    WSname = Array("2001", "2002", "2003", "2004", "2005", "2006", "2007")
    '----各シートのデータ（月ごとに異なる列）を1列にまとめ、まとめ用シートの各列にコピーします
    For i = 0 To 6
        With Worksheets(WSname(i))
            If WSname(i) = "2004" Then
                Days = Array(31, 29, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31)
            Else
                Days = Array(31, 28, 31, 30, 31, 30, 31, 31, 30, 31, 30, 31)
            End If
            For j = 0 To 11
                LastRow = newWS.Cells(Rows.Count, i + 1).End(xlUp).Row
                .Activate
                .Range(.Cells(5, j + 2), .Cells(Days(j) + 4, j + 2)).Copy newWS.Range(newWS.Cells(LastRow + 1, i + 1)).Value
            Next j
        End With
    Next i
    newWS.Activate
    Range("A1").Select
    Application.ScreenUpdating = True
End Sub

試したこと

コピー先のWorksheetオブジェクト（非アクティブ）はRangeおよびCellsの前に書き加えました。
各CellsのRowおよびColに0は代入していません。

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

こうですか？

.Range(.Cells(5, j + 2), .Cells(Days(j) + 4, j + 2)).Copy newWS.Cells(LastRow + 1, i + 1)

Comments

[maztips]

ご指摘のコードで無事解決しました。
コピー先の先頭セルのみ指定の場合はRangeオブジェクトは不要だったのですね。
素早いご回答、ありがとうございました。