【VBA】変数が２つあるときのループ処理？

Question

VBAについて質問です。
下記表のようにB列にパートを振りたいです。

|　|A|B|C|D|E|
|:--|:--:|--:|
|1|りんご|part1|||3
|
|2|ゴジラ|part2|||1758
|
|3|ピザ|part3|
|
|4|101匹|part1|
|
|5|サメ|part2|||
|
|6|いちご|part3|
|…|…|…|…|…|…|
|
|1758|にんにく|part3||

振りたいpart数はE1に入力されています（その都度変わる予定です）。
A列のデータ数は一応E2に入力されます（これもその都度変わる予定です）。

A列に入力されているデータの個数の分だけ、B列に規則的にpart数を振るVBAを教えていただけますでしょうか？

以下はわからないなりに自分で組んでみたやつですが、B2からB1758まで
Part3で埋め尽くされて終わりました。

＝＝＝＝＝
Sub test()

Dim x As Variant
Dim y As Variant

For x = 2 To Range("E2").Value 'E2にはA列の個数が入ってる
For y = 1 To Range("E1").Value '振り分けたいpartの数は１からE1まで
Cells(x, 2).Value = "part" & y

　Next y
Next x

End Sub
＝＝＝＝＝

よろしくお願いします。

Answer 1

Step を使うといいでしょう。

    For x = 2 To Range("E2").Value Step Range("E1")
        For y = 1 To Range("E1").Value
           Cells(x + y - 1, 2).Value = "part" & y
        Next y
    Next x

2重ループにしなくても、Mod演算子で余りを求めてもいいでしょう。

Sub test()
    Dim x As Long
    Dim y As Long
    y = Range("E1")
    For x = 2 To Range("E2").Value
        Cells(x, 2).Value = "part" & (x - 2) Mod y + 1
    Next x
End Sub

---

おまけ。ループを使わずに式を設定すれば1行で。こんな方法もあるということで。

Sub test()
    Range("B2").Resize(Range("E2").Value - 1).Formula = "=""part""&MOD(ROW()-2,$E$1)+1"
End Sub

Answer 2

別解を書いてみました。

Sub test()
    Dim p, r, i
    p = Range("E1").Value
    r = Range("E2").Value
    
    With Range("B1")
        For i = 1 To p
            .Offset(i - 1).Value = "part" & i
        Next
        .Resize(p).Copy .Resize(r)
    End With
End Sub

Answer 3

For y = 1 To Range("E1").Value '振り分けたいpartの数は１からE1まで

Cells(x, 2).Value = "part" & y
Next y

これでは同じセルに繰り返し上書きされるだけですよね