vbs httpリクエスト multipart/form-data

Question

現在VBSでBOXのAPIのファイルアップロードを実行するスクリプトを作成しているのですが、
リファレンス内に挙げられているcurlコマンドでの例で指定されているオプション-Fで列挙されている2行の指定方法がわかりません。
どのようにすればよいかわかる方がおりましたらご助力をお願い致します。

APIリファレンス↓
https://ja.developer.box.com/reference/post-files-content/#param-attributes-name

//curlでの実行例
curl -i -X POST "https://upload.box.com/api/2.0/files/content" \
     -H "Authorization: Bearer <ACCESS_TOKEN>" \
     -H "Content-Type: multipart/form-data" \
     -F attributes="{"name":"Contract.pdf", "parent":{"id":"11446498"}}" \
     -F file=@<FILE_NAME>

VBSでのhttpリクエストの方法は下記URLを参考にしています。
https://qiita.com/danishi/items/34d086fc466d5aa1df65

Set http = CreateObject("WinHttp.WinHttpRequest.5.1")

With http
    .Open "POST", "https://upload.box.com/api/2.0/files/content", False
    .SetRequestHeader "Authorization", "Bearer " & token
    .SetRequestHeader "Content-Type", "multipart/form-data"
    .Send postdata
End With

◆20210317追記◆

boundary設定バージョン

postdata = ""
postdata = postdata & "--------------------------ABCDEFG" & vbCrLf
postdata = postdata & "Content-Disposition: form-data; name=""attributes""" & vbCrLf
postdata = postdata & vbCrLf
postdata = postdata & "{""name"":""api_upload.txt"", ""parent"":{""id"":""123456789""}}" & vbCrLf
postdata = postdata & "--------------------------ABCDEFG" & vbCrLf
postdata = postdata & "Content-Disposition: form-data; name=""file""" & vbCrLf
postdata = postdata & vbCrLf
postdata = postdata & "C:\Users\ユーザー\Desktop\abc.txt" & vbCrLf
postdata = postdata & "--------------------------ABCDEFG--" & vbCrLf

Set http = CreateObject("WinHttp.WinHttpRequest.5.1")

With http
    .Open "POST", "https://upload.box.com/api/2.0/files/content", False
    .SetRequestHeader "Authorization", "Bearer " & token
    .SetRequestHeader "Content-Type", "multipart/form-data; boundary=------------------------ABCDEFG"
    .Send postdata
End With

###◆20210318追記◆
下記の指定でアップロードに成功しました。
20210317追記でのコードとほぼほぼ同じな気がしますが…

postdata = ""
postdata = postdata & "--------------------------ABCDEFG" & vbCrLf
postdata = postdata & "Content-Disposition: form-data; name=""attributes""" & vbCrLf
postdata = postdata & vbCrLf
postdata = postdata & "{""name"":""api_upload.txt"", ""parent"":{""id"":""1234567""}}" & vbCrLf
postdata = postdata & "--------------------------ABCDEFG" & vbCrLf
postdata = postdata & "Content-Disposition: form-data; name=""file""; filename=""abc.txt""" & vbCrLf
postdata = postdata & "Content-Type: application/octet-stream" & vbCrLf
postdata = postdata & vbCrLf
postdata = postdata & "aiueo" & vbCrLf
postdata = postdata & "--------------------------ABCDEFG--"

Set http = CreateObject("WinHttp.WinHttpRequest.5.1")

With http
    .Open method, requestUrl, False
    .SetRequestHeader "Authorization", "Bearer " & token
    .SetRequestHeader "Content-Type", "multipart/form-data; boundary=------------------------ABCDEFG"
    .Send postdata
End With
コード

###◆20210322追記（成功版）◆
バイナリファイルのアップロードのためにpostdataをバイナリ形式で送信する必要があったので、
下記URLを参考にしてみたところ、元のファイル情報を保持したままファイルのアップロードができました。
http://trash-area.com/archives/649
https://spirits.appirits.com/doruby/8783/

filePath = "C:\Users\ユーザー\Desktop\test.pdf"
forderId = "1234567"
boundary = "------------------------ABCDEFG"

'リクエストパラメータ生成
postData = SetPostData()

'HTTPリクエストオブジェクト
Set http = CreateObject("WinHttp.WinHttpRequest.5.1")

With http
    .Open "POST", "https://upload.box.com/api/2.0/files/content", False
    .SetRequestHeader "Authorization", "Bearer " & token
    .SetRequestHeader "Content-Type", "multipart/form-data; boundary=" & boundary
    .Send postData
End With

'-------------------------------------------------------
Function SetPostData()
  adTypeBinary = 1
  adTypeText = 2

  ' ファイル名取得
  Set fso = CreateObject("Scripting.FileSystemObject")
  filename = fso.GetFileName(filepath)
  Set fso = Nothing

  ' アップロードファイルをバイナリ形式で読込
  Set stream = CreateObject("ADODB.Stream")
  stream.Type = adTypeBinary
  stream.Open
  stream.LoadFromFile filePath
  fileContents = stream.Read
  stream.Close
 
  stream.Type = adTypeText
  stream.Charset = "UTF-8"
  stream.Open
 
  ' バイナリデータの前まで
  ChangeStreamType stream, adTypeText
  params = ""
  params = params & "--" & boundary & vbCrLf
  params = params & "Content-Disposition: form-data; name=""attributes""" & vbCrLf
  params = params & vbCrLf
  params = params & "{""name"":""" & filename & """, ""parent"":{""id"":""" & forderId & """}}" & vbCrLf
  params = params & "--" & boundary & vbCrLf
  params = params & "Content-Disposition: form-data; name=""file""; filename=" & filePath & vbCrLf
  params = params & "Content-Type: application/octet-stream" & vbCrLf
  params = params & vbCrLf
  stream.WriteText params
 
  ' バイナリデータ
  ChangeStreamType stream, adTypeBinary
  stream.Write fileContents
 
  ' 最後
  ChangeStreamType stream, adTypeText
  stream.WriteText vbCrLf & "--" & boundary & "--" & vbCrLf
 
  ChangeStreamType stream, adTypeBinary
  stream.Position = 0
  formData = stream.Read
  stream.Close

  SetPostData = formData
End Function

Function ChangeStreamType(stream, t)
    p = stream.Position
    stream.Position = 0
    stream.Type = t
    stream.Position = p
    Set ChangeStreamType = stream
End Function

Answer 1

postdata = "{""name"":""Contract.pdf"", ""parent"":{""id"":""11446498""}}&file=" & ファイルの中身

でしょうか。

#追記
間違えてました。マルチパート形式なので、マルチパートを自分で組み立てないといけませんね。

Content-Type: multipart/form-data; boundary=------------------------ABCDEFG

にして、postdataを

--------------------------ABCDEFG
Content-Disposition: form-data; name="attributes"

{name:Contract.pdf, parent:{id:11446498}}
--------------------------ABCDEFG
Content-Disposition: form-data; name="file"

ファイルの中身
--------------------------ABCDEFG--

みたいにして下さい。
#追記2
ちょっと違ったようです。curlで投げられるのはこんな感じ。

--------------------------ABCDEFG
Content-Disposition: form-data; name="attributes"

{name:Contract.pdf, parent:{id:11446498}}
--------------------------ABCDEFG
Content-Disposition: form-data; name="file"; filename="ファイル名"
Content-Type: application/octet-stream

ファイルの中身
--------------------------ABCDEFG--

しかし、そんなに違いはないので駄目かも知れませんが。

#追記3
バイナリーファイル読み込みの例：

Const adTypeBinary          = 1
Const adReadAll             = -1

Set ADO = CreateObject("ADODB.Stream")
ADO.Type = adTypeBinary
ADO.Open
ADO.LoadFromFile "aaaaa.jpg"
data = ADO.Read(adReadAll)
ADO.Close

WScript.Echo Lenb(data)

Comments

[coko1]

お世話になっております。

400 Bad Requestになってしまいました。
ファイルの中身は"C:\Users\ユーザー\Desktop\abc.txt"のような形で渡しています。

コマンドライン経由でのcurl実行はうまくいっているので、
指定の仕方の問題だとは思うのですが…

[otn]

失礼しました。
マルチパートにしないといけませんね。面倒くさい。

[coko1]

お世話になっております。
返信まで時間が空いてしまい申し訳ありません。

ご提示いただいた内容を参考に実行してみましたが
400 Bad Requestになってしまいました。（スクリプトの内容は質問に追記済み）

"ファイルの中身"はアップロード元ファイルのパスを指定する認識で誤りないでしょうか？

[otn]

> "ファイルの中身"はアップロード元ファイルのパスを指定する認識で誤りないでしょうか？
いや、名前じゃなくて中身です。ただ、お書きのコードでも「C:\Users\ユーザー\Desktop\abc.txt」という中身のファイルを送った体なので、エラーの原因では無いでしょう。

お書きのcurlコマンドで、私の管理するサーバーに投げてみて、サーバーが受け取ったものを見てみましたが、ちょっと違いましたね。追記します。

[coko1]

中身というと、元ファイルの内容をそのままでアップロードしたい場合は指定不要でしょうか？
また、元ファイルのパスはfilename="ファイル名"に指定する形になるのでしょうか？

[otn]

> 中身というと、元ファイルの内容をそのままでアップロードしたい場合は指定不要でしょうか？
すいません。意味が取れません。

> また、元ファイルのパスはfilename="ファイル名"に指定する形になるのでしょうか？
フルパスじゃなくて、ファイル名でしょう。

[coko1]

> ＞中身というと、元ファイルの内容をそのままでアップロードしたい場合は指定不要でしょうか？
＞＞すいません。意味が取れません。
例えばファイルの中身を”あいうえお”としてテキストファイルをアップロードした場合は、
アップロードしたファイルの中身がもともと"ABCDE"という内容でも"あいうえお"となってしまうということでしょうか？

＞> また、元ファイルのパスはfilename="ファイル名"に指定する形になるのでしょうか？
＞＞フルパスじゃなくて、ファイル名でしょう。
例えばデスクトップ上にあるabc.txtをアップロードしようとした場合は、
filename="abc.txt"とすればよいのでしょうか。
そうするとデスクトップ上に存在するabc.txtという指定はどこの記述をもって確定するのでしょうか。

理解不足で申し訳ないですが、引き続きよろしくお願いいたします。

[otn]

> 例えばファイルの中身を”あいうえお”としてテキストファイルをアップロードした場合は、
アップロードしたファイルの中身がもともと"ABCDE"という内容でも"あいうえお"となってしまうということでしょうか？

これも意味がわかりません。アップロードしたいファイルの中身は何なのでしょう？

> そうするとデスクトップ上に存在するabc.txtという指定はどこの記述をもって確定するのでしょうか。

デスクトップ上にあるファイルであるという情報はサーバーには送りません。不要なので。
ファイル名とファイルの内容だけを送ります。

[coko1]

＞これも意味がわかりません。アップロードしたいファイルの中身は何なのでしょう？
すみません、ファイルの中身がどんな値であってもその値のままアップロードさせたいということです。

＞デスクトップ上にあるファイルであるという情報はサーバーには送りません。不要なので。
＞ファイル名とファイルの内容だけを送ります。
上の質問と重複してしまう気がしますが、
つまりはアップロードしたいファイルの内容をそのまま保持したい場合には、
ファイルの内容をスクリプト内で事前に読み取っておく必要があるということでしょうか？

いまいち理解が及んでいないのですが、サーバーにアップロードファイルのパスを渡す必要がなく、ファイル名と内容のみを渡すということは、渡されたファイル情報をもとにサーバー側でファイルを新たに作成しているということなのでしょうか？

[otn]

> ファイルの内容をスクリプト内で事前に読み取っておく必要があるということでしょうか？

もちろんそうです。その内容をpostdataの中に埋め込みます。

> 渡されたファイル情報をもとにサーバー側でファイルを新たに作成しているということなのでしょうか？

サーバー側が受け取るのはあくまでファイル内容が埋め込まれたpostdataなので、受け取ってメモリ上で処理するだけなのか、サーバー上のファイルに書くのかは、サーバー側のプログラム次第です。
クライアント側でアップロード処理をしたからと言って、サーバー上でファイルが出来るとは限りません。

[coko1]

お世話になっております。
度々返信が遅れてしまい申し訳ありません。

"追記２"でご提示していただいたpostdataで処理を行ったところ、
無事にアップロードすることができました。

単純なテキストファイルの読み込み結果をpostdataに設定することまではできたのですが、
エクセルファイルなどの純粋のテキストデータでは読めないファイル情報を渡すにはどのように
したらよいでしょうか。

[otn]

FileSystemObjectだとバイナリーファイルは扱えないですよね。
何らかの外部コマンドでテキスト化して、読み込んだ後でバイナリーに戻すとかでしょうか。

[otn]

思い出しましたが、FileSystemObject じゃなくて、ADODB.Streamを使うと、バイナリーで読めます。
追記しておきます。

[coko1]

お世話になっております。

ご連絡遅れてしまい申し訳ありません。
バイナリ形式で送信する必要があるとの助言をいただいてから、
自分なりに調べながらやっていたため日数が空いてしまいました。

先日、otnさんが追記してくださっていた方法に私も行きつき、
いくつかのページを参考にしてバイナリファイルのアップロードに成功しました。
（コードは追記済みです）

この度は本当にありがとうございました。