VBAでメールを作成し、オートフィルターで選択したデータを特定の位置に貼付したい

Question

前提・実現したいこと

VBAでOutlookメールを作成し、特定の場所に表を挿入したいです。
表の詳細ですが、氏名・会社名・請求金額のリストが別シート（個別リスト）であり、
氏名でオートフィルターを選択し、個人別に作成したメールへ、
該当者のデータを貼付していきたいという内容です。

シートの構成は、
① メール作成のもとになるシート

② 上記表のもとになる、シート

オートフィルターで選択する対象は、①のK列に記載の氏名の方になり、
同一の氏名のメールに表を貼付する形にしたいです。

発生している問題・エラーメッセージ

メール作成まではできているのですが、表貼付のコードがわかりません。

該当のソースコード

Sub MsgfileSave()

'一覧の最終行取得
Dim maxRow As Long
maxRow = Cells(Rows.Count, 1).End(xlUp).Row

'リスト行数分メール送信処理を実施
Dim i As Long

For i = 4 To maxRow

'Outlookオブジェクトの変数宣言
Dim outlookObj As Outlook.Application
Set outlookObj = New Outlook.Application

'メール送信用のオブジェクト作成　本文はメールFMTを使用
Dim mailObj As Outlook.MailItem
Set mailObj = outlookObj.CreateItemFromTemplate(Cells(2, 3).Value)

With mailObj
.SentOnBehalfOfname = Cells(4, 2).Value 'FROM
.To = Cells(i, 5).Value 'TO
.CC = Cells(i, 6).Value 'CC
.BCC = Cells(i, 7).Value 'BCC
.Subject = Cells(i, 4).Value '件名

'添付ファイル1の記載があれば、指定ファイルを添付
If Cells(i, 9).Value = "" Then
Else

.Attachments.Add Cells(2, 9).Value & "" & Cells(i, 9).Value 'ファイル添付
End With

'Msg形式で保存
mailObj.SaveAs Cells(2, 8).Value & "" & Cells(i, 8).Value

Next i

MsgBox "MsgFile作成完了"

End Sub

試したこと

補足情報（FW/ツールのバージョンなど）

Answer 1

Excelの表をOutlookの本文に埋め込む方法としては以下のURLのマクロが参考になると思います。
https://outlooklab.wordpress.com/2019/09/07/excel-%e3%81%ae%e3%83%87%e3%83%bc%e3%82%bf%e3%82%92-outlook-%e3%81%ae%e6%9c%ac%e6%96%87%e3%81%ab%e8%a1%a8%e3%81%a8%e3%81%97%e3%81%a6%e3%82%b3%e3%83%94%e3%83%bc%e3%81%99%e3%82%8b%e3%83%9e%e3%82%af/

Public Sub CopyTableToMail()
     ' 転記する Excel ファイルの列の開始位置
     Const COL_START = 1
     ' 転記する Excel ファイルの列の数
     Const NUM_COLS = 5
     ' 転記する Excel ファイルの行の開始位置
     Const ROW_START = 1
     ' 転記する Excel ファイルの行の数
     Const NUM_ROWS = 10
     ' Outlook の定数
     Const olMailItem = 0
     Const olFormatRichText = 3
     '
     Dim appOlk As Object ' Outlook.Application
     Dim objItem As Object ' Outlook.MailItem
     Dim wrdEditor As Object ' Word.Document
     Dim wrdTable As Object ' Word.Table
     Dim wrdRange As Object ' Word.Range
     Dim iCol As Integer
     Dim iRow As Integer
     ' Outlook の Application オブジェクトを取得
     Set appOlk = CreateObject("Outlook.Application")
     ' 新規アイテムを作成
     Set objItem = appOlk.CreateItem(olMailItem)
     '
     objItem.BodyFormat = olFormatRichText
     ' 新規アイテムの WordEditor オブジェクトを取得
     Set wrdEditor = objItem.GetInspector().WordEditor
     ' WordEditor にフォーカス設定
     wrdEditor.Activate
     ' 表の挿入位置を取得
     Set wrdRange = wrdEditor.Application.Selection.Range
     ' 本文に表を挿入
     Set wrdTable = wrdEditor.Tables.Add(wrdRange, NUM_ROWS, NUM_COLS)
     '
     With wrdTable
         ' 表のスタイルを指定
         .Style = "表 (格子)"
         ' 表の [タイトル行] をオン
         .ApplyStyleHeadingRows = True
         ' 表の [集計行] をオン
         .ApplyStyleLastRow = False
         ' 表の [最初の列] をオン
         .ApplyStyleFirstColumn = True
         ' 表の [最後の列] をオン
         .ApplyStyleLastColumn = False
         ' 表の [縞模様 (行)] をオン
         .ApplyStyleRowBands = True
         ' 表の [縞模様 (列)] をオフ
         .ApplyStyleColumnBands = False
         ' Excel の表のデータを本文のテーブルに転記
         For iCol = 1 To NUM_COLS
             For iRow = 1 To NUM_ROWS
                 ' .Cell は本文の表のセル
                 ' Cells は Excel の表のセル
                 .Cell(iRow, iCol).Range.Text = _
                     Cells(ROW_START + iRow - 1, COL_START + iCol - 1).Value
             Next
         Next
     End With
     ' 表を挿入したアイテムを表示
     objItem.Display
End Sub