Excel VBA ENDプロパティーが使えません

Question

お世話になります。
こちら、エクセルＶＢＡ初心者です。
以下のコードは、アクセスＶＢＡにて、
アクセスからエクセルにT日報テーブルを既存のエクセルファイルへ新規シートとして、
エクスポートし、一行目を削除した上で、
これを既存の貼付用シートの一番最後の行の一つ下の行に張り付けようとしています。
しかしながら、最終行を取得する処理にて、１００４　アプリケーション定義またはオブジェクト定義のエラーです　が出ます。
ENDプロパティーを外しますと、きちんと進みますが、一番最後の行の取得にはENDプロパティーはかかせません。
また、コピーの処理でも、.PasteSpecialの後の xlPasteValuesでひっかかります。
どうしたらよいのか、よろしくご教授ください。

Public Function Startexec()

Dim rs As Recordset
Const xlMinimized = -4140
Dim stpathname As String
Dim stTbl As String
Dim stvardir As String
Dim stFilename As String
Dim stSheet As String
Dim stSheetQuery As String
Dim Excel As Object
Dim wb As Object
Dim llastrow As Long


    
    stSheet = "貼付用"
    stpathname = "\ここにファイルのパスが入ります"
    
    
    stFilename = "練習用.xlsm"


    stvardir = stpathname & "\" & stFilename                  'エクセルファイルを指定します。


    stTbl = "T日報"                                        'Accessファイルを指定します。
    
    DoCmd.TransferSpreadsheet acExport, _
            acSpreadsheetTypeExcel9, stTbl, stvardir, False
            
    Set rs = CurrentDb.OpenRecordset(stTbl)
    
    
    rs.MoveLast
    
    stSheetQuery = "T日報"

    Set Excel = CreateObject("Excel.Application") 'Excel
        Excel.WindowState = xlMinimized '最小化
        Excel.Visible = True '表示
    Set wb = Excel.Workbooks.Open(stvardir) 'excelファイルを開く
        wb.Sheets(stSheetQuery).Rows(1).Delete 'クエリシートの1行目削除
        
        wb.Application.DisplayAlerts = False 'メッセージ非表示
        
        llastrow = wb.Sheets(stSheetQuery).Cells(wb.Sheets(stSheetQuery).Rows.Count, 1).End(xlUp).Row
  
  'ここで、１００４　アプリケーション定義またはオブジェクト定義のエラーです　が出ます。
  
  
        wb.Sheets(stSheetQuery).Range("A1:W" & rs.RecordCount).Copy   'コピー
        wb.Sheets(stSheet).Range("A" & llastrow).Offset(1, 0).PasteSpecial xlPasteValues
        
        
        wb.Application.DisplayAlerts = True  'メッセージ再表示
        
        Excel.DisplayAlerts = False '警告禁止
        wb.Sheets(stSheetQuery).Delete 'クエリシート削除
        Excel.DisplayAlerts = True '警告許可
        wb.Close True '閉じる
    Excel.Quit 'Excel終了

    
    
    Exit Function

Answer 1

エクセルに参照設定されてないなら、xlUp というエクセルの定数は使えないので、数値で指定する必要があります。

'     llastrow = wb.Sheets(stSheetQuery).Cells(wb.Sheets(stSheetQuery).Rows.Count, 1).End(xlUp).Row

     llastrow = wb.Sheets(stSheetQuery).Cells(wb.Sheets(stSheetQuery).Rows.Count, 1).End(-4162).Row

数値はヘルプを調べると分かります。

xldirection 列挙 (Excel) | Microsoft Docs

---

参照設定をしておくとエクセルの定数が使えるだけでなく、コード入力時に選択リスト（インテリセンス）が使える、などいろいろメリットがあります。

Excelを起動する（オートメーション）：Access VBA｜即効テクニック｜Excel VBAを学ぶならmoug

Comments

[tokumeiko]

あああー！。そうですよね！。ツールの参照設定にチェック入れるのをすっかり忘れていました！。入れたらサクッと通りました。インクルードしなきゃ通るわけないですよね・・・・・・。

[tokumeiko]

あ！。御礼も忘れてました。ご丁寧な回答、ありがとうございました。