VBAでシート上のImageに画像を挿入したい(関数は標準モジュール内)

Question

行いたいこと
タイトルのことを行いたいです。

手順
手順１．「Sheet2」シートにて挿入➝Active Xコントロール➝イメージをクリックし、イメージをエクセル上に作成。
手順２．次のtest関数を実行し「Sheet2」シートに画像を挿入。

困っていること
手順２の関数についてです。

VBAの(標準モジュールではないほうです)「Sheet2」に次の関数を記載し実行するとBMP画像がImage1に挿入されます。

Public Sub test()
    Dim Pic As Object
    Set Pic = LoadPicture("bmp画像ファイルのパス")
    Image1.Picture = Pic
End Sub

この関数を「Sheet2」のところに記載はせず、
標準モジュール「Module1」に記載し実行できるようにしたいと思っています。
この処理以降にImage型で処理していきたいと考えています。
次のように試しましたが、「オブジェクト変数またはWithブロック変数が設定されていません。」
と表示され困っています。どなたかご教示いただけますと幸いです。

Public Sub test()
    Dim Pic As Object
    Set Pic = LoadPicture("bmp画像ファイルのパス")
    Dim Img As Image
    Img.Picture = Pic
End Sub

Answer 1

他の方のご回答にもありますがImgが標準モジュールから見えないからです。
この方法がよいかどうかは別ですが、問題を解決するにはImage1を渡してやればいいです。

Public Sub test(Img As Image)
    Dim Pic As Object
    Set Pic = LoadPicture("bmp画像ファイルのパス")
    'Dim Img As Image
    Img.Picture = Pic
End Sub

呼び出すときはこんな感じかな

call test(Image1)

ただfunctionにしてLoadPictureを返せばいいだけなような気もする。

Public Function test() As Object
    Dim Pic As Object
    Set Pic = LoadPicture("bmp画像ファイルのパス")
    Set test = Pic
End Sub

呼び出し

Image1.Picture = test

ここまできたら直接LoadPicture書けばよくね？ってなる。

Image1.Picture = LoadPicture("bmp画像ファイルのパス")

特に検証はしていません。思い付きで書いています。

Comments

[SkyRocket]

ご回答頂きありがとうございます！
参考になるコードをいくつかご記載頂き、とても参考になりました。

Answer 2

Active Xコントロールのイメージに対する処理だとすると

    Dim Img As Image
    Img.Picture = Pic

SkyRocketさん提示のこのコードでは「Img」が何処の誰なのかがわかりません。
Sheet1.Image1.Picture
のようにSheet1のImage1と指定して誰を指しているかを明確にする必要があります。

Comments

[SkyRocket]

ご回答頂きありがとうございます！
何故できないのかの理由や、指定の仕方をご記載頂き、参考になりました。

Answer 3

私の場合は、Pictures.Insertメソッドを使っています。

Sub Macro7()
    With ActiveSheet.Pictures.Insert("C:\Work\Sample1.jpg")
        .Top = Range("B3").Top
        .Left = Range("B3").Left
    End With
End Sub

他にShape.AddPictureメソッドを使う方法

Sub AddPictureSampLinkPaste()
    Dim myFileName As String
    Dim myShape As Shape
    
    myFileName = ActiveWorkbook.Path & "\mogtan.gif"
    
    '--(1) 選択位置に画像ファイルを挿入し、変数myShapeに格納
    Set myShape = ActiveSheet.Shapes.AddPicture( _
          Filename:=myFileName, _
          LinkToFile:=True, _
          SaveWithDocument:=False, _
          Left:=Selection.Left, _
          Top:=Selection.Top, _
          Width:=0, _
          Height:=0)
          
    '--(2) 挿入した画像に対して元画像と同じ高さ・幅にする
    With myShape
        .ScaleHeight 1, msoTrue
        .ScaleWidth 1, msoTrue
    End With
End Sub

Comments

[SkyRocket]

ご回答頂きありがとうございました！参考になりました。