excelのシート同士を比べたいのですがそのような関数は無いのでしょうか？

お世話になっております。

件名の通りなのですが
excelのシート同士を比べたいのですがそのような関数は無いのでしょうか？

グーグルさんで調べてもEXACT関数ぐらいしか無く
エクセル EXACT関数の使い方｜２つのセルの値の一致を判定する方法 - 病院ＳＥにゃんとのパソコン・エクセル活用術
には
セルA3クリック後、数式バーに「=EXACT(」
で範囲指定するとの事なのですが
シート毎全部を比較したいのです……

そのようなAシートとBシートの値が全部正解かどうか判断するVBAの命令は無いのでしょうか？

大変初心者の質問失礼しますが上記何かご存知な方はコメント頂ければ幸いです。

行動規範の内容に同意します

回答5件

ベストアンサー

EXACTをここで知って試行錯誤してると閃きました。

VBA
1Public Function MyEXACT(rSheet1 As Worksheet, rSheet2 As Worksheet) As Boolean
2    Dim tR1 As Long
3    Dim tR2 As Long
4    Dim tC1 As Long
5    Dim tC2 As Long
6    'Dim tAddress As String
7    Dim tAddress1 As String
8    Dim tAddress2 As String
9    
10    ' rSheet1のUsedRangeとrSheet2のUsedRangeの両方を含む範囲を求める
11    tR1 = WorksheetFunction.Min(rSheet1.UsedRange.Row, rSheet2.UsedRange.Row)
12    tR2 = WorksheetFunction.Max(rSheet1.UsedRange.Row + rSheet1.UsedRange.Rows.Count - 1, rSheet2.UsedRange.Row + rSheet2.UsedRange.Rows.Count - 1)
13    tC1 = WorksheetFunction.Min(rSheet1.UsedRange.Column, rSheet2.UsedRange.Column)
14    tC2 = WorksheetFunction.Max(rSheet1.UsedRange.Column + rSheet1.UsedRange.Columns.Count - 1, rSheet2.UsedRange.Column + rSheet2.UsedRange.Columns.Count - 1)
15
16    'tAddress = rSheet1.Range(rSheet1.Cells(tR1, tC1), rSheet1.Cells(tR2, tC2)).Address
17    'MyEXACT = Evaluate("AND(EXACT([" & rSheet1.Parent.Name & "]" & rSheet1.Name & "!" & tAddress & ",[" & rSheet2.Parent.Name & "]" & rSheet2.Name & "!" & tAddress & "))")   
18    ' 範囲のアドレスを取得
19    tAddress1 = rSheet1.Range(rSheet1.Cells(tR1, tC1), rSheet1.Cells(tR2, tC2)).Address(External:=True)
20    tAddress2 = rSheet2.Range(rSheet2.Cells(tR1, tC1), rSheet2.Cells(tR2, tC2)).Address(External:=True)
21    
22    ' EXACT実行
23    MyEXACT = Evaluate("AND(EXACT(" & tAddress1 & "," & tAddress2 & "))")
24End Function
25

※コメント追記とアドレスの取得処理変更

投稿2021/03/15 03:20

編集2021/03/15 14:14

xail2222

総合スコア1508

jinoji

2021/03/15 03:47

rSheet1.Range(tAddress).Address(External:=True) とすると多少シンプルかも

xail2222

2021/03/15 03:52 編集

なるほど。そんなのがあったのですね。確かにそっちの方が良いですね。勉強になります

ma2hiro

2021/03/15 08:35

xail2222さんコメントありがとうございます。 Evaluateメソッドというのを初めて知りました。 Evaluateメソッド（文字列の数式を実行します）｜VBA技術解説 https://excel-ubara.com/excelvba4/EXCEL_VBA_424.html こちらを使えばEXACT使えますねっ　実装してみようと思います。コメントありがとうございました。

xail2222

2021/03/15 14:19

Evaluate(EXACT だと、範囲1セルでないときに2次元配列が返ってくるみたいです。この2次元配列をどうにか出来ないかと考えてるとEvaluate(AND(EXACTと ANDで集約する方法を思いつきました。なかなか速い処理ですね。あとjinojiさんの指摘を参考にコードを少し修正しました。本質的には変わりないですけど。

ma2hiro

2021/03/16 08:28

xai2222さんありがとうございますm(_ _)m こちらで実装出来ましたっ 2つのシートを比べた際に違う場合はどこが違うのか分かるようにする変更は自分で考えてやってみようと思いますっ本当にありがとうございました。

行動規範の内容に同意します

こちらはどうでしょう。
VBAで２つの表の違いを調べる

投稿2021/03/15 01:14

radames1000

総合スコア1925

ma2hiro

2021/03/15 01:31

radames1000さんコメントありがとうございます。 Inquireアドインを利用するしかないのですね…… アドイン追加は上長の許可が必要そうなので相談してみます……

radames1000

2021/03/15 01:36

それは２つのブックの比較の場合ですよね。表の比較はもう少し下にのせられています。

ma2hiro

2021/03/15 01:53

あっ　失礼しました。 DiffSheetですねっもう少し見てみます！！！

行動規範の内容に同意します

Youtubeに、下記タイトルの動画があります参考までにURL記載します
「超簡単２つのExcelシートの差分を比較する3つの方法」
https://www.youtube.com/watch?v=XC3t-Gh4mkg

投稿2021/03/13 09:20

syousuke.33

総合スコア312

ma2hiro

2021/03/15 00:50

syousuke.33さん情報ありがとうございます。照会していただいたURL記載の方法だとマクロを追加しないと行けないのでちょっとやりにくいです。（顧客情報が記載している所なのでマクロは追加出来ないため）コメントありがとうございました。

行動規範の内容に同意します

シートCを作成し、シートCのA1セルに↓を入力すれば良いです。

=EXACT(シートA!1:1048576,シートB!1:1048576)

投稿2021/03/12 09:24

sinya0320

総合スコア211

ma2hiro

2021/03/15 00:51

sinya0320さんコメントありがとうございます。 VBAで使いたいのです…… 情報不足で失礼しました。

行動規範の内容に同意します

範囲指定でシート全体を選択するには、見出しエリアの左隅(Aの横、1の上)をクリックするか、CTRL+A を押下します。

=EXACT(Asheet!1:1048576,Bsheet!1:1048576)

VBAで一から書くならこんな感じ？

VBA
1Function SheetCompare(ws1 As Worksheet, ws2 As Worksheet) As Boolean
2
3    Dim rng1 As Range, rng2 As Range
4    Set rng1 = ws1.UsedRange
5    Set rng2 = ws2.UsedRange
6    
7    If rng1.Address <> rng2.Address Then Exit Function
8    
9    If rng1.Count = 1 Then
10        If rng1.Value <> rng2.Value Then Exit Function
11    End If
12    
13    Dim arr1, arr2, r, c
14    arr1 = rng1.Value
15    arr2 = rng2.Value
16    For r = 1 To rng1.Rows.Count
17    For c = 1 To rng1.Columns.Count
18        If arr1(r, c) <> arr2(r, c) Then Exit Function
19    Next c, r
20    
21    SheetCompare = True
22
23End Function