VBAの継承後のセル挿入ができない

Question

いつもお世話になっております。

現在、VBAの課題に取り組んでおり、行き詰まっています
Excel for 2016を使用しています

問題
・ユーザーフォームに入力した値が、セルに繁栄されない

試したこと
・.Cellを使用すると挿入されるます(btnOk_Click)が、なぜ継承を使うと挿入できないのか？が疑問です

稚拙な質問かも知れませんが、ご存知の方がいらっしゃれば、ご教授願いたいです

下記の画像で、Add transactionをクリックすると、画像２のシートに保存されるようにしたいのですが、クリックしても何も起こりません。

Private Sub btnAddtransaction_Click()
Dim newTransaction As New transaction

newTransaction.TransactionDate = Now()

If (optCredit) Then
newTransaction.transactionType = Credit
End If
If (optDebit) Then
newTransaction.transactionType = Debit
End If

save newTransaction
newTransaction.CryptCurrency = cmBoxCurrency.Value
newTransaction.Quantity = txtboxQuantity.Value
newTransaction.ExchangeRate = txtboxExchangerate.Value

End Sub
Public Sub save(transaction As transaction)
Dim validator As New TransactionValidator
If (validator.isValid(transaction)) Then
Worksheets("TransactionHistory").Rows(2).Insert Shift:=xlDown

Sheets("TransactionHistory").Range("A2") = transaction.TransactionDate

If (transaction.transactionType = Credit) Then
Sheets("TransactionHistory").Range("B2") = "Credit"
Else
Sheets("TransactionHistory").Range("B2") = "Debit"
End If

Sheets("TransactionHistory").Range("C2") = transaction.CryptCurrency
Sheets("TransactionHistory").Range("D2") = transaction.Quantity
Sheets("TransactionHistory").Range("E2") = transaction.ExchangeRate
End If

End Sub


Private Sub btnOk_Click()
MsgBox "Test2"
Dim lastRow As Long
With Worksheets("TransactionHistory")
lastRow = .Cells(.Rows.Count, 1).End(xlUp).Row + 1
.Cells(lastRow, 1).Value = Me.txtboxQuantity
.Cells(lastRow, 2).Value = Me.cmBoxCurrency
.Cells(lastRow, 3).Value = Me.txtboxExchangerate
End With
Unload Me

End Sub

Public CryptCurrency As String
Public ExchangeRate As Double
Public Quantity As Double
Public TransactionDate As Date
Public transactionType As transactionType
 
Public Function tostring() As String
tostring = CryptCurrency & " " & transcriptionType & " " & "quantity: " & Quantity & "rate: " & ExchangeRate
End Function

Public Function isValid(transaction As transaction) As Boolean

If (transaction Is Nothing) Then
isValid = False
End If

If (transaction.Quantity <= 0) Then
isValid = False
End IF
If (transaction.CryptCurrency <= 0) Then
isValid = False
End If

End Function

Comments

[meg_]

> クリックしても何も起こりません。
デバッグはされましたか？

Answer 1

なぜ継承を使うと挿入できないのか？が疑問です

ど素人なので間違ってるかも知れませんが、こういうのは継承っていうのかなぁ？

.Cellを使用すると挿入されるます

「表にデータを挿入」という意味だと思いますが、
単に空白欄に記入ではないですか？
エクセルで挿入というと、少し違った意味になりますので、
混乱します。

で、本題。

Private Sub btnAddtransaction_Click()
Dim newTransaction As New transaction

↑ここがまずいです。
プロシージャの中で変数を宣言しているので、
他のプロシージャからその中身を参照できません。
いろんなプロシージャで使うなら、
宣言セクションで変数を宣言してください。

＜ユーザーフォームのモジュール＞

Option Explicit

Dim myClass As Class1

Private Sub UserForm_Initialize()
    Set myClass = New Class1
    myClass.Initialize ThisWorkbook.Worksheets(1).UsedRange
    With Me.ListBox1
        .ColumnCount = 5
        .ColumnWidths = "50;50;50;50;50"
        .ColumnHeads = True
    End With
    Me.CommandButton1.Enabled = False
    InputClear
End Sub

Private Sub OptionButton1_Change()
    If Not IsNull(Me.OptionButton1.Value) Then
        myClass.DeditCredit = IIf(Me.OptionButton1.Value, "Dedit", "Credit")
    End If
    InputCheck
End Sub

Private Sub ComboBox1_AfterUpdate()
    myClass.pCurrency = Me.ComboBox1.Value
    InputCheck
End Sub

Private Sub TextBox1_AfterUpdate()
    myClass.Quantity = Me.TextBox1.Value
    InputCheck
End Sub

Private Sub TextBox2_AfterUpdate()
    myClass.Rate = Me.TextBox2.Value
    InputCheck
End Sub

Private Sub CommandButton1_Click()
    With myClass
        .AddTransaction
        .Initialize ThisWorkbook.Worksheets(1).UsedRange
    End With
    InputClear
End Sub

Private Sub InputClear()
    Dim c As Control
    
    For Each c In Me.Controls
        Select Case TypeName(c)
        Case "ListBox": c.RowSource = myClass.DataBody.Address
        Case "OptionButton": c.Value = Null
        Case "TextBox": c.Value = ""
        Case "ComboBox": c.Value = ""
        End Select
    Next
    Me.CommandButton1.Enabled = False
End Sub

Private Function InputCheck() As Boolean
    Dim c As Control
    
    For Each c In Me.Controls
        Select Case TypeName(c)
        Case "OptionButton", "TextBox", "ComboBox"
            If IsNull(c.Value) Or Len(c.Value) = 0 Then Exit Function
        End Select
    Next
    Me.CommandButton1.Enabled = True
    InputCheck = True
End Function

＜クラスモジュール＞

Option Explicit

Private mDate As Date
Private mDeditCredit As Variant
Private mCurrency As Double
Private mQuantity As Double
Private mRate As Double
Private mTable As Range
Private mDataBody As Range
Private mNewData As Range

Public Property Let RegisteredDate(ByVal d As Date)
    mDate = d
End Property

Public Property Let DeditCredit(ByVal CorD As Variant)
    mDeditCredit = CorD
End Property

Public Property Let pCurrency(ByVal c As Double)
    mCurrency = c
End Property

Public Property Let Quantity(ByVal q As Double)
    mQuantity = q
End Property

Public Property Let Rate(ByVal r As Double)
    mRate = r
End Property

Public Property Get DataBody() As Range
    Set DataBody = mDataBody
End Property

Public Sub Initialize(ByRef Rng As Range)
    mDate = 0
    mDeditCredit = Empty
    mCurrency = 0
    mQuantity = 0
    mRate = 0
    
    With Rng
        Set mTable = .Cells
        Set mDataBody = Intersect(.Cells, .Offset(1))
        Set mNewData = .Rows(.Rows.Count + 1)
    End With
End Sub

Public Function AddTransaction() As Boolean
    Dim v As Variant
    mDate = Now()
    v = Array(mDate, mDeditCredit, mCurrency, mQuantity, mRate)
    mNewData.Value = v
    AddTransaction = True
End Function

クラスモジュールを普段使わないので、
勉強で書いてみました。拙いですが参考になれば。
（読み返すと個人的に不満が多々あるけど、突っ込んで勉強する時間がないので、ここまでにします）

でも、変数の置き場で使うだけなら、
ユーザーフォームのコントロールがすでに変数の変わりが出来ているので、
敢えてクラスモジュールを使うのは二度手間なきがします。

継承がテーマなら、
https://sites.google.com/site/compositiosystemae/home/vbaworld/upper/interface
こことか参考にならないですかね。。。。。

Answer 2

.Rangeに対して

.Range("B2") = "Credit"

各所この様に書かれていますが

.Range("B2").Value = "Credit"

ではないですか？