Excel VBA aタグのクリックが上手くいきません。ステップインでは作動するのですが・・・

Question

Excel VBAにて以下のコードでaタグをクリックしたいのですが、作動しません。
ステップインではFor~Nextのところで何度かループをして作動しますが、実行をクリックすると作動しなくなります。

実際のサイトは社内サイトのため控えさせていただきます。

原因がわかる方がいらっしゃいましたら、ご教授下さいませ。

宜しくお願い致します。

Sub 来店予約()

Dim objIE As InternetExplorer
Set objIE = New InternetExplorer


objIE.Visible = True
objIE.navigate "社内サイトURL" '管理画面ページのURLを指定
    
Call WaitIE(objIE)

Dim htmlDoc As HTMLDocument
Set htmlDoc = objIE.document
    
htmlDoc.getElementById("btnLogin").Click


Call WaitIE(objIE)
    
htmlDoc.getElementById("focus").Value = "" 'ユーザー名を指定

objIE.document.getElementsByName("lpw")(0).Value = ""

htmlDoc.getElementById("btnLogin").Click


    Set htmlDoc = Nothing 'ログインページのHTMLをいったん破棄

Call WaitIE(objIE) '画面遷移の待機

Set htmlDoc = objIE.document 'ログイン後のページのHTMLを読み込む


'変数を定義

Dim ieDoc As HTMLDocument
Dim obj As Object

'HTML型ドキュメントに収録する
Set ieDoc = objIE.document

For Each obj In ieDoc.getElementsByTagName("a")
If obj.innerText = "予約者情報検索" Then
obj.Click
Exit For
End If
Next

'該当のWebサイトが表示されるのを待つ
While objIE.Busy Or objIE.readyState <> READYSTATE_COMPLETE
DoEvents
Wend

'オブジェクト参照を解除
Set ieDoc = Nothing
Set objIE = Nothing

End Sub

Sub WaitIE(objIE As InternetExplorer)

Do While objIE.Busy = True Or objIE.readyState < 4 '読み込み待ち
    '4=READYSTATE_COMPLETE
    DoEvents
Loop

End Sub

Comments

[jinoji]

とりあえず、Forループの中や前後にDebug.Print入れてみるとかしてみたらどうでしょう。

[tosi]

htmlDoc.getElementById("btnLogin").Click
の後の処理が完了していない為ではないでしょうか。
msgboxで一旦停止して、動くようであればその可能性高いです。
DoEventsや下記の様にobjIEの再取得を、実行前にして見たら如何でしょうか。(IE系は試験環境がないので憶測ですが)
https://vba-create.jp/vba-ie-shell-set-objie/

[TAJ_242]

対象のaタグのHTMLは公開できないでしょうか？？

[hiro22]

皆様、ご回答ありがとうございます。
明日、確認する時間が確保出来そうなので、ご回答頂いた対処法を実践してみて結果を投稿してみます。

[hiro22]

対象のaタグのHTMLも明日公開します。

[hiro22]

対象のaタグは以下の通りです。

<a href="/ReserveForm/reserveC/Subscriber/Search.aspx">予約者情報検索</a>

[hiro22]

ステップインで実行すると以下のｺｰﾄﾞ部分を4回ほど繰り返すことでaタグがクリックされます。

If obj.innerText = "予約者情報検索" Then
obj.Click
Exit For
End If
Next

[hiro22]

tosiさんの仰る通り、Set ieDoc = objIE.document と
For Each obj In ieDoc.getElementsByTagName("a")
の間にmsgboxを入れると作動しましたが、msgboxを消して同じ場所にDoEventsを入れると作動しません。

当方初心者のため、申し訳ございませんが詳しく教えて頂けますでしょうか。

[TAJ_242]

aタグの確認ありがとうございます！
何度もすみませんが、id="btnLogin"の部分のHTMLも見せて頂けますでしょうか？？？

Answer 1

明確な回答ではありませんが、追記で書きましたobjIEの再取得の方法を記載させて頂きます。こちらで安定する事はありませんでしょうか。
https://vba-create.jp/vba-ie-shell-set-objie/
参照設定:Microsoft Shell Controls And Automation

    Dim objIE As InternetExplorer
    Set objIE = New InternetExplorer
    '(追記)
    Dim winshell As Shell
    Dim win As WebBrowser
    Set winshell = CreateObject("Shell.Application")
           ・
           ・
           ・
    '(追記)オブジェクト再取得
    DoEvents
    Set objIE = Nothing
    For Each win In winshell.Windows
　　　　'(-動作確認-)
        Debug.Print "---> " & win.Name
        If win.Name = "Internet Explorer" Then
            Set objIE = win
            Exit For
        End If
    Next

    '変数を定義
    Dim ieDoc As HTMLDocument
    Dim obj As Object
    
    'HTML型ドキュメントに収録する
    Set ieDoc = objIE.document
    
    For Each obj In ieDoc.getElementsByTagName("a")
        If obj.innerText = "予約者情報検索" Then
            obj.Click
            Exit For
        End If
    Next
           ・
           ・
           ・

p.s.追記・修正でも書きましたが、IE起動のVBA動作はHPソース/サーバーが違うために、環境が無い為に試験が出来ず確実な回答は出来ません。その為に、参考程度となるかも知れません。

Comments

[hiro22]

ご回答いただいたものとは少々異なりますが、再取得・再読み込みをすることで作動しました。

原因を明らかにしていただき、ご丁寧な回答をありがとうございました。