VBAでフォルダ内のファイル/シートを巡回して、フィルタが掛かっていたら解除したい

Question

VBAでフォルダ指定し、ファイルとシートを巡回してフィルタが掛かっていたら解除したいです。
調べながら作成しましたが、シートが巡回できていないようです。
どこかおかしな点がありますでしょうか？

Sub FilterClear()
    Dim buf As String
    Dim xlsxFile As String
    Dim newWbName As String
    Dim tmpSheet As Object
       
'    指定したディレクトリ内にあるxlsxファイルをすべて列挙
    With Application.FileDialog(msoFileDialogFolderPicker)
        If .Show = True Then
            buf = .SelectedItems(1)
            xlsxFile = Dir(buf & "*.xlsx")
        End If
    End With
    
'    xlsxファイルの数だけループ
    Do While xlsxFile <> ""
    
        '    xlsxファイルを開く
        Workbooks.Open buf & "\" & xlsxFile, UpdateLinks:=False
               
        '    ブック内のシートの数だけループ
        For Each tmpSheet In Workbooks(xlsxFile).Sheets
            'フィルターがあれば解除、なければなにもしない
                
             If tmpSheet.AutoFilterMode = True Then
               Dim MaxRow  As Long
               MaxRow = Cells(Rows.Count, 1).End(xlUp).Row
               Range(Cells(1, 1), Cells(MaxRow, 50)).AutoFilter
             End If
        
        Next tmpSheet
        
        '    xlsxファイルを閉じる
        Workbooks(xlsxFile).Close SaveChanges:=True
        
        '    次のxlsxファイルに移る
        xlsxFile = Dir()
    Loop
End Sub

Answer 1

フィルターの有無を判断せずに解除しています。
フィルター無しのシートでもエラーにはなりません。

For Each tmpSheet In Workbooks(xlsxFile).Sheets
    'フィルター解除（フィルター有無は判断しない）
    tmpSheet.AutoFilterMode = False

Next tmpSheet

Comments

[KAZ_KAZ]

なるほど、シンプルですね。有難うございます。

Answer 2

Cells とか Range とかが、 tmpSheet.Cells とかになってないからではないかと。
シート名を指定しないと、その時点のActiveSheetのRangeと解釈されます。
For EachでまわすだけではActiveSheetは変わらないので、
各シートを巡回しながら最初のシートのフィルターをつけたりはずしたりしていることになります。

それか、いっそ以下のようにしてもいいと思いました。

If tmpSheet.AutoFilterMode Then tmpSheet.AutoFilter.Range.AutoFilter

Comments

[KAZ_KAZ]

For　EachでActivesheetが変わらないのですね。
有難うございました！