値を変更しながら、一括で印刷プレビューしたいです。

Question

前提・実現したいこと

VBAの値を変更しながら一括で印刷プレビューをしたいです。

発生している問題・エラーメッセージ

「試してみたこと」のように作成すると、変更後ごと毎回毎回印刷プレビューされます。
lgPositionの値が変更する度にシートの値が変わります。
それをすべて繋げて印刷プレビューしたいです。

印刷情報を保持しておく変数などあれば可能なのでしょうが・・・。
実現可否含めて教えていただけると幸いです。

該当のソースコード

言語：Excel VBA
ソースコード
Const lgStart As Long = 1
Const lgStep As Long = 1

lgEnd = lgHitCount
lgPosition = 1

Dim i As Long

With Application
    .ScreernUpdating = False
        For i = lgStart To longEnd Step lgStep
            Call PMNest 'lgPositionの値によって、シートに表示する値を変更する関数
            ActiveSheet.PrintPreview
            lgPosition = lgPosition + 1
        Next
    .ScreenUpdateing = True
End With

試したこと

ttps://excel.syogyoumujou.com/vba/printout_1.html

上記サイトを参考にプログラムを組みました。

Answer 1

ActiveSheet.PrintPreviewでは1シート分しかプレビューできませんので、それをFor文で繰り返した数だけプレビューが表示されます。

現状のシートを繰り返しコピー追加して値を変更して、追加したシート全体を一度にプレビューするようにします。
複数シートをプレビューする方法は下記を参考に。

複数シートの印刷（PrintOut）｜VBAサンプル集

---

取りあえずのサンプルコードです。
アクティブなシートを3回コピー追加してプレビューします。
３つ固定なので、コピー数を可変にしたい場合は、もう少し工夫が必要です。

Public Sub PreViewTest()

    Const lgStart As Long = 1
    Const lgStep As Long = 1

    Dim lgEnd As Long, lgPosition As Long
    lgEnd = 3    '取りあえず３つぶんプレビュー
    lgPosition = 1

    Dim ws As Worksheet
    Set ws = ActiveSheet
    
    Application.ScreenUpdating = False
    Application.DisplayAlerts = False

    Dim i As Long
    For i = lgStart To lgEnd Step lgStep
        ws.Copy After:=Worksheets(Worksheets.Count)    '末尾にシートをコピー
'        Call PMNest    'lgPositionの値によって、シートに表示する値を変更する関数
        ActiveSheet.Cells(1, 1) = i    '取りあえず追加コピーしたシートのA1に代入
        lgPosition = lgPosition + 1
    Next

    With Sheets(Array(Worksheets.Count - 2, Worksheets.Count - 1, Worksheets.Count))
        .PrintPreview '追加したシートをまとめてプレビュー
        .Delete       '追加したシートを削除
    End With

    Application.DisplayAlerts = True
    Application.ScreenUpdating = True
End Sub

Comments

[torimuneniku]

回答いただき、ありがとうございます。
今絶賛格闘中です・・。

同じSheetを指定しているからか、何度やっても最後の値変更分しか出てきません。
・mySht(UBound(mySht)) = Worksheets(i).Name
　↓書き換え
・mySht(UBound(mySht)) = Worksheets(1).Name

myShtにシートを代入する部分を、Worksheets(1)に変更しました。
（全く同じシートに値だけ変更しているので）

これだと以前のシートの内容は上書きされてしまうのでしょうか？
知識がなく申し訳ございません・・・。教えていただければ助かります。

[hatena19]

サンプルコードを回答に追記しましたので参考にしてください。

[torimuneniku]

ワークシートの後ろに追加していって、一気にプリントアウトする、というやり方ですね。

本日実装してみます。

サンプルコードまでつけていただいて、本当ご丁寧にありがとうございます。

[torimuneniku]

経過をお伝えするのが遅くなり申し訳ございませんでした・・。
いろいろあってバタバタしておりました。

その後、問題は解決できました！助かりました、ありがとうございました。