オートフィルタの結果をコンボボックスに表示したい

Question

前提・実現したいこと

Excelでオートフィルタの抽出結果をUserFormに置いたcomboBox に表示する場合は
どのようにしたらよいのでしょうか？
下記のような『一覧表』シートの中から
列A：●□川
列B：H29
列C：L
という条件で列DをComboboxで表示したいのです。
|列A|列B|列C|列D|
|--:|--:|--:|
|●□川|H29|L|L-01.xdw|
|●□川|H29|L|L-02.xdw|
|●□川|H29|R|R-01.xdw|
|●■川|H29|R|R-02.xdw|
|●□川|H30|L|L-01.xdw|
|●□川|H30|L|L-02.xdw|
|●□川|H30|L|L-10.xdw|
|●■川|H30|R|R-01.xdw|

発生している問題・エラーメッセージ

comboboxに列Dが出てきません。

エラーメッセージ

該当のソースコード

VBA

Private Sub combobox_Initialize()

MaxRow = Worksheets("一覧表").Cells(Rows.Count, 1).End(xlUp).Row
With Range(Cells(1, 1), Cells(MaxRow, 5))
    .AutoFilter Field:=1, Criteria:="●□川"
    .AutoFilter Field:=2, Criteria:="H29"
    .AutoFilter Field:=3, Criteria:="L"
End With

End Sub

試したこと

上記ソースコードに.RowSourceを書いてみたり
comboboxのプロパティ『RowSource』に範囲を入れてみたりしましたが
ダメでした。

補足情報（FW/ツールのバージョンなど）

Excel for Microsoft 365 MSO

Answer 1

こんな感じでどうでしょうか。

    Dim rng As Range, c As Range, i
    With Worksheets("一覧表").AutoFilter.Range
        Set rng = .Resize(.Rows.Count - 1, 1).Offset(1, 3).SpecialCells(xlCellTypeVisible)
    End With
    ReDim wList(rng.Count - 1)
    For Each c In rng
        wList(i) = c.Value
        i = i + 1
    Next
    ComboBox1.List = wList

Answer 2

RowSourceを使うならコンボボックスの為の処理用ワークシートを作成しておいて
そこに張り付けてやれば出来るには出来ますね。

フィルターの結果をリストボックスに表示させる

ちょっとごちゃごちゃしてますけど、正確にやるならこんな感じなのかな。

    Dim tSheet As Worksheet
    Set tSheet = Worksheets("一覧表")
    
    ' オートフィルターのヘッダ行を除く該当行を取得⇒データ行
    Dim tRange1 As Range
    Set tRange1 = tSheet.Rows(tSheet.AutoFilter.Range.Row + 1 & ":" & tSheet.AutoFilter.Range.Row + tSheet.AutoFilter.Range.Rows.Count - 1)
    ' データ行とフィルターの結果表示されている行の共通部分＝オートフィルターの結果データ部分⇒結果データ
    Dim tRange2 As Range
    Set tRange2 = Intersect(tRange1, tSheet.AutoFilter.Range.SpecialCells(xlCellTypeVisible))
    ' 表示用列と結果データの共通部分＝コンボボックスに表示したいデータ
    Dim tRange3 As Range
    Set tRange3 = Intersect(tSheet.Columns(4), tRange2)
    ' コンボボックスに表示したいデータの転記
    Sheet2.Cells.Clear
    tRange3.Copy (Sheet2.Cells(1, 1))
    Me.ComboBox1.RowSource = Sheet2.Cells(1, 1).CurrentRegion.Address(External:=True)

まぁ、tRange3の中身を巡回してadditemで追加していけばワークシートは不要ですね。

Comments

[t-244]

ありがとうございます。
やってみます。