VBAにて複数CSVを1ブックの複数シートにまとめたい

Question

タイトルの通りですが、複数のCSVファイルを1つのブック内の複数シートに貼り付けたいと思っています。

フォルダ・ファイルは以下の通り仮定します。
C:\temp
Hitotsume_sjis.csv (カンマ区切り、数列ぐらい、2万行ぐらい、SJIS)
Futatsume_utf8.csv (カンマ区切り、数列ぐらい、2万行ぐらい、UTF-8)
Mittsume_utf8.csv (カンマ区切り、数列ぐらい、2万行ぐらい、UTF-8)
※それぞれ半角英数字だけの列もあれば、全角文字がある列もあります。

同一フォルダに
Torikomi.xlsmというExcelブックを置いて、マクロを記載していきたいです。

Torikomi.xlsmには初期状態でWKシートとBetsuシートの2シートがある状態で、
WKシート上にボタンを配置し、そのボタン押下で動作させたいと考えています。

Betsuシートは取り込んだ後に使いたい関数が入っているシートなので、変更したくないです。

このTorikomi.xlsm上のWKシートにあるボタンを押下して
Hitotsume_sjisシート、Futatsume_utf8シート、Mittsume_utf8シートを自動生成し
それぞれのシート上にそれぞれのCSVの内容を文字化けさせず貼り付けたいです。

サンプルコードを記載していただけないでしょうか。

取り込みだけ、であるとか　文字コード指定、という情報は見つけ出せたのですが、
まとめたものを作成すると上手くいかず、困りましたので質問させていただきます。

よろしくお願いいたします。

Comments

[meg_]

> まとめたものを作成すると上手くいかず
そのコードを載せましょう。どこまで出来ていて、どこが出来ないのでしょうか？

Answer 1

サンプル作ってみました。

Sub Sample()
Dim oSheet As Object
Dim vName As Variant
vName = Array("Hitotsume_sjis", "Futatsume_utf8", "Mittsume_utf8")

Dim i As Long
'シート追加
For i = 0 To 2
    DoEvents
    Set oSheet = Worksheets.Add(After:=Worksheets(Worksheets.Count))
    oSheet.Name = vName(i)
Next i

Dim j As Long
Dim sLine As String
Dim vString As Variant
Dim oStream As Object
Const adTypeText As Long = 2
Const adReadLine As Long = -2

Application.ScreenUpdating = False
For i = 0 To 2
    DoEvents
    j = 1 '書き出す最初の行
    Set oStream = CreateObject("ADODB.Stream")
    With oStream
    .Type = adTypeText
    If i = 0 Then
        .Charset = "Shift_JIS"
    Else
        .Charset = "UTF-8"
    End If
    .Open
    .LoadFromFile ("C:\temp\" & vName(i) & ".csv")
    Do While Not (.EOS)
        DoEvents
        sLine = .ReadText(adReadLine)
        vString = Split(sLine, ",")
        With Worksheets(vName(i))
        .Range(.Cells(j, 1), .Cells(j, UBound(vString) + 1)) = vString
        End With
        Application.StatusBar = vName(i) & ", " & j
        j = j + 1
    Loop
    .Close
    End With
Next i
Application.ScreenUpdating = True
Application.StatusBar = False
Worksheets(vName(0)).Activate
End Sub

Comments

[a802]

回答ありがとうございます。
記載情報が足りておらず申し訳ありませんでした。

こちらを参考に、進めてまいります。