バッチ処理でif文の条件に計算式を用いたい

Question

実現したいこと

バッチ処理でif文の条件で"%A%" equ "%B-1%"の右側のように変数の計算を書き込みたいです。
（イメージとして上記のように表現しています。）
非常に初歩的なご質問で申し訳ないのですが、ご教授いただければと思います。

発生している問題・分からないこと

ソースコードの実行でOKを表示させたいです。
if文の条件の中にB-1のような変数を用いた計算式を入れると、計算結果ではないものとして扱われてしまいます。どのようにしたら計算結果を比較に用いることができるでしょうか。
条件分岐としてB-2、B-3と続けていきたいため最初にB-1を別の変数に格納してからif文に書き込むことはできません。

最終的に実現したいコード
set /a A=1
set /a B=2

if "%A%" equ "%B%-1" (
echo No.1
) else if "%A%" equ "%B%-2" (
echo No.2
) else if "%A%" equ "%B%-3" (
echo No.3
)

該当のソースコード

setlacal enablededelayedexpansion

set /a A=1
set /a B=2

if "%A%" equ "%B%-1" (
 echo OK
) else (
 echo NG
)

pause

試したこと・調べたこと

• teratailやGoogle等で検索した
• ソースコードを自分なりに変更した
• 知人に聞いた
• その他

上記の詳細・結果

"%B%-1" のダブルクォーテーションの位置の変更や、setを付け加えるなどしてみましたがうまくいきませんでした。（1と2-1の文字列が比較されてしまっていることは理解しています）
調べてみたものの、そういったコードを書いているサイトも見つけることができませんでした。

補足

windows11にて作業を行っています。
また、こういった初歩的な躓きがかなり多く勉強不足であると感じるため、おすすめの入門サイト等をご存じでしたら教えていただきたいです。

Answer 1

バッチスクリプトで数値演算（加減乗除など）が出来るのは、set /a コマンドだけなので(注1)、演算結果を変数に置くのが普通です。

(注1) for /Lで等差数列を作れますので、「等差数列の作成も数値演算の一種だ」とするなら、これも数値演算でしょうが、今回は使えないでしょうね。

AとBの差を求めてNo. 差と表示するだけなら、ダイレクトにそうすれば良いので、実際はIFの中味はそれぞれ全く異なる処理なのでしょうね。

set /A B1=B-1, B2=B-2, B3=B-3
if %A% equ %B1% (
    echo No.1
) else if %A% equ %B3% (
    echo No.2
) else if %A% equ %B3% (
    echo No.3
)

下記のように、差を求めて差で分岐する方法もありますが、計算はset /aで行うのは同じです。
ただ、書いてみた物の、この方法はやめた方が良いですね。大きいケースから書かないといけないなどあるし。

call :B_MINUS_A
if ERRORLEVEL 3 (
	echo No.3
) else if ERRORLEVEL 2 (
	echo No.2
) else if ERRORLEVEL 1 (
	echo No.1
) else (
	echo No. 0
)
exit /b

:B_MINUS_A
set /a Diff=B-A
exit /b %Diff%

まだ、こっちの方がましか。

set /a Diff=B-A
goto :WHEN_%Diff%

:WHEN_1
echo No. 1
exit /b
:WHEN_2
echo No. 2
exit /b
:WHEN_3
echo No. 3
exit /b

差が1,2,3のどれでもない場合は、gotoがエラーになります。

あと、ifでの比較では「文字列としての比較」「数値としての比較」の両方があります。
どういうケースでどっちになるかの説明は、if /?を実行すると詳しく表示されます。

if 01 == 1 echo 等しい
if "01" == "1" echo 等しい
if 01 equ 1 echo 等しい ・・・・・この時だけ「等しい」と表示される
if "01" equ "1" echo 等しい

こういった初歩的な躓きがかなり多く勉強不足であると感じるため、おすすめの入門サイト等をご存じでしたら教えていただきたいです。

何らかの言語でのプログラミング経験(注2)と十分な日本語読解能力があれば、set /? if /? for /?などを読むだけで良いのですが、プログラミング経験がないのなら、まずはプログラミングに入門するのが良いと思います。

(注2) バッチスクリプトはかなり変な仕様なので、「世の中には変な言語もある」という認識も必要でしょう。
「私の知っている～～言語ではこうだから、バッチスクリプトでも多分こうだろう」は半分くらいは通用しないと思った方がいいです。

Comments

[assemble]

ご回答ありがとうございました。
数値演算は条件には直接配置できないのですね。
gotoを用いた方法が私のプログラムには最適そうなので参考にさせていただきます。
また、勉強に関する質問にもお答えいただきありがとうございました。

Answer 2

https://learn.microsoft.com/ja-jp/windows-server/administration/windows-commands/set_1

• /a パラメーターを使用すると、次の演算子が、優先順位の高いものから順にサポートされます。

計算結果をいったん変数に入れておく必要がありそうです。

set /A B1=%B% - 1
if "%A%" equ "%B1%" (