VBA 乱数の繰り返し

Question

VBAで8回乱数処理を実行して0から3までの数字で構成された、8桁の数値を生成するプログラムを作ろうとしています
条件で必ず0から3までの数字が1つは存在しなければならないことです

OK　01201231
NG　03001013 2がない

乱数は以下まで組んでみたのですが、条件に合うプログラムが思いつきません
ご教授お願いします

  For cnt = 1 To 8
    ransuu = WorksheetFunction.RandBetween(0, 3)
  Next

Answer 1

プログラミング言語上の乱数というのは計算式によって生成される擬似的な乱数です
こういう乱数には色々癖が出てきて、小さい桁ではこの問題のように偏った出力がなされることがあります
ということで、

ransuu = WorksheetFunction.RandBetween(0, 3999)\1000

とでもしてみてはどうでしょう

Answer 2

まず、0,1,2,3それぞれを出現させる位置を８桁からランダムに決定してから、
残った４つの桁に乱数をあてはめます。

'配列を8桁の数字文字列に変換する関数
Function ArrayToString(ary As Variant)
    Dim r As String
    For i = 0 To 7
        r = r + CStr(ary(i))
    Next
    ArrayToString = r
End Function


'8桁の乱数を持った配列を生成する関数
Function RandomNumbers()
    Dim ary As Variant
    '数字を格納する配列。-1は数字が決まっていない桁を表す。
    ary = Array(-1, -1, -1, -1, -1, -1, -1, -1)

    '0,1,2,3それぞれを出現させる位置を８桁からランダムに決定
    For num = 0 To 3
        Do While True
            pos = WorksheetFunction.RandBetween(0, 7)
            If ary(pos) = -1 Then
                ary(pos) = num
                Exit Do
            End If
        Loop
    Next num

    '残った４つの桁に乱数をあてはめる。
    pos = 0
    
    For i = 1 To 4:
        num = WorksheetFunction.RandBetween(0, 3)
        'すでに数字が決まっている桁はスキップする。
        Do While ary(pos) <> -1
            pos = pos + 1
        Loop
        ary(pos) = num
        pos = pos + 1
    Next i
    RandomNumbers = ArrayToString(ary)
End Function


Sub Test()
    Debug.Print RandomNumbers()
End Sub

Answer 3

とりあえず8桁生成してみて、0～3が含まれているかチェックしてなければ再トライするというロジックでどうでしょう。

Public Function GetRansuu() As String
  Dim ransuu As String, cnt As Long, Num, ok As Boolean
  Do
    ransuu = ""
    For cnt = 1 To 8
        ransuu = ransuu & WorksheetFunction.RandBetween(0, 3)
    Next
    
    ok = True
    For Each Num In Split("0 1 2 3")
        ok = InStr(ransuu, Num) > 0
        If ok = False Then Exit For
    Next
  Loop Until ok
  GetRansuu = ransuu
End Function

Sub Test()
    Debug.Print GetRansuu()
End Sub