VBA シート選択のシート名にワイルドカード

Question

いつも初歩的な質問に答えて頂きありがとうございます。

シートを選択するときにシート名を使うことでシートを選択できるかと思うのですが、その際にワイルドカードを使用することはできるのでしょうか。
また同時変数の使用できるのでしょうか。

したいことを簡素化して申し上げますと、
A1セルに別のシート名の一部が入力されていて、そのA1セルに入力された値とワイルドカードを繋げて、別シートを取得したいということです。
実際にマクロを実行しますと インデックスが有効範囲にありません。 というエラーメッセージが出てきてしまいます。

以下にサンプルコードを載せましたので参考にお願い致します。

Sub sheetNameWildcard()

Dim a1Cell
'アクティブシートのa1セルに入力されている別のシート名の一部を取得
a1Cell = ActiveSheet.Cells(1, 1).Value
'取得した別のシート名の一部とワイルドカードを繋げてシートを取得
Sheets(a1Cell & "_*").Cells(1, 1).Value = 12345

End Sub

Comments

[tatsu99]

そのようなことはできません。自前でワイルドカードを展開する仕組みを造るしかないです。

Answer 1

そのような機能はないので、自分で作成しましょう。
標準モジュールに下記の関数を作成します。

Public Function FindSheet(SheetName As String) As Worksheet
    Dim ws As Worksheet
    
    For Each ws In Worksheets
        If ws.Name Like SheetName Then
            Set FindSheet = ws
            Exit For
        End If
    Next
End Function

上記を作成しておけば、
質問のコードのSheets を FindSheet に変更するだけです

Sub sheetNameWildcard()

    Dim a1Cell
    'アクティブシートのa1セルに入力されている別のシート名の一部を取得
    a1Cell = ActiveSheet.Cells(1, 1).Value
    '取得した別のシート名の一部とワイルドカードを繋げてシートを取得
    FindSheet(a1Cell & "_*").Cells(1, 1).Value = 12345

End Sub

Comments

[tttkkk]

なるほど！そういうやり方もあるんですね！
ネットで調べるとやはりfor eachを使うのが主みたいですが、新しい知見を教えて頂きありがとうございます！
ただ今回は私も初心者というのもありまして、一般的なfor eachを使ってみようと思いましたので、申し訳ありませんが、ベンストアンサーは外させて頂きました

Answer 2

シート名をワイルドカードで直に引き当てる方法はたぶんなかったと思います。
以下のように Like演算子を使って、ActiveWorkbook.Sheets 配列から探すのが最もご希望に近い方法ではないかと思います。

Sub sheetNameWildcard()

Dim a1Cell As String
'アクティブシートのa1セルに入力されている別のシート名の一部を取得
a1Cell = ActiveSheet.Cells(1, 1).Value
'取得した別のシート名の一部とワイルドカードを繋げてシートを取得
Dim wc As String
wc = a1Cell & "_*"

' ワイルドカードを使ってシートを取得
Dim objSheet As Worksheet
For Each objSheet In ActiveWorkbook.Sheets
    If objSheet.Name Like wc Then
        objSheet.Cells(1, 1).Value = 12345
        Exit For
    End If
Next objSheet

End Sub

Answer 3

こんな感じでしょうか。

Sub sheetNameWildcard()

    Dim a1Cell
    'アクティブシートのa1セルに入力されている別のシート名の一部を取得
    a1Cell = ActiveSheet.Cells(1, 1).Value
    '取得した別のシート名の一部とワイルドカードを繋げてシートを取得
    
    Dim ws As Worksheet
    For Each ws In ActiveWorkbook.Worksheets
        If ws.Name Like a1Cell & "_*" Then Exit For
    Next
    If ws Is Nothing Then Exit Sub
    ws.Cells(1, 1).Value = 12345

End Sub