Unity2Dでシェーダーに2つめのスプライトを渡したい

Question

■やりたいこと
シェーダーのスクリプトに_MainTexとはもう1つ別の_SubTexを定義して渡したい。

GameObjectは以下のようにSpriteRendererのみアタッチされています。
ここで_MainTexは自動的にSpriteRenderer.spriteが使われますが、
_SubTexに他のスプライトを渡すにはどうすればよいのでしょうか？

Shader "Sprites/SpriteUnion"
{
    Properties
    {
        [PerRendererData] _MainTex ("Main Texture", 2D) = "white" {}
        [PerRendererData] _SubTex ("Sub Texture", 2D) = "white" {}
        [PerRendererData] _AlphaTex ("External Alpha", 2D) = "white" {}
        _Color ("Tint", Color) = (1,1,1,1)
    }

    SubShader
    {
        Tags
        {
            "Queue"="Transparent"
            "IgnoreProjector"="True"
            "RenderType"="Transparent"
            "PreviewType"="Plane"
            "CanUseSpriteAtlas"="True"
        }

        Cull Off
        Lighting Off
        ZWrite Off
        Blend One OneMinusSrcAlpha

        Pass
        {
        CGPROGRAM
            #pragma vertex vert
            #pragma fragment frag
            #pragma target 2.0
            #pragma multi_compile_instancing
            #pragma multi_compile _ PIXELSNAP_ON
            #pragma multi_compile _ ETC1_EXTERNAL_ALPHA
            #include "UnitySprites.cginc"

            sampler2D _SubTex;

            fixed4 SampleSpriteTextureMain (float2 uv)
            {
                fixed4 color = tex2D (_MainTex, uv);

            #if ETC1_EXTERNAL_ALPHA
                fixed4 alpha = tex2D (_AlphaTex, uv);
                color.a = lerp (color.a, alpha.r, _EnableExternalAlpha);
            #endif

                return color;
            }

            fixed4 SampleSpriteTextureSub (float2 uv)
            {
                fixed4 color = tex2D (_SubTex, uv);

            #if ETC1_EXTERNAL_ALPHA
                fixed4 alpha = tex2D (_AlphaTex, uv);
                color.a = lerp (color.a, alpha.r, _EnableExternalAlpha);
            #endif

                return color;
            }

            v2f vert(appdata_t IN)
            {
                v2f OUT;

                UNITY_SETUP_INSTANCE_ID (IN);
                UNITY_INITIALIZE_VERTEX_OUTPUT_STEREO(OUT);

                OUT.vertex = UnityFlipSprite(IN.vertex, _Flip);
                OUT.vertex = UnityObjectToClipPos(OUT.vertex);
                OUT.texcoord = IN.texcoord;
                OUT.color = IN.color * _Color * _RendererColor;

                #ifdef PIXELSNAP_ON
                OUT.vertex = UnityPixelSnap (OUT.vertex);
                #endif

                return OUT;
            }

            fixed4 frag(v2f IN) : SV_Target
            {
                fixed4 c = SampleSpriteTextureMain (IN.texcoord) * IN.color;
                fixed4 sc = SampleSpriteTextureSub (IN.texcoord) * IN.color;
                c.rgb *= c.a;
                return c;
            }
        ENDCG
        }

    }
}

Answer 1

スプライトオブジェクトにもう一つスクリプトをアタッチして、それに_SubTexをセットさせるというのはどうでしょうか?
アタッチするスクリプトとしては、たとえば下記のようなものはいかがでしょう。

using UnityEngine;

[ExecuteAlways]
[RequireComponent(typeof(Renderer))]
public class SubTextureProvider : MonoBehaviour
{
    private static readonly int SubTexProperty = Shader.PropertyToID("_SubTex");

    // インスペクター上で（または別のスクリプトから）
    // ここに_SubTexにセットしたいテクスチャをセットしておく
    public Texture subTexture;
    
    private MaterialPropertyBlock propertyBlock;
    private new Renderer renderer;

    private void LateUpdate()
    {
        // rendererが未取得ならば取得し...
        this.renderer ??= this.GetComponent<Renderer>();

        // propertyBlockが未生成なら生成し...
        this.propertyBlock ??= new MaterialPropertyBlock();

        // rendererから現在のプロパティブロックの内容を取得し...
        this.renderer.GetPropertyBlock(this.propertyBlock);

        // _SubTexにセットされているテクスチャがsubTextureと同一なら
        // 再設定は不要なのでここで処理を終え...
        if (this.propertyBlock.GetTexture(SubTexProperty) == this.subTexture)
        {
            return;
        }

        // 再設定が必要ならsubTextureを_SubTexにセットする
        this.propertyBlock.SetTexture(SubTexProperty, this.subTexture);
        this.renderer.SetPropertyBlock(this.propertyBlock);
    }
}

Comments

[yrema]

ありがとうございます。試してみます。