excelグラフのデータラベルの取得

Question

図のexcelグラフのデータラベルの項目名を取得したいですが、項目名のみを抽出する方法がなさそうなので、データラベル全体を取得するため、下記のコードで試みましたが、全て空白が返ってきます。

ActiveChart.SeriesCollection(1).DataLabels(1).Format.TextFrame2.TextRange.Characters.Text

もちろん、取得したいグラフをアクティブ（クリック）してから実施しています。

問題はどこでしょうか。

Comments

[m.ts10806]

どのようなタイミングでどう取得したいのでしょうか。
「グラフ」といっても万人が同じものを作るわけではないです。
「前提」部分が伝わらなければ誰も答えようがないものとなります。

Answer 1

データーラベルの３要素の内１つめ

Sub DataLabel_1()
  Dim n As Integer
  Dim c As Object, a As Object, pt As Object
  Dim dt As Variant
  Dim DL As String
  For Each c In ActiveChart.FullSeriesCollection
    With c
      Select Case .ChartType
      Case xlPie    '円
        n = 1
        For Each pt In .Points
          If pt.HasDataLabel = True Then
            With pt.DataLabel
              If .ShowCategoryName And .ShowPercentage And .ShowValue Then
                DL = .Text
                dt = Split(.Text, ",")
                Debug.Print n; " 値<"; .Text; "> "; dt(0)
              End If
            End With
            n = n + 1
          End If
        Next
      Case Else
            
      End Select
    End With
  Next
End Sub

すべてのラベル取得

Sub subete()

Dim a As String
Dim b As Variant
Dim c As Object
Dim n As Integer

For Each c In ActiveChart.FullSeriesCollection
  With c
    Select Case .ChartType
    Case xlPie    '円
      a = Replace(Replace(.Formula, "=SERIES(", ""), ")", "")
      b = Split(a, ",")
      For n = 1 To Range(b(1)).Cells.Count
        Debug.Print n; ">", Range(b(1)).Cells(n).Value
      Next
    End Select
  End With
Next
     
End Sub

Comments

[pulim]

ありがとうございます。ちなみにですが、同じ円グラフでもDLに値が抽出されるものとされないものがでてくるのですが、原因はわかりますでしょうか。
様式はすべて同じグラフなのですが。。。

[sinzou]

>If .ShowCategoryName And .ShowPercentage And .ShowValue Then
ここですが　データラベルオプションの
.ShowCategoryName　分類名
.ShowPercentage 　　 パーセンテージ
.ShowValue 　　　　　値
に対応しています。３要素表示していれば処理しています。
表示要素数違うのであれば調整願います。

マルチに対応するなら
１． 分類名のみの場合はIF分もSplitもいらない
２．２要素以上ならSplitがいる。
とすればよい。

[pulim]

質問なのですが、図では、「小樽市」、「札幌市」、「函館市」とありますが、仮に分類として、「室蘭市」がデータ数0であった場合、グラフでは表示されないので、「DL = .Text」は空白になるという認識でよろしいでしょうか。

[sinzou]

データラベルが非表示だと取得できていません、
取得するには、
１．一時的にpt.HasDataLabel を Trueにする　
　引き出し線付きで表示されるの、位置調整されてると崩れるかも
２．c.Formulaでセル範囲取得できるので、位置カウントして、値を拾ってくる。

２番の方が安全かな？

[pulim]

ありがとうございます。
2番目の方法は、seriesに記載されている式を参照し、splitで区分してカウントするということですか？
可能であれば、参照位置のカウント方法も教えていただきたいです。

[pulim]

ちなみにnは必要なのでしょうか

[sinzou]

追記しました。

Answer 2

ActiveChart.SeriesCollection(1).DataLabels(1).Text
で取得できます。
参考：DataLabel オブジェクト (Excel) | Microsoft Docs

Comments

[pulim]

ありがとうございます。ちなみにですが、同じ円グラフでも値が抽出されるものとされないものがでてくるのですが、原因はわかりますでしょうか。
様式はすべて同じグラフなのですが（コピーしたもの）。。。