excel vba でautofilterのcriteriaを動的にして、処理を繰り返したい

Question

●最終的にやりたいこと
→下記のように、A列”使用者"でautofilterをかけ,フィルター後の状態をで 印刷や、"使用者"ごとにデータをメール送信したい（他の"使用者"のデータを見えないようにすることが必要になるので、ＰＤＦ保存や他シートに値で張り付けるなどが必要になると思われる）。

例えば、最初に
➀"勝村"でフィルターをかけ、”勝村"だけのデータを印刷し、フィルター解除。
➁"加藤"でフィルターをかけ、"加藤"だけのデータを印刷し、フィルター解除。
➂"木村"で～　
を繰り返したい。

●今回わからなくて困ってること
autofilterメソッドの引数criteria1の値（勝村の部分)を動的にして、次のフィルター候補に自動で変動するようにしたいです。（フィルター後の印刷やメール送信の処理はまだ書き方を知らず、これから調べるため割愛しております）

当然、"使用者"のデータは都度変更します。
となると、forループのループ回数の設定にも困ります。

もしくは、そもそもautofilterじゃない方法でいい方法があるのかどうか。

どなたかご教授いただけないでしょうか？
よろしくお願いいたします。

Dim i
for i = ? to ?
Cells(1, 1).autoFilter 1, "勝村"

'フィルター後の印刷や、メール送信の処理を書く
Cells(1, 1).autoFilter 'フィルター解除
Next i
End Sub

```Sub filter()
Dim i As Long
Dim ws, ws2 As Worksheet
Dim path As String
path = "E:\work\"
Set ws = Worksheets("sheet23")
Set ws2 = Worksheets.Add(after:=ws)
Dim c As Integer
c = 1
Dim result As Range
With ws.UsedRange
For i = 2 To .Rows.count
Set result = ws2.Columns(1).Find(what:=ws.Cells(i, 1))
If result Is Nothing Then
ws2.Cells(c, 1) = ws.Cells(i, 1)
.autoFilter 1, Cells(i, 1)
ws.ExportAsFixedFormat Type:=xlTypePDF, Filename:=path & ws.Cells(i, 1)
c = c + 1
End If
Next
End With
ws.AutoFilterMode = False
End Sub
コード

![イメージ説明](2012775f776b335d890db18e4d793949.png)

Answer 1

Sub Sample()

    Dim ws As Worksheet
    Set ws = Sheets("Sheet1")
    
    With ws.UsedRange
        Dim i
        For i = 2 To .Rows.Count
            .AutoFilter 1, .Cells(i, 1)
            '.Worksheet.PrintOut
            '.Worksheet.ExportAsFixedFormat xlTypePDF, .Cells(i, 1)
        Next
    End With
    ws.AutoFilterMode = False
    
End Sub

---

＜追記＞複数回登場する場合に初回のみ処理する判定を追加

    With ws.UsedRange
        Dim i
        For i = 2 To .Rows.Count
            If WorksheetFunction.Match(.Cells(i, 1), .Columns(1), False) = i Then
                .AutoFilter 1, .Cells(i, 1)
                '.Worksheet.PrintOut
                '.Worksheet.ExportAsFixedFormat xlTypePDF, .Cells(i, 1)
            End If
        Next
    End With

Comments

[robben]

jinoji様
早速ご回答ありがとうございます。早速ＰＤＦ保存したらできました。
でも、お恥ずかしいながら、疑問なのですが、
criteriaをcells(i,1)にしてループすると、同じ名前が複数ある場合（今回だと例えば　田中とか）、重複されてしまう（つまり同じ田中のデータが複数つくられてしまう）のかと思いました。実際、重複されないようなのですが、これはなぜでしょうか？
教えていただけると幸いです。

[jinoji]

重複して処理されています。
１回目の田中.pdfを２回目の田中.pdfが上書きしているので、
結果としては１ファイルだけができているように見えるということだと思います。

ただ、Printoutの方は複数ページ印刷されることになりますね・・・
もし複数ある場合には１回だけ処理する、としたい場合には、もう一工夫必要です。

[robben]

jinoji様
ありがとうございます。Matchを使うだけで、できてしまいますね。
初回のみ処理する方法を自分で考えたとき、一度、シートを追加して、そのシートの1列目(columns(1))に、すでに出た名前は転記しておき、次の名前が既に使われているかどうかを columns(1)の範囲でfindメソッドを使って、判定して、nothingだったら、処理を行うというやり方を思いつき、一応、できました。

ですが、jinojiさんが教えてくださった通り、matchを使って、見つかった一番上のセルの位置を返すというmatch関数を使う方が、コードが楽ですね。

ありがとうございました。
とても、参考になりました。