【Excel VBA】ブック開始から終了までインスタンスを保持したい。

Question

前提・実現したいこと

初めて投稿します。

Excel VBAについて質問です。
現在、依存の標準モジュールをクラスモジュールに書き換えています。
あるインスタンスをExcelの１つのブックの起動から終了まで生存させたいのですが、
どのようにしたら良いのでしょうか。

そのインスタンスが保持しているメンバ変数やメンバメソッドを
ブックが開いている間、常にそれらを使用したいと考えています。

適当なサンプルコードを提示頂けたら、幸いです。

Answer 1

クラスについては理解できているとして、

そのインスタンスが保持しているメンバ変数やメンバメソッドを

ブックが開いている間、常にそれらを使用したいと考えています。

標準モジュールにPublicで宣言したのと同様に、ブックが開いている間中どこからでもいつでも使用したいということなら、
標準モジュールの宣言部でPublicでインスタンスを生成すればいいでしょう。
下記のようにNewステートメントを付加すると宣言と同時にインスタンスを生成します。

標準モジュール

Option Explicit

Public cls1 As New Class1

クラスモジュール　クラス名 Class1

Option Explicit

Public X As Long
Public Y As Long
Public Z As Long

Public Function GetSum() As Long
    GetSum = X + Y + Z
End Function

例えばユーザーフォームから呼び出す場合

Private Sub CommandButton1_Click()

    cls1.X = 1
    cls1.Y = 2
    cls1.Z = 3

End Sub

Private Sub CommandButton2_Click()
    
    Debug.Print "Xは" & cls1.X & "、Yは" & cls1.Y & "、Zは" & cls1.Z
    Debug.Print "合計は" & cls1.GetSum

End Sub

Comments

[sanmaserver]

標準モジュールで作成したcls1は、どのように開放するのでしょうか。

[hatena19]

ブックが閉じる時に自動で解放されると思います。

VBA Set Obj = Nothing は必要か - t-hom’s diary
https://thom.hateblo.jp/entry/2015/12/20/135035

もし、不安なら、THisWorkbookモジュールのBeforeCloseイベントで解放しておけばいいでしょう。

Private Sub Workbook_BeforeClose(Cancel As Boolean)
Set cls1 = Nothing
End Sub

[sanmaserver]

ありがとうござます！
理解できました。
本当に助かりました。

Answer 2

クラスモジュールをClassと言う名称で作成して、ソースをコピペして下さい。
Testを動かすとクラスの感じが掴めると思います。
(標準モジュール)

Sub Test_Sample_Miniature()
    'クラス定義
    Dim ClassX As Class
    Dim ClassY As Class
    'オブジェクト作成
    Set ClassX = New Class
    Set ClassY = New Class
    '実行処理
    ClassX.glng数値X = 1500
    ClassX.glng数値Y = 100
    ClassX.gstr名称 = "ClassX"
    ClassX.計算処理
    ClassY.glng数値X = 12300
    ClassY.glng数値Y = 10000
    ClassY.gstr名称 = "ClassY"
    ClassY.計算処理
    MsgBox ClassX.gstr名称 & "と" & _
           ClassY.gstr名称 & "の合計は" & _
           Format(ClassX.glng数値Z + ClassY.glng数値Z, "#,##0")
    '終了
    Set ClassX = Nothing
    Set ClassY = Nothing
End Sub

(Classモジュール)名称Class

'プロパティ実装
Public glng数値X As Long
Public glng数値Y As Long
Public glng数値Z As Long
Public gstr名称 As String
'クラス変数実装
Dim lngWORK As Long
'関数実装
Function 計算処理()
    lngWORK = glng数値X * glng数値Y
    glng数値Z = lngWORK
    MsgBox Trim(gstr名称) & "クラスで計算しました ＝ " &　Format(lngWORK, "#,##0")
End Function

Comments

[sanmaserver]

ご回答ありがとうございます。