エクセルVBAでメール送る

Question

下記がネットで見つけたエクセルを
更新したときに、それを
メールで通知できるマクロだそうです
これで行くと
メールで送る内容（本文）が
B7
1つしかないのですが
それの範囲を広げるには
どこを
どううちこんだらいいか
わかりません。
広げる範囲は
B7からM27
くらいを本文にしたいです。
よろしくおねがいします

Option Explicit

'設定シート情報
Private Const SETTING_SHEET_NAME As String = "設定シート"
Private Const RANGE_TO As String = "B3"
Private Const RANGE_CC As String = "B4"
Private Const RANGE_BCC As String = "B5"
Private Const RANGE_SUBJECT As String = "B6"
Private Const RANGE_BODY As String = "B7"

'送信ボタン押下時の処理
Public Sub SendBtnClicck()
Dim wsSetting As Worksheet
Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)

If wsSetting.OLEObjects("OptBtnSend").Object.Value Then
    Call SendEmail
End If

End Sub

'ファイル保存時の処理
Private Sub Workbook_AfterSave(ByVal Success As Boolean)
Dim wsSetting As Worksheet
Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)

If wsSetting.OLEObjects("OptBtnSave").Object.Value Then
    Call SendEmail
End If

End Sub

'メール送信の処理
Private Sub SendEmail()
On Error GoTo ErrorHandler

Dim objOutlook As Outlook.Application
Dim objMail As Outlook.MailItem
Dim wsSetting As Worksheet

Set objOutlook = New Outlook.Application
Set objMail = objOutlook.CreateItem(olMailItem)
Set wsSetting = ThisWorkbook.Sheets(SETTING_SHEET_NAME)

'設定シートの値を設定する
With wsSetting
    objMail.TO = .Range(RANGE_TO).Value             'TO
    objMail.CC = .Range(RANGE_CC).Value             'CC
    objMail.BCC = .Range(RANGE_BCC).Value           'BCC
    objMail.Subject = .Range(RANGE_SUBJECT).Value   '件名
    objMail.Body = .Range(RANGE_BODY).Value         '本文
    'メールの形式
    If wsSetting.OLEObjects("OptBtnHTML").Object.Value Then
        objMail.BodyFormat = olFormatHTML
    End If
    If wsSetting.OLEObjects("OptBtnPlain").Object.Value Then
        objMail.BodyFormat = olFormatPlain
    End If
End With

'メール送信
objMail.Send

GoTo Finally

ErrorHandler:
MsgBox "メールの送信に失敗しました", vbOKOnly + vbCritical

Finally:
Set objOutlook = Nothing

End Sub

前提・実現したいこと

メール本文の範囲をおおきくしたい
B7からM27くらいに

■■な機能を実装中に以下のエラーメッセージが発生しました。

発生している問題・エラーメッセージ

どこをどうしたらいいかわかりません

該当のソースコード

ソースコード

試したこと

Private Const RANGE_BODY As String = "B7：M27"
に入力すると、メールが送れませんでした

補足情報（FW/ツールのバージョンなど）

ここにより詳細な情報を記載してください。

Answer 1

これでどうでしょうか。

Private Const RANGE_BODY As String = "B7:M27"

'中略

objMail.Body = WorksheetFunction.TextJoin(vbLf, False, .Range(RANGE_BODY).Value)      '本文

Comments

[Kasai5363]

メール送信でき、受信もできました。
ありがとうございます。