クラス内の特定のプロパティを動的にReadonlyにできるでしょうか。

Question

実現したいこと

自作したクラス内の特定のプロパティを動的にReadonlyにしたいのですが可能でしょうか。

該当のソースコード

【クラス側】

    Public Class FixStr
        Private _pValue As String
        Public Property pValue As String
            Get
                Return Me._pValue
            End Get
            Set(value As String)
                '■何らかの処理
            End Set
        End Property
    End Class

    Public Class stRecord
        Public ReadOnly Property 項目_読み取り専用 As New FixStr
        Public Property 項目_書き込みOK As New FixStr

        Public Sub New()
            _項目_読み取り専用.pValue = "固定値"
        End Sub
    End Class

【利用者側】

    Private Sub クラス利用()
        Dim rec As New stRecord
        rec.項目_読み取り専用.pValue = "aaaa"  ’★←ここでエラーになるようにしたいです。
        rec.項目_書き込みOK.pValue = "OK"      ’←同じ型だが書き込みOKにしたいものもある
    End Sub

解決したいこと

上記の「項目_読み取り専用」と「項目_書き込みOK」は同じFixStrですが、
「項目_読み取り専用」はコンストラクタで固定値をクラス側で設定し
プログラマには変更させないようにできないか、と考えております。

ですが、「項目_読み取り専用」にReadOnlyをつけてもpValueプロパティに値は
設定できてしまいます。

やりたいことのイメージとしてはFixStrをインスタンス化するときにReadOnlyを
付けたらpValueに値を設定するのは不可、ReadOnlyをつけなければ値設定可能、
というような使い方をしたいのですが、当然現時点でうまく行ってないのでこの
使い方はNGなのですが、このイメージに近い使い方を可能にするような方法を
アドバイスいただけますと幸いです。

補足情報（FW/ツールのバージョンなど）

Visual Studio 2017
.NETframework 4.7

Comments

[Zuishin]

書き込みができるよう作らないのが筋です。

[Arsnova]

そうしたいと思っているのでここで質問をしています。

[Zuishin]

不要な実行時エラーの可能性ができるので、そうしたいと思っているのが間違いだという話です。
後で書き込みたいときにはメソッド等を使うようにするのが良いでしょう。

[Arsnova]

readonlyが効くようにできれば、実行前にエラーであることがわかるのでそうしたいのです。

[Zuishin]

コンパイル時にわからないので悪手だという話ですが、それがなぜ悪手なのか理解できないのであれば、好きなときに例外を発生させればいいのでは？

[Arsnova]

だからreadonlyが効けばコンパイル時に分かるでしょう。

[maisumakun]

＞ だからreadonlyが効けばコンパイル時に分かるでしょう。

それは「動的」とは呼ばない、という話ではないでしょうか。

[Arsnova]

動的というのは適切ではなかったですね。
あらかじめわかっているので。

[Zuishin]

> FixStrをインスタンス化するときにReadOnlyを
付けたらpValueに値を設定するのは不可、ReadOnlyをつけなければ値設定可能、
というような使い方をしたいのですが、

これは構文の問題ではなくデータの問題なのでコンパイル時ではなく実行時に決まります。
コンパイル時に決めるには型を変えるしかなく、KOZ6.0 さんの方法がスマートです。

Answer 1

読み取り専用のインターフェイスを被せてそれを公開するとか。

Public Interface IFixStrReadOnly
    ReadOnly Property pValue As String
End Interface

Public Class FixStr
    Implements IFixStrReadOnly

    Private _pValue As String
    Public Property pValue As String
        Get
            Return Me._pValue
        End Get
        Set(value As String)
            '■何らかの処理
        End Set
    End Property

    Private ReadOnly Property IFixStrReadOnly_pValue As String _
                                Implements IFixStrReadOnly.pValue
        Get
            Return pValue
        End Get
    End Property
End Class

Public Class stRecord

    Private _項目_読み取り専用 As New FixStr
    Public ReadOnly Property 項目_読み取り専用 As IFixStrReadOnly
        Get
            Return _項目_読み取り専用
        End Get
    End Property

    Public Property 項目_書き込みOK As New FixStr

    Public Sub New()
        _項目_読み取り専用.pValue = "固定値"
    End Sub
End Class

Comments

[Arsnova]

ご回答ありがとうございます！
ご回答内容でイメージ通りの使い方ができます！
ありがとうございました！

Answer 2

Public Class FixStr

    Public ReadOnly Property pValue As String

    Public Sub New(value As String)
        pValue = value
    End Sub

End Class

Public Class stRecord

    Public ReadOnly Property 項目_読み取り専用 As FixStr
    Public Property 項目_書き込みOK As FixStr

    Public Sub New()
        _項目_読み取り専用 = New FixStr("固定値")
    End Sub

End Class


    Private Sub クラス利用()

        Dim rec As New stRecord
        rec.項目_書き込みOK = New FixStr("新たにセット")
        rec.項目_読み取り専用.pValue = "新たにセット"    'BC30526 プロパティは'ReadOnly'です。　とエラーになる

    End Sub

こういうことでしょうか？

Comments

[Arsnova]

ご回答ありがとうございます！
私の使い方のイメージとしては(そもそも不可能なのでは？と思い始めています)、
書き込みOKの項目はpValue="aaa"のように設定でき、読み取り専用項目は同じ書き方をすると
YAmaGNZさんが書いてくださったように「BC30526 プロパティは'ReadOnly'です。」になるのが理想でした。

ですが、考え方の重要なヒントになりました。
ご回答ありがとうございました！

Answer 3

FixStr側にbReadOnly as booleanを追加して、TrueならpValueのSet でInvalidOperandExceptionでも投げるとか、
FixStrのpValueをReadonly Propertyにして、FixStrのコンストラクタでしか書けなくするか。

Comments

[Arsnova]

ご回答ありがとうございます。
確かにこの方法も良いかもしれません。
考え方の非常に重要なヒントになりました。
ありがとうございました！