VBA エラーの原因：RangeクラスのSelectメソッドが失敗しました

Question

If MsgBox("本日分作成しますか？", vbQuestion + vbOKCancel) = vbCancel Then
   MsgBox "終了します。"
   Exit Sub
End If

ActiveSheet.Select
ActiveSheet.Copy Before:=ActiveSheet

Dim Sname As String
Sname = Now
ActiveSheet.Name = Format(Sname, "m.d")

Dim Nengetu As Date
Nengetu = Now
Range("A2").Select
ActiveCell.FormulaR1C1 = Format(Nengetu, "ggge年　m月　d日(aaa)")

Dim tomorrow As Date
tomorrow = Now + 1
Range("G2").Select
ActiveCell.FormulaR1C1 = Format(tomorrow, "ggge年　m月　d日(aaa)")

 Range( _
        "S4:S5,S8:S20,S23:S26,S29:S31,S34:S49,V4:V10,V13:V17,V20:V27,V30:V37,V40:V49,Y4:Y10,Y13:Y17,Y20:Y35,Y38:Y49,AB4:AB14,AB17:AB18,AB21:AB35,AB38:AB49,AE4:AE24,AE27:AE41,AE44,AE47:AE49,AH4:AH49" _
        ).Select
    Range("AH4").Activate
    Range( _
        "S4:S5,S8:S20,S23:S26,S29:S31,S34:S49,V4:V10,V13:V17,V20:V27,V30:V37,V40:V49,Y4:Y10,Y13:Y17,Y20:Y35,Y38:Y49,AB4:AB14,AB17:AB18,AB21:AB35,AB38:AB49,AE4:AE24,AE27:AE41,AE44,AE47:AE49,AH4:AH49,AK4:AK49" _
        ).Select
    Range("AK4").Activate
    Selection.ClearContents

Range("G4:L43").Copy Range("A4:F43")

Range("P4:P30").Copy
Range("O4:O30").PasteSpecial xlPasteValues
Range("O4:O30").PasteSpecial xlPasteFormats
Application.CutCopyMode = False

Range("A1").Select

End Sub

Private Sub CommandButton2_Click()

If MsgBox("今月分作成しますか？", vbQuestion + vbOKCancel) = vbCancel Then
   MsgBox "終了します。"
   Exit Sub
End If

   Worksheets(Array("はじめ", "原紙")).Move Before:=Worksheets(3)
    
     Dim LOOP_CNT    As Long
     Dim PAGE_CNT    As Long
     
     PAGE_CNT = Worksheets("原紙").Index + 2
     Application.DisplayAlerts = False 
     For LOOP_CNT = Worksheets.Count To PAGE_CNT Step -1
         Worksheets(LOOP_CNT).Delete
     Next
     Application.DisplayAlerts = True 
     
     Worksheets(5).Move Before:=Worksheets(3)
     
      Dim Sname As String
      Sname = Now
      ActiveSheet.Name = Format(Sname, "m.d")
     
      Dim Nengetu As Date
      Nengetu = Now
      Range("A2").Select
      ActiveCell.FormulaR1C1 = Format(Nengetu, "ggge年　m月　d日(aaa)")

      Dim tomorrow As Date
      tomorrow = Now + 1
      Range("G2").Select
      ActiveCell.FormulaR1C1 = Format(tomorrow, "ggge年　m月　d日(aaa)")

      Range("G4:L43").Copy Range("A4:F43")
      
      Range("O4:O30").ClearContents

      Worksheets.Copy
      b = "連絡書" '
      c = Format(Now(), "(yyyy年mm月)")
      d = b & c & ".xlsm"
      e = ThisWorkbook.Path & "\" & d
      ActiveWorkbook.SaveAs Filename:=e, FileFormat:=xlOpenXMLWorkbookMacroEnabled

      Sheets(3).Activate
      Range("A1").Select
      
      Application.DisplayAlerts = False 
      ThisWorkbook.Close
End Sub

現在上記のコードを使用しています。
今まで標準モジュールで使っていたコードをそのままコマンドボタンに設定したらエラーが出るようになりました。エラーが出るようになった理由と対策を教えてください。
Range("A2").Select、Range("A1").Selectのところでエラーが出ます。

Comments

[jinoji]

どの行で発生したかがわからないので確かなことは言えませんが、おそらくRangeクラスのSelectメソッドが失敗したのではないでしょうか。

[321Kurumins]

エラー行は質問に追記しました。
どうやって対策したらいいいんでしょう？

[jinoji]

私の場合、基本的に以下のことを気を付けています。

・Rangeオブジェクトは、極力シート名をつける ・・・ws.Range("A1")
　（どのシートのRangeなのかを意識し、コード上も明確にする）

・シートオブジェクトは変数にセットする
　Activesheetは途中の操作によって別のものに変わることもあるので、
　Set ws = Activesheet としておいて、以降は ws を使う、など

・RangeのSelectメソッドは極力使わない
　大抵の場合、使わなくても書ける
　マクロの記録でコードを生成するとSelectが頻出するが、そのままで使うのでなくなるべく消していく

[321Kurumins]

なるほど。勉強になります。
なるべく変数にセットしてわかりやすいように改善してみます。

Answer 1

Dim Nengetu As Date
Nengetu = Now
Range("A2").Select
ActiveCell.FormulaR1C1 = Format(Nengetu, "ggge年　m月　d日(aaa)")

 Range("A2").Select

↑ここでエラーが出ていると思います。

標準モジュールにこのコードを書くと、
「アクティブなシートのA2セル」と解釈されます。
一方、シートのモジュールに書くと、
「そのモジュールのA2セル」と解釈されます。

セルを選択する命令をしたときに、
解釈されたシートが、アクティブになってなければ、セルを選択できないので、
エラーになります。
場当たり的にエラーを回避するならば、
Activesheet.Range("A2").Select
と書けば回避できるとは思いますが、
後で（数か月後または数年後に）読んだときに、どのシートの話か分かりにくくなるので、
複数のシートを扱うときは、どのシートのどのセルなのかをちゃんと書いた方がよいかと
思います。

Option Explicit

Private Sub CommandButton2_Click()
    Dim wbkNew As Workbook
    Dim dtmToday As Date
    Dim sFName As String
    
    ThisWorkbook.Worksheets(Array("はじめ", "原紙")).Copy   '雛形をコピーして新規ブックへ
    Set wbkNew = Workbooks(Workbooks.Count)                 '新しくできたブックを取得
    dtmToday = Date                                         '今日の日付を取得
    
    '日付を記入
    With wbkNew.Worksheets("はじめ")
        .Name = Format(dtmToday, "m_d")
        .Range("A2").Value = dtmToday
    End With

    '保存するファイル名を作成
    sFName = ThisWorkbook.Path & "\" & "連絡書" _
                & Format(dtmToday, "(yyyy年mm月)") & ".xlsm"
                
    '名前を付けて保存
    wbkNew.SaveAs sFName, xlOpenXMLWorkbookMacroEnabled

    'このブックを閉じる
    ThisWorkbook.Close
End Sub

こんな感じで書いてみてはいかがでしょう？
あくまで参考です。そちらのコードを修正したわけではありません。
コードを読んで分かるとこに想像で補完して書いてます。

Comments

[321Kurumins]

ありがとうございます。
参考にして修正したらうまくいきました。