Excel VBA split関数マクロのうまい使い方を教えてください。

Question

『Excel VBA split関数マクロのうまい使い方を教えてください。』

エクセルworksheet内のC4からC6までの複数行の文字を\でsplitした上で、分割文字を列に並べたいのですが、全ての分割した文字を並べる方法をどなたかご教授願います。

Sub Test()
 Dim rr As Range
 Dim bb
 Range("C4") = "AA\BB\CC\DD"
 Range("C5") = "AA\BB\CC\DD\EE\FF\GG"
 Range("C6") = "AA\BB\CC\DD\EE\FF\GG\HH\RR\TT\YY"
 For Each rr In Range("C4:C6").Rows
 bb = Split(rr, "\")
Cells(rr.Row, 7) = bb(0)
Cells(rr.Row, 8) = bb(1)
Cells(rr.Row, 9) = bb(2)
Cells(rr.Row, 10) = bb(3)
Cells(rr.Row, 11) = bb(4)　'←C4の列数が４列なのでここでエラーが出る！それを回避したい！
Next
End Sub

Comments

[meg_]

コードは「コードの挿入」で記入してください。

> ←C4の列数が４列なのでここでエラーが出る！それを回避したい！
何のエラーですか？

[KANNORYUJI]

エラー内容ですが
インデックスが有効範囲にありません
というエラーがでます。
原因はわかっているのですが、それを回避する方法がわからないため
精通者にお尋ねしたく

[meg_]

コードは「コードの挿入」で記入されましたが、インデントがなく読みにくいままです。（私が修正依頼をしたのはコードを読みやすくして欲しかったからです）

> エラー内容ですがインデックスが有効範囲にありませんというエラーがでます。
質問に追記してください。

> 原因はわかっているのですが、それを回避する方法がわからないため
質問者さんが考えている”原因”についても質問に追記するべきです。

[KANNORYUJI]

泣きたくなってきました。どうやら場違いのところに来てしまいました。すみませんでした。

[meg_]

回答者は質問に書いてあることしか分かりません。回答するために必要なので質問や依頼をしています。（質問者さんと回答者ではOS、Excelのバージョン等環境も違うでしょうし、少しでも正確な回答をするための確認作業です）

[KANNORYUJI]

ありがとうございます。
私が求めていたことが出来ました。
今後は質問内容をもっと具体的かつ詳細に書くことに努めます。

[meg_]

hatena19さんの回答がシンプルで良いかもですね。

Answer 1

セル範囲のValueに配列を直接代入できます。

Sub Test1()
    Dim rr As Range
    Dim bb
    Range("C4") = "AA\BB\CC\DD"
    Range("C5") = "AA\BB\CC\DD\EE\FF\GG"
    Range("C6") = "AA\BB\CC\DD\EE\FF\GG\HH\RR\TT\YY"
    On Error Resume Next
    For Each rr In Range("C4:C6").Rows
        bb = Split(rr, "\")
        rr.Offset(, 4).Resize(, UBound(bb) + 1).Value = bb
    Next
End Sub

別案

リボンのデータ→データツール→区切り位置 コマンド(TextToColumnsメソッド)を使うと1行でできます。

Sub Macro1()
    Range("C4") = "AA\BB\CC\DD"
    Range("C5") = "AA\BB\CC\DD\EE\FF\GG"
    Range("C6") = "AA\BB\CC\DD\EE\FF\GG\HH\RR\TT\YY"

    Range("C4:C6").TextToColumns Destination:=Range("G4"), OtherChar:="\"
End Sub

Comments

[meg_]

色々な書き方があるのですね。勉強になります。

[KANNORYUJI]

なんと！　teratailへの質問投稿の凄さに今、天にも登る気持ちで感動しています。
エンジニア人生がかなりひらけてきた気がします。
これからもご教授いただきます。

[hatena19]

meg_さんの回答のコードが基本ですのでまずはこれを習得してから、他の方法(私の回答等)も覚えるのがいいと思います。
いろいろな手段をもっていると、場面に応じて最適な方法が選択できますので。

[KANNORYUJI]

はいアドバイスありがとうございます。
これからvbaを使って水準の高い仕事に集中できるように邁進します。

Answer 2

Sub Test()

    Dim rr As Range
    Dim bb
    Dim i As Integer
    Dim col As Integer
    
    
    Range("C4") = "AA\BB\CC\DD"
    Range("C5") = "AA\BB\CC\DD\EE\FF\GG"
    Range("C6") = "AA\BB\CC\DD\EE\FF\GG\HH\RR\TT\YY"
    
    For Each rr In Range("C4:C6").Rows
       bb = Split(rr, "\")
       col = 7
       For i = 0 To UBound(bb)
           Cells(rr.Row, col) = bb(i)
           col = col + 1
       Next i
    Next rr

End Sub

Comments

[KANNORYUJI]

ありがとうございます。For - Next関数の鍛錬中なのでこちらのコードが今は好きです。
想像力が養われるコードに感動しました。