Ecelvbaでデータを配列ないでforを用いて計算

Question

Excel 2013 VBAについての質問です。
シートのA1からD10までの範囲をDataTBという配列に格納してその中のデータをforを使って計算させるというものを作成しました。そのなかで以下のコーであると最後に一番最後のiの時なぜか１増えるのはなぜでしょう？

```
Dim LR As Long '最終行の取得
    LR = ws1.Cells(Rows.Count, 4).End(xlUp)
Dim dataTB As Variant
    dataTB = ws1.Range(ws1.Cells(1, 1), ws1.cels(LR, 4))
’シートの最終行が不定のためＬＲを使用
    
Dim i As Long
    For i = 2 To LR　'1行目はデータの題目を入れるため開けている
        dataTB(i, 4) = dataTB(i, 1) + dataTB(i, 2)
    Next i
  'i=LRのときにLRが（LR＋１）になってしまう。
  'これによりＬＲ行までしか配列がないため「インデックスがありません。」となってしまう。

```
上記のようになってしまう
例えばLR=10ならばi=10のとき配列dataTB(10,4)がdataTB(11,4)になる
要は配列最後のiが増えるのはなぜか
どうすれば治せるのかを知りたいです。
（個人的に自身の配列に対する知識不足な気がしますが、、）

Answer 1

Dim LR As Long '最終行の取得  
LR = ws1.Cells(Rows.Count, 4).End(xlUp)  

これだとD列の最終行の行番号ではなく、最終行のセルの値が代入されます。
最終行の行番号を取得するなら、下記でないと。

Dim LR As Long    '最終行の取得
LR = ws1.Cells(Rows.Count, 4).End(xlUp).Row

Dim i As Long
For i = 2 To LR  '1行目はデータの題目を入れるため開けている
    dataTB(i, 4) = dataTB(i, 1) + dataTB(i, 2)
Next i
'i=LRのときにLRが（LR＋１）になってしまう。 ←なりません。

For Nextを抜けてもLRの値が変化することはありません。(iは変化しますが。)
D列の最終行のセルの値がたまたま（LR＋１）だったのでしょう。

おまけ

セル範囲を配列に格納したとき、セル番地と配列のインデックスが一致するとは限りません。
（今回はセル範囲が1行目から始まってますのでまたまた一致しますが。）

LBound、UBound 関数でインデックスの最小値と最大値を取得したほうがいいでしょう。

サンプルコード

Public Sub test()
    Dim ws1 As Worksheet
    Set ws1 = ActiveSheet
    
    Dim LR As Long    '最終行の取得
    LR = ws1.Cells(Rows.Count, 4).End(xlUp).Row
    Dim dataTB As Variant
    dataTB = ws1.Range(ws1.Cells(2, 1), ws1.Cells(LR, 4)).Value '1行目はタイトルなので配列に含めない

    'セルの行番号と配列のインデックスが一致するとは限らないので
    'LBound関数で配列の最終インデックスを取得した方かいい。
    Dim i As Long
    For i = LBound(dataTB) To UBound(dataTB)  '1行目はデータの題目を入れるため開けている
        dataTB(i, 4) = dataTB(i, 1) + dataTB(i, 2)
    Next i
    
    '更新した配列を元に戻す
    ws1.Cells(2, 1).Resize(UBound(dataTB), UBound(dataTB, 2)).Value = dataTB
End Sub

Answer 2

LR = ws1.Cells(Rows.Count, 4).End(xlUp).Row

---

Sub test()
 Dim i
 For i = 1 To 10
 Next
 Debug.Print i   '11
End Sub

Answer 3

配列のサイズを1つ大きくすることで解決になるでしょうか。

dataTB = ws1.Range(ws1.Cells(1, 1), ws1.Cells(LR + 1, 4))
'dataTB = ws1.Range(ws1.Cells(1, 1), ws1.cels(LR, 4))

Comments

[Apoll047]

Emptyが返されてきます。
一応インデックスありなので成立していますがやはりiが1つ増加しています。
この現象の理由を知りたいです。

[TanakaHiroaki]

直接の回答になっていないですが、
For-Next ループ終了後　i = LR +1 となるのは仕様通りです。

[Apoll047]

確かに今思えばその通りですね、、
今気づきました。

このような場合さきほどご教授いただいたように配列の要素を一つ大きくしておけばよろしいのでしょうか？またはそのまま”LR”にしておいてインデックスなしでも問題ないのでしょうか？
また空白のセルを配列に格納した場合その配列の要素のは”Empty”という認識でよろしいのでしょうか？
以下サイトを参考にしたのですが配列を使用するのが初めてなものでしてよろしければご教授ください。
https://sugoikaizen.com/excelvba/9_316/

[TanakaHiroaki]

配列の要素を一つ大きくしなくてもjinojiさんの回答で解決するかもしれません。