「For文を使ってA1～A5の値を配列(Array)に格納する。その後、その配列の３番目(A3)の値をB1に表示する。」のやり方を教えてほしい。

Question

「For文を使ってA1～A5の値を配列(Array)に格納する。その後、その配列の３番目(A3)の値をB1に表示する。」のやり方を教えてほしい。

そもそもコードはあっているか。（arrayに格納するとあるが、arrayは使っていない。。。）
A3の値と異なる値がB1に入力されるのはなぜ。（A5の値が入っていると思う）
エラー原因はなぜ。

追加質問
・arrayにforで取得したセルの値を入れることができれば解決できると思うが、やり方が分からないのでそれができるのであれば教えてほしいです。

例えば
for～nextで取得した値をarray()に一つずついれる方法

上記を教えてほしいです。

試したこと

'ここのコードはセルに値を入れるコード
Sub 問41rnd()

    Dim i As Integer
    
    Randomize
    
    Range("c2") = Int(Rnd * 10) + 1

    For i = 1 To 5
        Cells(i, "a") = Int(Rnd * 10) + 1
        
    Next i
    
    Range("A6") = WorksheetFunction.Sum(Range("A1:A5"))
    
    
End Sub

'試したこと１回目
'ここが題名（For文を使ってA1～A5の値を配列(Array)に格納する。その後、その配列の３番目(A3)の値をB1に表示する）のコード

Sub 問42forarray()
　　Dim a As Variant
    Dim i As Long
    
    
    
    For i = 0 To 4 '配列aにA1～A5の値を格納
        a = Cells(i + 1, 1)
        
        i = i + 1
        
    Next i
    
    Cells(1, "b") = a 'A3の値をB1に表示
        
    
    
End Sub

'試したこと２回目
Sub 問42forarray()

    Dim a As Variant
    Dim i As Long
    
    
    
    For i = 0 To 4 '配列aにA1～A5の値を格納
        a = Cells(i + 1, 1)
        
        i = i + 1
        
    Next i
    
    Cells(1, "b") = a(2) 'A3の値をB1に表示
        
    
End Sub

１回目の実行結果画像

２回目の実行結果画像

Answer 1

詳しい解説は先の回答を参照して頂ければわかると思います。

しかし、配列やarrayを使いこなすのは、難しいので単純なコピーでなく配列に格納する意図はなんでしょうか？

配列を使わない簡素なやり方をご提案できればと思います。

変数、配列、Arrayを混同されているようなので、一旦整理して頂いた方がいいかと思います。

ざっくりとした例えです。

変数　田中="はい"
独り身の田中さん　田中さんを呼べば返事してもらえる

配列　田中(0)="夫" 田中(1)="夫人"　
田中さん夫婦　田中さんを呼んでもどちらかわからないので返事してもらえない。

Array　田中=array("101号","102号","103号")等
アパート全員が田中さん　田中さんを呼んでも誰なのかわからないので返事してもらえない。

それぞれ、用途があるので、違いをしっかりと勉強して下さい。

Answer 2

相談者様のソースコードを見ると、「配列」と「Array関数」の区別ができていないように見受けられます。

配列は英訳すると確かに"Array"ですが、Excel VBAにおいて「配列」と「Array」は全く別物です。

配列の使用法

Dim i as Integer
Dim a(5) as Long               ' 要素数(5)が必要、型はLongで良い

For i=1 To 5
    a(i) = Cells(i, 1)
Next i

Cells(3, 2) = a(3)

要素数5の配列a(5)を宣言すると、a(0)～a(5)の領域が確保されます。
今回の場合、a(1)～a(5)を利用した方がスマートでしょう。

Array関数の使用法

Dim a as Variant               ' 要素数は不要、型はVariantにする必要がある

a = array(3, 4, 10, 4, 5)      ' a(0)=3, a(1)=4, a(2)=10, a(3)=4, a(4)=5

cells(3,2) = a(2)              ' 3番目の要素はa(2)に格納されている

Array関数を利用する場合、代入先aの型はVariantにしなければなりません。
またArray関数を利用した場合、値はa(0)から順番に代入されます。

相談者様のケースでは、セルA1~A5に値が入っているため、「配列」を利用することになります。

「試したこと1回目」は以下のようになっています。

For i = 0 To 4 '配列aにA1～A5の値を格納
    a = Cells(i + 1, 1)

    i = i + 1
Next i

この場合aの値を毎回上書きしています。
a = Cells(1, 1)
a = Cells(3, 1)
a = Cells(5, 1)
ついでにいえば、i=i+1は不要です(Next iの行でi=i+1の処理をやっているため)。
この結果、Cells("b", 1) = aではcells(5, 1)の値が代入されます。

「試したこと2回目」では、配列ではない変数aの「要素」a(2)を参照しようとしています。
変数aと配列変数a(2)では「型」が違うので、「型が一致しません」とのエラーが表示されます。

説明が長くなりましたが、結論として配列とArray関数は別ものと捉えていただければと思います。

Answer 3

Sub 問42forarray()

    Dim a(4) As Variant
    Dim i As Long

    For i = 0 To 4 '配列aにA1～A5の値を格納
        a(i) = Cells(i + 1, 1)
    Next i

    Cells(1, "B") = a(2) ' その配列の３番目(A3)の値をB1に表示

End Sub