ブック内のハイパーリンクで「参照が正しくありません」と表示される。

Question

同じブック内のシートのインデックスを作る表を作ったのですが、リンクの設定が上手くいきません。

「インデックス」というシートの中に、他のシートの名前から「ジャンル」と「名前」をそれぞれ抽出し、それぞれ別のセルに入力しています。（ジャンル：B列、名前：C列）

シート名は、「ジャンル（名前）」となっており、「（）」までの文字数から抽出する「データ」と「ジャンル」を判別しています。

※（）までの文字数を変数 bgn とし、bgn＝0の場合は（Continue）で飛ばし、1の場合はジャンルを「テンプレ」としています。（シート名が「（テンプレ）」となっているので。）

以下のコードは問題なく実行されるのですが、リンクが上手くいきません（「参照が正しくありません」となってしまいます。）

Sub インデックス作成()
 
    Dim ws As Worksheet
    Dim ws01 As Worksheet 'インデックスのシート
    Dim ws_Name As String
    Dim I As Long
    Dim Row As Long
    
    Set ws01 = ActiveSheet '書き込むシートを指定
    
    Row = 3 '3行目から入力
    
    For Each ws In Worksheets '他のワークシート全て繰り返します。
    
        If ws.Name <> ws01.Name Then 'インデックス以外のワークシートを巡回する
          bgn = InStr(ws.Name, "(")
          ed = InStr(ws.Name, ")")
          lg = ed - bgn
            If bgn = 0 Then '名前なし
             GoTo Continue
            ElseIf bgn = 1 Then
             Cells(Row, 2) = "テンプレ"
            Else
             Cells(Row, 2) = Mid(ws.Name, 1, bgn - 1) 'ジャンルを記入
            End If
          Cells(Row, 1) = Row - 2
          ws01.Hyperlinks.Add Anchor:=ws01.Cells(Row, 3), Address:="", SubAddress:=ws.Name & "!A1", TextToDisplay:=Mid(ws.Name, bgn + 1, lg - 1)
         Row = Row + 1
        End If
Continue:
    Next ws
 
End Sub

関係の無い情報が多いかと思いますが、どこに問題が有るかわからなかったため、コードの内容を書かせていただきました。
このコードはこちらのサイトを参考に書かせていただきました。
https://akira55.com/hyperlink/

よろしくお願いします。

Answer 1

シート名はシングルクォートで囲むようですね。

"'Sheet2'!A2"

SubAddress:="'" & ws.Name & "'!A1"

HyperLinkでググると、シート名の前に"#"を付けるともありましたが。
どちらも、ジャンプできました。

SubAddress:="#'" & ws.Name & "'!A1"

Comments

[ice930]

正常に動きました！ありがとうございます！

Answer 2

ws01.Hyperlinks.Add Anchor:=ws01.Cells(Row, 3), Address:="", SubAddress:="'" & ws.Name & "'" & "!A1", TextToDisplay:=Mid(ws.Name, bgn + 1, lg - 1)

Comments

[ice930]

回答の通りでした。
ありがとうございます！