VBA : #VALUE!か0が含まれるセルの列を削除したい

前提・実現したいこと

VBA初学者です。
分かりにくい説明かもしれませんが、ご教授お願いします。

11行目に「#VALUE!」又は「0」があれば、そのセルが含まれている列を削除したいのですが、下記のようなエラーが出てしまい困っています。

発生している問題・エラーメッセージ

エラーメッセージ   実行時エラー'13':
                型が一致しません。

該当のソースコード

VBA
1ソースコード  
2
3Sub Fix_0()
4    Dim zV As Long
5    
6    For zV = 50 To 4 Step -1
7        If Cells(11, zV).Value = 0 Or Cells(11, zV).Text = "#VALUE!" Then
8            Columns(zV).Delete Shift:=xlToLeft
9        End If
10    Next
11
12End Sub
13
14

行動規範の内容に同意します

回答1件

ベストアンサー

数式の結果表示されている#VALUE!はエラーとして返されています。
"#VALUE!"という形でエラー表示されているからと文字列で指定しても中に格納されているのは文字列ではないので型の不一致となります。

追加検証してみたところ、私の勘違いでした。
Cells(11, zV).text = "#VALUE!"でもエラーチェックが可能でした。
正確には提示コードではlongの0とstringの"#VALUE!"を同時にチェックしているため必ずどちらかが型不一致になるのが原因です。
IsError()には数値を入れてもエラーにならないので下記の方式になりました。

下記はテストコードです。

Sub Fix_0()
    Dim zV As Long

    For zV = 10 To 4 Step -1
        'IsErrorで数式のエラー判定
        If IsError(Cells(11, zV)) Then
            'エラーだった場合Cells.Valueで#VALUE!か判定（エラー全て対応ならifを削除）
            If Cells(11, zV).Value = CVErr(xlErrValue) Then
                Columns(zV).Delete Shift:=xlToLeft
            End If
            'CVErrではなく文字列での直接指定ならCells().Textで指定
            'If Cells(11, zV).Text = "#VALUE!" Then
                'Columns(zV).Delete Shift:=xlToLeft
            'End If
        ElseIf Cells(11, zV).Value = 0 Then
            Columns(zV).Delete Shift:=xlToLeft
        End If
    Next
End Sub

投稿2021/02/17 05:57

編集2021/02/17 06:47