VBAで自動的に特定のフォルダに入っているmsgファイルやtxtファイルをPDF化する方法について

Question

現在aフォルダに以下の様なファイルが格納されています。
これがa-zフォルダまであるような状態で、pdfではないファイルをpdf化したうえで自動的にVBAで結合できないかと閑雅ております。

aフォルダ
hoge.pdf
piyo.txt
fuga.msg

利用しているAcrobatの契約:Acrobat 2017

PDFの結合自体はVBAでこちらのサイトを参考にして、技術的にできるのではないかと考えております。
※サイトの中ではAcrobat Proの契約が必要と書いてあったのですが、参照設定のライブラリでAcrobatにチェックを入れることができたので、いけると考えております。

一方で、msgやtxtファイルをpdf化する作業を自動化できないものかとGoogleで探しているのですが、それらしいものを見つけることができません。このような技術はvbaでは実現できないのでしょうか？方法をご存知の方がいればアドバイスを頂きたいです。

宜しくお願い申し上げます。

Answer 1

とりあえず変換する関数を作ってみました。
MSGファイルは、一旦HTML化したものをワークブックとして開きそれをPDFに変換しています。
TXTファイルは直接ワークブックとして開きPDFに変換しています。
ただTXTファイルは文字コードがSJIS限定です。
何かの設定でUNICODEにも対応できたと思うのですが失念しました。
思い出したら追記します。

Sub test()
    Call Msg2Pdf("aaa.msg", "aaa.pdf")
    Call Txt2Pdf("bbb.txt", "bbb.pdf")
End Sub

Sub Msg2Pdf(msgf As String, pdff As String)
   
    Dim ol As Outlook.Application
    Dim msg As Outlook.MailItem
    Dim wb As Workbook
    Dim htmlf As String
    
    htmlf = msgf & ".html"
    
    ' MSGファイルを開く
    Set ol = New Outlook.Application
    Set msg = ol.CreateItemFromTemplate(msgf)
    
    ' HTMLに変換
    msg.SaveAs htmlf, olHTML
    
    ' Outlook後始末
    msg.Close olDiscard
    Set msg = Nothing
    Set jol = Nothing
    
    ' HTMLファイルを開く
    Set wb = Workbooks.Open(htmlf)
    
    ' PDFに変換
    wb.ExportAsFixedFormat xlTypePDF, pdff
    wb.Close
    Set wb = Nothing
    
    ' HTMLファイル削除
    Kill htmlf

End Sub

Sub Txt2Pdf(txtf As String, pdff As String)
   
    Dim wb As Workbook
    
    ' TXTファイルを開く
    Set wb = Workbooks.Open(txtf)
    
    ' PDFに変換
    wb.ExportAsFixedFormat xlTypePDF, pdff
    wb.Close
    Set wb = Nothing
    
End Sub

Comments

[pegy]

コメントを頂き、誠にありがとうございます！
かなりの部分が解決しました。神・・・
重要な問題ではないのですが、例えばMsg2Pdfを実行した後に、同じディレクトリに
xxxx.msg.filesといったディレクトリが作られ、その中には
colorschememapping.xml
filelist.xml
themedata.thmx
にようなものができてしまうのですが、これは仕様でしょうか？

[ttyp03]

あぁ、そこまで確認してませんでした。申し訳ない。
HTML化することでファイルが作られてしまうのですね。
そのフォルダごと削除して構わないので、処理を追加してみてください。
ただフォルダ内にファイルがあると削除するのは面倒かもしれませんが。

[pegy]

承知を致しました、有難うございます！

Answer 2

こんにちは。

msgがどのようなファイルかわからないので出来るとは言い切れませんが。

WordVBAでファイルを開き、ExportAsFixedFormatでPDF指定すればよいのではないでしょうか？

参考：【コード】WordファイルをPDF形式で保存するWordマクロ

Comments

[pegy]

コメントありがとうございます。.msgはoutlookで、メールが保存される場合の拡張子です。リンクを見たのですが、ちょっとmsgからpdfには拡張子を返還すれば利用できるものではないので難しいかも知れません

[kay-ws]

ちょっとこちらの調べが足りないので申し訳ありませんが
・VBAでOutlookを操作して、.msgを、.rtfに変換して
・WordVBAで.rtfをPDFに変換する
ことが出来るかもしれません。

参考になりそうなサイト
https://detail.chiebukuro.yahoo.co.jp/qa/question_detail/q12169526712
https://tonari-it.com/vba-outlook-object/
https://outlooklab.wordpress.com/2019/07/20/
＃力技すぎる・・・

[kay-ws]

少し訂正：
（訂正前）WordVBAで.rtfをPDFに変換する
（訂正後）VBAでWordを操作して.rtfをPDFに変換する