指定の列の空白でないセルを別シートにコピーしたい

Question

VBAで、シート「test2」に記載している値を別のシート「本日」に記載したいと思っています

コピー元：シート「test2」のC7からC28で、空白ではない値
C7:AAA
C8:BBB
C9:(null)
C10:CCC
C11:DDD
C12:EEE
C13:(null)
C14:FFF

各セルには上記のように入っています

コピー先：シート「本日」のc13から下

C13:AAA
C14:BBB
C15:CCC
C16:DDD
C17:EEE
C18:FFF

上記のようにしたと考えています

コードを以下のように記載したのですが、
コピー元とコピー先のシートが同じになってしまいます
（コピー元の値が、「test2」のc13から張り付けられてしまいます）

どのように修正すればよいかお分かりになられるかた、
修正方法をご教授できませんでしょうか。

Sub T111()

Dim wb0 As Workbook

Dim UST1 As Long
Dim UST2 As Long
Dim ws0 As Worksheet, ws1 As Worksheet,

Set wb0 = ThisWorkbook

Set ws0 = wb0.Worksheets("本日")
Set ws1 = wb0.Worksheets("test2")

UST1 = 13
With Worksheets("test2")
For UST2 = 7 To .Cells(Rows.Count, 3).End(xlUp).Row
If .Cells(UST2, 3).Value <> "" Then '
.Cells(UST2, 3).Copy
Worksheets("本日").Select
.Cells(UST1, 3).PasteSpecial Paste:=xlPasteValues
UST1 = UST1 + 1
Worksheets("test2").Select
End If
Next UST2
Application.CutCopyMode = False
End With

End Sub

Answer 1

With の意味が理解できていないようです。

With Worksheets("test2")
    

    .Cells(UST1, 3).PasteSpecial Paste:=xlPasteValues

End With

は

Worksheets("test2").Cells(UST1, 3).PasteSpecial Paste:=xlPasteValues

という意味になります。ですので、「test2」に貼り付けられます。
その前の Worksheets("本日").Select は意味ないです。

    Set ws0 = wb0.Worksheets("本日")
    Set ws1 = wb0.Worksheets("test2")

とシートを変数に代入しているのなら、それを使うと読みやすいコードになります。
対象シートを明示できますので、Selectも不要になります。

Sub T111()

    Dim wb0 As Workbook
    Dim UST1 As Long
    Dim UST2 As Long
    Dim ws0 As Worksheet, ws1 As Worksheet

    Set wb0 = ThisWorkbook

    Set ws0 = wb0.Worksheets("本日")
    Set ws1 = wb0.Worksheets("test2")

    UST1 = 13

    For UST2 = 7 To ws1.Cells(Rows.Count, 3).End(xlUp).Row
        If ws1.Cells(UST2, 3).Value <> "" Then    '
            ws1.Cells(UST2, 3).Copy
            ws0.Cells(UST1, 3).PasteSpecial Paste:=xlPasteValues
            UST1 = UST1 + 1
        End If
    Next UST2
    Application.CutCopyMode = False

End Sub

別案

SpecialCells(xlTextValues) で空白セル以外の範囲を指定できるので、それをコピーして貼り付ければループする必要はないです。

Sub T111()

    Dim ws0 As Worksheet, ws1 As Worksheet
    With ThisWorkbook
        Set ws0 = .Worksheets("本日")
        Set ws1 = .Worksheets("test2")
    End With
    
    ws1.Range(ws1.Cells(7, 3), ws1.Cells(Rows.Count, 3).End(xlUp)) _
                              .SpecialCells(xlTextValues).Copy
    ws0.Cells(13, 3).PasteSpecial Paste:=xlPasteValues
    
    Application.CutCopyMode = False

End Sub

Comments

[amatsuno]

ありがとうございます。
別案に記載の方法で動作できました。