〖VBA〗マクロを使用してシート間の検索をして一致しない場合、背景に色付けをしたい

Question

前提・実現したいこと

前回質問した内容とほぼ同一ですが、再度教えていただける方がいましたらお願い致します。

Sheet1、Sheet2があり
Sheet1のE列に記載されている会員番号を検索値とし
Sheet2のA列に記載されている会員番号を検索し一致しない場合に
Sheet1のE列の該当セルの背景色のみ変更したい。

発生している問題・エラーメッセージ

エラーはないですが背景色がつくセルが異なったりします。

該当のソースコード

Sub 会員以外の回答者()
    Dim x As Long
    Dim i As Long

    With Sheets("Sheet2")
        x = .UsedRange.Cells(.UsedRange.Count).Row
        For i = x To 2 Step -1
            If Sheets("Sheet1").Range("E:E").Find(What:=.Cells(i, 1)) Is Nothing Then '一致しない場合
                .Cells(i, 5).Interior.Color = RGB(0, 0, 255) 'E列の背景を青色に
            End If
        Next i
    End With
End Sub

補足情報（FW/ツールのバージョンなど）

Office 2019を使用しています。

Answer 1

質問文のやりたいことをまとめると

検索値　Sheet1のE列の値
検索範囲　Sheet2のA列
一致しない場合に背景色を変更するセル　Sheet1のE列の該当セル

コードでは下記のようになってます。

検索値　Sheet2のA列の値
検索範囲　Sheet1のE列
一致しない場合に背景色を変更するセル　Sheet2のE列の該当セル

シートが両者で逆になってますが、どちらがやりたいことですか。

Findの書式は下記だということを理解してますか。

検索範囲.Find(What:=検索値)

Answer 2

日本語で書いてあることを信用するとして、こういうことですか？

Sub 会員以外の回答者()
    Dim x As Long
    Dim i As Long

    With Sheets("Sheet1")
        x = .UsedRange.Cells(.UsedRange.Count).Row
        .Range("E2:E" & x).Interior.Pattern = xlNone
        For i = x To 2 Step -1
            If Sheets("Sheet2").Range("A:A").Find(What:=.Cells(i, 5), LookAt:=xlWhole) Is Nothing Then '一致しない場合
                .Cells(i, 5).Interior.Color = RGB(0, 0, 255) 'E列の背景を青色に
            End If
        Next i
    End With
End Sub

Sub 回答者の重複は色付け()
    Dim i As Long, j As Long, x As Long

    With Sheets("Sheet1")
        x = .Cells(Rows.Count, 5).End(xlUp).Row  'Sheet1 E列最大行
        .Range("E2:E" & x).Interior.Pattern = xlNone
        For i = x To 2 Step -1   '最終行から2行目まで
            For j = i - 1 To 2 Step -1     'iの前のから２行目まで
                If Cells(i, 5) = Cells(j, 5) Then
                    Cells(i, 5).Interior.Color = RGB(255, 0, 0)    'E列の該当セルは背景を赤色
                    Exit For
                End If
            Next j
        Next i

    End With
End Sub

ちなみに、キー（社員番号等）の重複チェックをするような場合は、Scripting.Dictionaryを使うと
簡単にかつ高速に処理が行えます。
上のマクロは２重のfor文なので、行数が１００００行程度になると劇的に遅くなります。
Scripting.Dictionaryを使った場合は、１重のfor文で済むので、それほど遅くなりません。
１００００行以上で試してみると違いが体感できるかと。

'Scripting.Dictionary版
Sub 回答者の重複は色付け2()
    Dim sh1 As Worksheet
    Dim maxrow As Long
    Dim wrow As Long
    Dim dicT As Object
    Dim key As String
    Set dicT = CreateObject("Scripting.Dictionary")
    Set sh1 = Worksheets("Sheet1")
    maxrow = sh1.Cells(Rows.Count, "E").End(xlUp).row  'Sheet1 E列最大行
    sh1.Range("E2:E" & maxrow).Interior.Pattern = xlNone
    For wrow = 2 To maxrow
        key = sh1.Cells(wrow, "E").Value
        If dicT.exists(key) = False Then
            dicT(key) = True
        Else
            Cells(wrow, "E").Interior.Color = RGB(255, 0, 0)    'E列の該当セルは背景を赤色
        End If
    Next
End Sub

Comments

[退会済みユーザー]

ご回答ありがとうございます。
いただいた内容で問題なく対応できました。ありがとうございます。

大変恐縮ですが、もう1点伺いたいです。
先程の処理をするのと同時に、Sheet1のE列で同じ会員番号がいないか重複チェックを行いたいです。
下記コードですと実行結果に反映されないのですが、原因わかりますでしょうか。

```

Sub 回答者の重複は色付け()
Dim i As Long, j As Long

With Sheets("Sheet1")
x = .UsedRange.Cells(.UsedRange.Count).Row '最終行を取得
For i = x To 2 Step -1 '下から2行目まで
For j = i + 1 To 1000
If Cells(i, 5) = Cells(j, 5) Then
Cells(i, 5).Interior.Color = RGB(255, 0, 0) 'E列の該当セルは背景を赤色
Exit For
End If
Next j
Next i

End With
End Sub

```

[tatsu99]

回答に追記しました。

[退会済みユーザー]

ご丁寧にありがとうございます。

実行したい事ができ大変助かりました。