VBA セルがエラーかどうかの判定

Question

VBAの初心者ですが、よろしくお願いいたします。

if文を使用して、セルの値がエラーかどうかを判定したいのですが、それと同時にセルが指定の値かどうかも判定したいのですが、if文の中に、isErrorを Or でつなげると、「型が一致しません」というエラーメッセージが出てきてしまいます。
やはりセルの値がエラーかどうかを判定するには、if文を分けるしかないのでしょうか。

以下に私の書いたサンプルコードを記載致します。

Sub iserrorIf()

'A列にa以外の値が入っていたら､メッセージを表示したい｡
Dim cella As Range
For Each cella In Sheets(2).Range("a1:a10")
    If (cella.Value <> "a" Or IsError(cella.Value)) Then
        MsgBox "値が違います。"
    End If
Next cella

End Sub

拙い文章で申し訳ございませんが、教えて頂けないでしょうか。

Answer 1

m-oguraさんの回答と同じですが、少し補足です。

「型が一致しません」は、セルのエラーを式 cella.Value <> "a" にて評価する際に生じています。
よって、先にセルのエラーをチェックするよう以下のように修正します。

If IsError(cella.Value) Then
    MsgBox "Error"
ElseIf cella.Value <> "a" Then
    MsgBox "Not a"
End If

Answer 2

やはりセルの値がエラーかどうかを判定するには、if文を分けるしかないのでしょうか。

If文を分けた方がいいと思いますが、
どうしても一つのIf文で行きたいなら、

'A列にa以外の値が入っていたら､メッセージを表示したい｡
Dim cella As Range
For Each cella In Range("a1:a10").Cells
    If IsError(cella.Value) Or (cella.Text <> "a") Then
        MsgBox "値が違います。" & cella.Text
    End If
Next cella

あるいは、下記のようにメッセージを変えたほうがいいのかと。

'A列にa以外の値が入っていたら､メッセージを表示したい｡
Dim cella As Range
For Each cella In Range("a1:a10").Cells
    If IsError(cella.Value) Then
        MsgBox "エラーです。"
    ElseIf cella.value <> "a" Then
        MsgBox "値が違います。"
    End If
Next cella

Answer 3

今回の場合、セルの値を文字列の完全一致で見ているようですので、

    If (cella.Value <> "a" Or IsError(cella.Value)) Then

を、

    If (cella.Text <> "a") Then

と書き換えてはどうでしょうか？
条件によっては使えない可能性がありますが、エラーの検出ではなく回避が目的なら、これで事足りると思いますが。

Answer 4

VBAは短絡評価（ググってね）を行わないので、Ifに書いた全ての条件が評価されます。
なので、tttkkkさんの意図したようには動作しません。

If 条件１ Then
    処理１
ElseIf 条件２ Then
    処理２
End If

を試してみてください。