指定せるが空白の際に行消去のマクロを作ったのですが、処理速度が遅くすごい時間がかかってしまいます。

Question

Aの列が空白の際に行を消去するマクロを作成したのですが、
セル内に関数が組んであるものと組んでないもので処理速度が違います。

コードが悪いのでしょうか？関数による処理速度低下なのでしょうか？

ちなみにコードは以下です。

Sub ボタン3_Click()
    Dim i As Long
    Dim toprow As Long
    Dim bottomrow As Long
    
    '開始する行
    toprow = 4
    '終了する行
    bottomrow = 2000
    
    For i = bottomrow To toprow Step -1
        If ActiveSheet.Cells(i, 1) = "" Then
            'A列が空白なら行削除
            Application.Rows(i).Delete
        End If
    Next
End Sub

Comments

[Crimson_Tide]

セル内に関数があって関数の結果が空白の場合は行削除する想定ですか？

Answer 1

Unionメソッドで削除したい行を結合し、最後に一括削除する方法です。
行数が5万行くらいまでなら、それほど待たずに処理が終わります。

Sub Sample()
    Dim i As Long
    Dim toprow As Long
    Dim bottomrow As Long
    Dim Target As Range

    For i = toprow To bottomrow  '上から下へ
        'A列が空白ならその行を変数Targetに結合
        If ActiveSheet.Cells(i, 1).Value = "" Then
            If Target Is Nothing Then
                Set Target = ActiveSheet.Rows(i).EntireRow
            Else
                Set Target = Union(Target, ActiveSheet.Rows(i).EntireRow)
            End If
        End If
    Next i
    
    '削除対象の行があれば削除する
    If Not Target Is Nothing Then
        Target.Delete
    End If
End Sub

Answer 2

処理前に下記のコードを挿入して再計算と描画を停止したらどうでしょう。

Application.Calculation = xlCalculationManual
Application.ScreenUpdating = False

処理の後で戻しておくのは忘れないように。

Application.Calculation = xlCalculationAutomatic
Application.ScreenUpdating = True

別案

ちなみに下記の1行でも同様のことが可能です。
速度的にどうかはわかりません。

   Range(Cells(toprow ,1),Cells(bottomrow ,1)).SpecialCells(xlCellTypeBlanks).EntireRow.Delete