VBA : #VALUE!か0が含まれるセルの列を削除したい

Question

前提・実現したいこと

VBA初学者です。
分かりにくい説明かもしれませんが、ご教授お願いします。

11行目に「#VALUE!」又は「0」があれば、そのセルが含まれている列を削除したいのですが、下記のようなエラーが出てしまい困っています。

発生している問題・エラーメッセージ

エラーメッセージ   実行時エラー'13':
                型が一致しません。

該当のソースコード

ソースコード  

Sub Fix_0()
    Dim zV As Long
    
    For zV = 50 To 4 Step -1
        If Cells(11, zV).Value = 0 Or Cells(11, zV).Text = "#VALUE!" Then
            Columns(zV).Delete Shift:=xlToLeft
        End If
    Next

End Sub

Answer 1

数式の結果表示されている#VALUE!はエラーとして返されています。
"#VALUE!"という形でエラー表示されているからと文字列で指定しても中に格納されているのは文字列ではないので型の不一致となります。

追加検証してみたところ、私の勘違いでした。
Cells(11, zV).text = "#VALUE!"でもエラーチェックが可能でした。
正確には提示コードではlongの0とstringの"#VALUE!"を同時にチェックしているため必ずどちらかが型不一致になるのが原因です。
IsError()には数値を入れてもエラーにならないので下記の方式になりました。

下記はテストコードです。

Sub Fix_0()
    Dim zV As Long

    For zV = 10 To 4 Step -1
        'IsErrorで数式のエラー判定
        If IsError(Cells(11, zV)) Then
            'エラーだった場合Cells.Valueで#VALUE!か判定（エラー全て対応ならifを削除）
            If Cells(11, zV).Value = CVErr(xlErrValue) Then
                Columns(zV).Delete Shift:=xlToLeft
            End If
            'CVErrではなく文字列での直接指定ならCells().Textで指定
            'If Cells(11, zV).Text = "#VALUE!" Then
                'Columns(zV).Delete Shift:=xlToLeft
            'End If
        ElseIf Cells(11, zV).Value = 0 Then
            Columns(zV).Delete Shift:=xlToLeft
        End If
    Next
End Sub

Comments

[radames1000]

IsErrorだと#VALUE!以外も拾いませんか

[退会済みユーザー]

すみません。
確かに拾います。
そこまで意識して使い分けていませんでした。
CVErrで#VALUE!を指定して判定する、が最適になりますか？

[radames1000]

CVErrでもいいですし、IsErrorでエラー判定後、
再度textで"#VALUE!"か確認するのも良いかもしれません。

[daic]

すみません。
私の説明不足でしたが、必ず数式が入力されている行なので#VALUE!としました。

[radames1000]

わたしが気にしすぎていましたね。
msuguruさん、失礼しました。

[退会済みユーザー]

今回は確実でより良い方法のご提案でした。
私自身も勉強になりました。
ありがとうございます。

[退会済みユーザー]

radames1000さんのコメントを参考にして追加検証し、私の勘違いしていた内容を編集にて修正しました。
より正確になったと思いますが投稿主には多数の編集でお騒がせしました。