テキストボックスの入力文字数に上限を設定したいが、半角全角が混じっていた場合は…?（VBAユーザーフォーム）

Question

Excel2016 32bit版

お世話になります。
ビジネスホンへの電話帳登録をVBAで書いています。
相手先名の入力が全角10文字・半角20文字までという制限があるため、テキストボックスの入力文字数に上限を設けたつもりです。

Private Sub TextBox1_Change()
  Dim convFromUcode As String
  Dim leftFromUcode As String
  convFromUcode = StrConv(TextBox1.Text, vbFromUnicode)
  leftFromUcode = LeftB(convFromUcode, 20)
  TextBox1.Text = StrConv(leftFromUcode, vbUnicode)
End Sub

架空の [株式会社川崎ｲﾝﾀﾞｽﾄﾘｰｽﾞ] を入力すると20byteまで表示されますが、

")"を半角にして [株)川崎ｲﾝﾀﾞｽﾄﾘｰｽﾞ本社] を入力すると、最後の"社"の半分までと言いますか中途半端な表示となってしまいます。

LeftBで20と決めずに、20番目のバイト数を判定して2byteなら19にしたいと考えています。

leftFromUcode = LeftB(convFromUcode, 20)  '20と決め打ちしたくない

20文字目というか LenBの20番目が半角か全角かを判定する方法がわかればと以下のようにしてみましたが、"不明"が出るばかりです…。

Private Sub TextBox1_Change()
'注意 これは動きません

  Dim convFromUcode As String
  Dim leftFromUcode As String
  Dim midFromUcode
  Dim tmp as Integer
  convFromUcode = StrConv(TextBox1.Text, vbFromUnicode)
  If LenB(convFromUcode) > 20 Then
    midFromUcode = MidB(convFromUcode, 20, 1)　　　　　　　　'20番目?
    If midFromUcode = StrConv(midFromUcode, vbNarrow) Then
      tmp = 20
    ElseIf midFromUcode = StrConv(midFromUcode, vbWide) Then
      tmp = 19
    Else
      MsgBox "不明"
    End If
    leftFromUcode = LeftB(convFromUcode, tmp)
    TextBox1.Text = StrConv(leftFromUcode, vbUnicode)
  End If
End Sub

どうかお知恵をお貸しください。

Comments

[yo_u]

全角、半角の判定方法の前に、どうして”不明”になるのか調べてはどうでしょう。
実際に、StrConv(midFromUcode, vbNarrow)がどういう値になっているのか、
StrConv(midFromUcode, vbWide)がどういう値になっているのか調べてみれば
原因がわかるような気がするのですが。。。

[arakuman]

その前の段階で、MidB(convFromUcode, 20, 1) を Debug.Print させても何も表示されず、ローカルウィンドウでは "" なので、MidB で20文字目を判定するのは無理なのかもしれません。
1文字ずつ数えて足していく方向で考え直してみます。ありがとうございました。

Answer 1

ご指摘いただいたサロゲートペア文字の判定は入っていないのですが、先頭から1文字ずつ数えて20byteを超えないかどうかは判定できるようになりました。
…もっと勉強します。

Private Sub TextBox1_Change()
    '全角10文字 or 半角20文字の入力制限
    'サロゲートペア文字には非対応
    Dim s As String: s = TextBox1.Text
    Dim convFromUcode As String
    Dim midFromUcode As String
    Dim leftFromUcode As String
    Dim cnt As Integer
    Dim i As Integer
    convFromUcode = StrConv(s, vbFromUnicode)
    If LenB(convFromUcode) > 20 Then
        cnt = 0
        For i = 1 To Len(s)
            midFromUcode = Mid(s, i, 1)
            '全角
            If Len(midFromUcode) <> LenB(StrConv(midFromUcode, vbFromUnicode)) Then
                If cnt + 2 <= 20 Then
                    cnt = cnt + 2
                Else
                    Exit For    '20を超えそうならForを抜ける
                End If
            '半角
            Else
                If cnt + 1 <= 20 Then cnt = cnt + 1
            End If
        Next
        leftFromUcode = LeftB(convFromUcode, cnt)
        TextBox1.Text = StrConv(leftFromUcode, vbUnicode)
    End If
End Sub

Answer 2

leftFromUcode = LeftB(convFromUcode, 20) '20と決め打ちしたくない

この部分ですが、
ちょっと長くなりますが・・・。

leftFromUcode = Right(convFromUcode, 1) ' 文字列の右側から一文字取得
詳しくは、https://www.tipsfound.com/vba/05right を見てください。

最後の文字を取得するだけでは問題は解決しないです。

サロゲートペア文字を判定して、頭から文字数をカウントするのが必要だと思います。

Comments

[arakuman]

御回答ありがとうございます。
恥ずかしながらサロゲートペア文字というのは初めて聞きました。これは1文字＝4bytesということですね。
ループを回して文字数を足し算という方向で考えてみます。