各文字列の先頭行にファイル名を追加したい

Question

以下のような日付データが名前となっているテキストファイルが複数あるとします
20160406.txt
20160407.txt
20160408.txt
・
・
・

テキストデータ内の各文字列はただのログですが、日付は入っていません。
テキストデータの各ファイル名を取得し、ファイル内の各行先頭にファイル名を文字列として追加することは可能でしょうか？

自分には、ファイルの文字列を一括取得してテキストにするだとか、
複数ファイルの中身を結合するバッチだとかを作る程度のことしかできませんでした

ご助力をお願いいたします

Comments

[kei344]

使用されている環境（OSなど）をお書きください。

[mezzot]

大変失礼いたしました windowsになります。バージョンは6.1.7601と書かれています。

Answer 1

「ファイル名」を付加じゃなくて、「ファイル名:」を付加で良ければ、さらに簡単にできます。
findstrコマンドにその機能があります。

cd /d "対象のディレクトリ"
for %%A in (*.txt) do (
  findstr "^" %%A NUL > tempfile
  move %%A %%A.bak
  move tempfile %%A
)
```これだとファイル内に空行があっても、特殊文字があっても大丈夫です。

Answer 2

Windowsの場合。組み方は色々あると思います。複雑な処理になるようであれば、tkturboさんもおっしゃってますがWSHとかPowerShell（バージョンによる）で組んだほうが良いです。
バッチ処理ではそのまま書き換えることは無理なので一時ファイルに出力してリネームする方法です。
エラー処理などを入れてないので参考程度に。

@echo off
setlocal enabledelayedexpansion
rem  対象パス
set TARGET_PATH=C:\foo\ba zzzzzz
cd /d "%TARGET_PATH%"
for /f "usebackq tokens=*" %%A in (`dir /B`) do (
  set TARGET_FILE=%%A
  set TEMP_FILE=!TARGET_FILE!.tmp
  for /f "usebackq delims=" %%B in ("!TARGET_FILE!") do (
    echo !TARGET_FILE! %%B >> "!TEMP_FILE!"
  )
  del "!TARGET_FILE!"
  ren "!TEMP_FILE!" "!TARGET_FILE!"
)
cd %~dp0
endlocal

Comments

[mezzot]

ありがとうございます。おそらくこれは、「ファイル名」の先頭に任意の文字を入れる処理だと思うのですが(もし違ったら申し訳ないです…実行したらそうなりました)、
私がやりたかったのは、「ファイル内容(ログ)」の各行先頭に、「ファイル名」を追加したい、という処理でした。誤解を招き申し訳ありません。

また、WSHとPowerShellについて教えていただきありがとうございます！
こちら今まで存じ上げなかったので、どのような違いがあるのか調べて是非導入いたします。

[umed0025]

失礼、ちょっと仕様読み込みを間違ってました。
修正しましたです。バッチだけでやろうとすると小難しくなりますね。

[mezzot]

わざわざご修正までいただき、大変感謝申し上げます…
本当に申し訳ありません…　「各行」の「先頭」にファイル名を追加することはかなわず、どうやらファイル内の最初の一行にファイル名を挿入することができる、という処理のようです。バッチだけでやろうとすると本当に難しい、ということがわかっただけでも本当に恩の字でございますので、これ以上解答は募らず、BAとさせていただきます

なお、最終的に、秀丸GREPの「ファイル名をフルパスで出力」を使用して事なきを得ましたので（こんなにバッチを書かせてしまい本当に申し訳ないです）、ご報告申し上げます

[umed0025]

あ、各行でよかったのね・・・失礼。
修正しました。

[mezzot]

何度もご修正いただき恐縮でございます。
誤解を招く表現で大変申し訳ございませんでした。
本当にありがとうございます。こちらで本来の予期通りに作動いたしました。

Answer 3

とりあえずこんな感じでしょうか。

@echo off
for %%A in (*.txt) do call :procfile %%A
goto :eof

:procfile
move %1 %~n1.bak
for /F "delims=" %%A in (%~n1.bak) do echo %~n1 %%A>>%1

ファイルの内容によっては問題が生じるかもしれません。
すでにWindowsではコマンドラインシェルとしてPowerShellが標準搭載されており、従来の「コマンドプロンプト」より遙かに高機能なので、より複雑なことをするにはそちらのご利用をお勧めします。
WSHも選択肢としては悪くはないですが、ファイル操作はシェルに比べると面倒です。

Answer 4

タグに「コマンドプロンプト」とあるので、OS=Windowsを想定してみます。
ぶっちゃけ、WindowsのCUIコマンドはUnix系のそれとは比べ物にならないくらい貧弱です。
メンテナンス性も含め、WSHなどを使用する方が有用かもしれません。

Comments

[mezzot]

おっしゃるとおり、Windowsになります。コマンドユーザーインターフェースにかなり違いがある、というのは耳にしたことがありますが、あわてすぎて完全に失念しておりました…　WSHというのはWindows Script Hostのことでしょうか？　これはWindowsにもとから搭載されている機能、というような解釈でよいでしょうか…？　こちらでもバッチが作成できるのでしょうか？

[mezzot]

教えていただきありがとうございました！　今回やりたかったことに関してはバッチではなく秀丸GREPでフルパス出力することで自己解決いたしました！　ありがとうございます！

Answer 5

(grep を使った例)

for file in *.txt ; do
    grep -H '.*' $file > $file.new
done

出力ファイル(.new)の行頭に「ファイル名:」が付きます。
出力ファイルの内容に問題なければリネームするなりしてください。

余談ですが、
操作ログを残すときに、設定ファイルのあるディレクトリで grep . * とすることがあります。

Comments

[TaichiYanagiya]

あ、Linux の sh, bash 系の例です。

[mezzot]

ご回答大変感謝いたします！
grep -h コマンドというのがあるのですね！

教えていただいた内容を.batとしてそのままテキストが放り込まれているフォルダに入れて実行したみたのですが、新しいファイルが作成されませんでした
どこか変更すべき箇所があるのでしょうか…

grep . *という表現は、未熟な私にはどのような違いがあるのかわからず、せっかく教えていただいたにも関わらず完全に理解できないこと無念に思います…精進いたします

[mezzot]

教えていただきありがとうございました！　今回やりたかったことに関してはバッチではなく秀丸GREPでフルパス出力することで自己解決いたしました！　ありがとうございます！　わたしのほうでもGowというソフトを入手し、コマンドプロンプトでも別コマンドを使えるようにしてみましたが、やはりご回答いただいた内容では作動していないようでした。今後知識を深めまして、Linuxを使用できるまでになりましたら再度チャレンジしてみようと思います！　本当にありがとうございました。