Ocamlの型変換について

Question

前提・実現したいこと

以下のような数式を表すデータ型expを用意したとき、exp 型の数式の文字列表現を返す関数を作りたい。

type exp =
| Num of int
| Var of string
| Add of exp * exp
| Mul of exp * exp;;

発生している問題・エラーメッセージ

エラーメッセージ
This expression has type exp -> string
but an expression was expected of type exp

該当のソースコード

let rec string_of_exp v = function
| Num n -> string_of_int n
| Var x -> int_of_exp x
| Add (x,y) -> make_sum(string_of_exp (x+y))
| Mul (x,y) -> make_sum(string_of_exp (x*y));;

試したこと

型変換が上手くいってないのは分かるのですが、どこがおかしいのかよく分かりません。プログラムを直していただけると幸いです。

Comments

[ozwk]

https://teratail.com/questions/340550

こちらは解決しましたか？

Answer 1

すでに解決済みかもしれませんが、同じような方がいるかもしれないので回答します。

functionについて

OCamlのfunctionキーワードはlet f x = match x with ...のショートハンドです。
そのため、let rec string_of_exp v = function ...の引数vは不要です。

ご参考までに、以下のfとgは同じです。

let f x =
    match x with
    | None -> "None"
    | Some v -> v
let g = function
    | None -> "None"
    | Some v -> v

string_of_expを書く

以上の話を踏まえ、関数string_of_expの型を考えます。
欲しい関数はデータ型expをstringに変換する関数ですから、以下のような型の関数になります。

val string_of_exp : exp -> string

では、各パターンマッチでstringを返すように関数を書いていきましょう。

let rec string_of_exp = function
    | Num n -> (* n: int を string に変換する式 *)
    | Var v -> (* v: string を string に変換する式 *)
    | Add (x, y) -> (* x: exp, y: exp を string に変換する式 *)
    | Mul (x, y) -> (* x: exp, y: exp を string に変換する式 *)

引数がNumのときはstring_of_intでstringに変換します。

let rec string_of_exp = function
    | Num n -> string_of_int n

引数がVarのときは値がstringということでおそらく変数名でしょうから、そのまま返します。

let rec string_of_exp = function
    | Var v -> v

引数がAddのときは(値 + 値)と表示するか足し算した結果を表示するかによりますが、今回は「exp 型の数式の文字列表現」ということなので、前者とします。

let rec string_of_exp = function
    | Add (x, y) -> Printf.sprintf "(%s + %s)" (string_of_exp x) (string_of_exp y)

引数がMulのときもAddと同様に(値 * 値)と表示することにします。

let rec string_of_exp = function
    | Mul (x, y) -> Printf.sprintf "(%s * %s)" (string_of_exp x) (string_of_exp y)

以上をまとめて、string_of_expは以下のようになります。

let rec string_of_exp = function
    | Num n -> string_of_int n
    | Var v -> v
    | Add (x, y) -> Printf.sprintf "(%s + %s)" (string_of_exp x) (string_of_exp y)
    | Mul (x, y) -> Printf.sprintf "(%s * %s)" (string_of_exp x) (string_of_exp y)

参考情報

以下にpuroさんが書かれたコードにでてくるいくつかの式の型を書いておきます。
int_of_expやmake_sumがどういった関数なのか不明だったので、一部は関数名から想像した型を前提に書いています。

string_of_int n     (* string *)
int_of_exp x        (* int_of_exp: exp -> int なら int *)
(x+y)               (* x: exp, y: exp なので対応する + が定義されておらず、型エラー *)
make_sum (...)      (* make_sum: int list -> int なら int *)

注意点

わかりやすさを優先し、以上のstring_of_expは末尾再帰になっていません。
大きな式を文字列に変換しようとするとスタックオーバーフローする可能性があるので、そのときは何回かに分けて呼び出すか、関数を末尾再帰に書き直してください。

以上、お役に立てれば幸いです。