ESP8266 C++ コード勉強中

Question

##試していること
ESP8266を使用しています．
シリアル通信を使用して，GPSのでーたを送信するプログラムを考えています．
今，↓のコードを参考にして，このコードの中身を理解しようとしていますが，

###わからないこと1
12行目～14行目の部分は，何をしているのでしょうか?
プログラムの他の部分との兼ね合いがまったくみえてこず，分かりません．
ネットで検索すると，ESP-WROOM-02でアナログ入力をするために必要とあるのですが，
このプログラムにおいてアナログ入力（Analog read）している部分がないので，必要ないと考えていますが，
必要あるのでしょうか?

###わからないこと2
152行目の
buf = (i == 0) ? shortbuf : obuf;
ここが，何をしているのかまったく理解できません．

125行目～129行目でGPSのデータを12桁の文字列"obuf"に格納していますが，
131行目～135行目でGPSのデータを8桁の文字列"shortbuf"に格納しています，

なぜ，GPSのデータを桁数が異なる2つの文字列に格納しているのかが分かりません．
そして，152行目が何をしているのかも分かりません．

教えていただけると助かります．

##プログラムコード

/*
 * ESP8266+LoRaモジュール+GPSモジュールで、
 * スイッチを押されたら緯度経度を取得し、
 * bw, sfを変えながらLoRaで送信し、
 * LoRaモジュールからのレスポンスをプリントする
 */
#include <ESP8266WiFi.h>
#include <SoftwareSerial.h>
#include <TinyGPS++.h>
#include <string.h>

extern "C" {
#include "user_interface.h"
}

static const int LED = 2;
static const int gps_RX = 4, gps_TX = 5;
SoftwareSerial gps_ss(gps_RX, gps_TX, false, 256);
TinyGPSPlus gps;

static const int sw = 16;
static const unsigned long PUSH_SHORT = 1000;

static const int LoRa_RX = 13, LoRa_TX = 12;
static const int LoRa_Rst = 14;
SoftwareSerial LoRa_ss(LoRa_RX, LoRa_TX, false, 256);

void LoRa_reset(void) {
    digitalWrite(LoRa_Rst, LOW);
    delay(100);
    digitalWrite(LoRa_Rst, HIGH);
}

int LoRa_recv(char *buf) {
    char *start = buf;

    while (true) {
        delay(0);
        while (LoRa_ss.available() > 0) {
            *buf++ = LoRa_ss.read();
            if (*(buf-2) == '\r' && *(buf-1) == '\n') {
                *buf = '\0';
                return (buf - start);
            }
        }
    }
}

int LoRa_send(char * msg) {
    char *start = msg;
    while (*msg != '\0') {
        LoRa_ss.write(*msg++);
    }
    return (msg - start);
}

#define NMODE 24
 
struct mode {
    int bw;
    int sf;
    int timeout;
};
struct mode Mode[NMODE] = {
    {3, 12, 5}, {3, 11, 5}, {3, 10, 4}, {3, 9, 3}, {3, 8, 2}, {3, 7, 2},
    {4, 12, 5}, {4, 11, 4}, {4, 10, 3}, {4, 9, 3}, {4, 8, 2}, {4, 7, 2},
    {5, 12, 4}, {5, 11, 3}, {5, 10, 2}, {5, 9, 2}, {5, 8, 2}, {5, 7, 2},
    {6, 12, 3}, {6, 11, 3}, {6, 10, 2}, {6, 9, 2}, {6, 8, 2}, {6, 7, 2},
};

int sendcmd(char *cmd) {
    unsigned long t;
    char buf[64];

//    Serial.print(cmd);
    LoRa_send(cmd);

    while (true) {
        LoRa_recv(buf);
        if (strstr(buf, "OK")) {
//            Serial.print(buf);
            return true;
        } else if (strstr(buf, "NG")) {
//            Serial.print(buf);
            return false;
        }
    }
}

void setMode(int bw, int sf) {
    char buf[64];

    LoRa_send("config\r\n");
    delay(200);
    LoRa_reset();
    delay(1500);

    while (true) {
        LoRa_recv(buf);
        if (strstr(buf, "Mode")) {
            Serial.print(buf);
            break;
        }
    }

    sendcmd("2\r\n");
    sprintf(buf, "bw %d\r\n", bw);
    sendcmd(buf);
    sprintf(buf, "sf %d\r\n", sf);
    sendcmd(buf);
    sendcmd("q 2\r\n");
    sendcmd("w\r\n");

    LoRa_reset();
    Serial.println("LoRa module set to new mode");
    delay(1000);
}

void send2LoRa() {
    char obuf[64], ibuf[64], shortbuf[32];
    char * buf;
    int n;
    unsigned long t;

    strcpy(obuf, "loc=(");
    dtostrf(gps.location.lat(), 12, 8, &obuf[strlen(obuf)]);
    strcat(obuf, ",");
    dtostrf(gps.location.lng(), 12, 8, &obuf[strlen(obuf)]);
    strcat(obuf, ")\r\n");

    strcpy(shortbuf, "loc=(");
    dtostrf(gps.location.lat(), 8, 4, &shortbuf[strlen(shortbuf)]);
    strcat(shortbuf, ",");
    dtostrf(gps.location.lng(), 8, 4, &shortbuf[strlen(shortbuf)]);
    strcat(shortbuf, ")\r\n");

    digitalWrite(LED, HIGH);

    for (int i = 0; i < NMODE; i++) {
        Serial.print("setMode(bw: ");
        Serial.print(Mode[i].bw);
        Serial.print(", sf: ");
        Serial.print(Mode[i].sf);
        Serial.println(")");

        setMode(Mode[i].bw, Mode[i].sf);

        t = millis();
        delay(500);

        Serial.print("send to LoRa: ");
        buf = (i == 0) ? shortbuf : obuf;
        Serial.print(buf);
        LoRa_send(buf);

        while (true) {
            LoRa_recv(ibuf);
            if (strstr(ibuf, "OK")) {
                Serial.print(ibuf);
                break;
            } else if (strstr(ibuf, "NG")) {
                Serial.print(ibuf);
                break;
            }
        }

        if (i != 0) {
            long s;

            s = Mode[i].timeout * 1000 - (millis() - t);
            if (s > 0) {
                Serial.print("delay: ");
                Serial.println(s);
                delay(s);
            }
        }
    }

    digitalWrite(LED, LOW);
}

void setup()
{
    WiFi.mode(WIFI_OFF);

    Serial.begin(115200);
    delay(20);

    pinMode(LED, OUTPUT);
    digitalWrite(LED, LOW);

    gps_ss.begin(9600);

    pinMode(sw, INPUT);

    LoRa_ss.begin(115200);
    pinMode(LoRa_Rst, OUTPUT_OPEN_DRAIN);
    digitalWrite(LoRa_Rst, HIGH);

    LoRa_reset();

    delay(1000); // LoRaモジュールをリセットしてからCPUと通信できるまでに1秒程度かかるようだ

    while (LoRa_ss.available() > 0) {
        char c = LoRa_ss.read();
            if (c < 0x80) {
                Serial.print(c);
            }
    }
    Serial.println(F("\r\nStart"));
}

void loop()
{
    unsigned long gauge = 0;
    char buf[128];

    while (digitalRead(sw) == 0) {
        gauge++;
        delay(0);
    }
    if (gauge > PUSH_SHORT) {
        if (gps.location.isValid()) {
            gps_ss.enableRx(false);
            send2LoRa();
            gps_ss.enableRx(true);
        }
    }
    while (gps_ss.available() > 0) {
        if (gps.encode(gps_ss.read())) {
            break;
        }
    }
}

Comments

[ozwk]

> ↓のコードを参考にして

このコードの出どころはどこですか?

[raspypy]

失礼しました．
https://github.com/AmbientDataInc/LoRa-rssi-measure/blob/master/ESP_GPS_LoRa/ESP_GPS_LoRa.ino

Answer 1

12行目～14行目の部分は，何をしているのでしょうか?

extern "C" {
#include "user_interface.h"
}

user_interface.hをincludeしています。
Arduino/user_interface.h at master · esp8266/Arduino

---

152行目の

buf = (i == 0) ? shortbuf : obuf;
ここが，何をしているのかまったく理解できません．

i==0のときbufにshortbufを、そうでないときobufを代入しています。
そのbufを

LoRa_send(buf);

していますね。

ということはi==0のときはshortbufをLoRa_send()して、それ以外はobufをsend_LoRa()していますね。

Comments

[raspypy]

分かりやすい説明ありがとうございます。
>i==0のときはshortbufをLoRa_send()して、それ以外はobufをsend_LoRa()していますね。

ここなのですが，
どうして，i==0のときは，8桁文字列のshortbufで，
それ以外のときは，12桁文字列のobufにしているのでしょうか?
ここがよく理解できません．

[ozwk]

大前提なのですが、コードに書いてあるのは「何をしているか」で
「なぜそうしているか」は書いてないです。
したがっていくらコードだけ見ても「なぜそうしているか」は原則わかりません。

(なのでこの手の質問は「書いたやつに聞け」という答えが付きやすいです。)

[raspypy]

この場で的外れな質問をしてしまい，すみませんでした．

Answer 2

三項演算子というもんです。
それでぐぐってみれば、解説出てきますよ

Comments

[raspypy]

ありがとうございます。とても勉強になりました。
１つ私の理解を確認させてください。
152行目 i==0は常にFalseになる　（139行目～のfor文が終了したあと，iの値が0にセットされていないので）
変数bufには，obufの値が代入される

私の理解が正しいか分かりませんが，正しいとすると，
shortbufの値が変数bufに代入されることはないように思うのですが，なぜ，shortbufの値が用意されているのでしょうか?

[y_waiwai]

本当に i は０にはならないんでしょうか
よくかんがえましょう

[y_waiwai]

って、実際に走らせてみればわかるんじゃないの？

[raspypy]

for文の範囲を間違えて解釈していました．