for do () ブロック内の echo で遅延展開及び、Call :ラベル を使わずに引数名を出力するには

Question

以下に、出力とバッチファイルの順で書きます。
遅延展開及び、Call :ラベル を使わずに、下記の出力をさせる方法はあるでしょうか?

%%~fi : "C:\Windows\Temp\hoge.log"

出力

Microsoft Windows [Version 10.0.19041.844]

 %%~fi : "C:\Windows\Temp\hoge.log"
 %%~fi : "C:\Windows\Temp\hoge.log"

 %\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 ^~fi : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %%C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %%C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %%C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"
 %C:\Windows\Temp\hoge.log : "C:\Windows\Temp\hoge.log"

バッチファイル

@echo off
ver
echo/
set "_f1=C:\Windows\Temp\hoge.log"
set "_pp=%%%%"
for %%i in ("%_f1%") do (
    
    rem 期待通り
    setlocal enabledelayedexpansion
    echo/ !_pp!~fi : "%%~fi"
    endlocal
    
    rem 期待通り
    call :sub "%%~fi"
    
    rem 試行錯誤
    echo/
    call echo/ %%%%^%%%%^~fi : "%%~fi"
    echo/ %%%%~fi : "%%~fi"
    echo/ %%%%^~fi : "%%~fi"
    echo/ %%%%~f^i : "%%~fi"
    echo/ %%%%~^f^i : "%%~fi"
    echo/ %%%%^~^f^i : "%%~fi"
    echo/ %^%^%^%^~^f^i : "%%~fi"
    echo/ ^%%^%%^~^f^i : "%%~fi"
    echo/ %%%%%%~fi : "%%~fi"
    echo/ %%%^%%%^~fi : "%%~fi"
    echo/ ^%%%^%%%^~^f^i : "%%~fi"
    echo/ %%^%%^%%~^f^i : "%%~fi"
    echo/ %%^%%^%%^~^f^i : "%%~fi"
    echo/ %%%%~f^
i : "%%~fi"
    echo/ %%%%~^
f^
i : "%%~fi"
)
exit /b

:sub
    echo/ %%%%~fi : "%~f1"
    exit /b

Answer 1

希望されているものとは違う気もしますが、遅延展開やサブルーチンを避けたい理由によってはこれでもいいかも。

for %%i in ("%_f1%") do (
  for %%A in (%%%%) do (
    echo/ %%A~fi : "%%~fi"
  )
)

遅延展開の代用でのforはちょいちょい使います。

Comments

[cor]

なるほど、これはいいですね、大変参考になりました。
色々な場面で使えそうです、ありがとうございます。

[otn]

遅延展開やサブルーチンを避けたかったのは、単なる興味じゃなくて、おそらく、それらを使うとこういうケースで困るということがあったのではと思いますが、もしそうなら、参考までにお聞かせねがえませんか？

[cor]

これといった困ったケースで、という事では無かったです。
遅延展開及び、Call :ラベルでの処理時間を懸念して、なるべく使いたくないという心情でした。

ちなみに 10000 loop のテスト結果は当環境では

call :sub
29.07 s

enabledelayedexpansion
4.42 s

for
3.78 s

となりました。
これはいいですね!

[otn]

へー、時間計ったことは無かったです。ありがとうございます。
遅延展開が遅いのは、ループの中でsetlocal/endlocalしてるからでしょうね。
先頭で1回だけsetlocalすれば当然早いと思います。