UBound関数で-1が出力される

Question

学習目的です。解説をお願いしたいです。

予想ではhairetu(3)(0)に改行（目には見えませんが）が入っていると思ったのですがエラーになりました。
UBound関数で確認すると-1が出力されます。UBound関数は最大のインデックス番号を出力すると思うのですが、-1はどういった意味なのでしょうか？
また、hairetu(3)(0)に改行（もしくは改行コードvbCrLf）を格納するにはどのような方法がありますか？

Dim hairetu
hairetu = csvHairetuKakunou("test.csv")　'csvからジャグ配列に格納
msgbox UBound(hairetu(3)) '-1と表示される

msgbox hairetu(1)(2) '12と表示される
'msgbox hairetu(3)(0) 'インデックスが有効範囲にありません。とエラーになる
'msgbox hairetu(-1)(0) 'インデックスが有効範囲にありません。とエラーになる

下記でcsvファイルから配列に格納します。

Function csvHairetuKakunou(inFile) '戻り値にジャグ配列
'csv形式のファイルジャグ配列に格納する。,区切り
	'inFile:ファイルのパス
	Dim fso 'ファイルを操作する準備
	Set fso = WScript.CreateObject("Scripting.FileSystemObject")
	Dim inputFile
	Set inputFile = fso.OpenTextFile(inFile, 1, False) '読み取り専用でファイルを開く。
	Dim Arr() 'データを格納する配列
	Dim dataLine '一行のデータを一時的に入れる変数
	Dim i 'ループ変数
	i = 0
	Do Until inputFile.AtEndOfStream 'ファイルの終端になるまで繰り返し
		dataLine = inputFile.ReadLine 'ファイルを1行読み込んで次の行の先頭にポインタを移動。
		Redim Preserve strArr(i) '動的配列の格納データを保持したまま最大インデックスiに変更
		strArr(i) = Split(dataLine, ",") 'Split(文字列,区切り文字)文字列を区切り文字ごとに配列に格納する
		i = i + 1
	Loop
	csvHairetuKakunou = strArr
End Function

00,01,02,03
10,11,12,13,14
20,21,22,23

40,41,42,43
50,51,52,53,54

上記test.csvファイル内です。間が空いてる部分は何もない改行です。

Answer 1

他の回答のまとめみたいになってしまいますが。。。

-1は要素がない場合の戻り値です。
なぜ-1になるかというとReadLineは改行コードを含まず読み込むからです。
公式マニュアル

また、hairetu(3)(0)に改行（もしくは改行コードvbCrLf）を格納するにはどのような方法がありますか？

前述通りReadLineは改行コードを含みません。
よって空行ではない行の最終列は改行コードを含んでいません。
空行の時だけ改行コードのデータを作るのは、他の行とデータ構成が違ってしまいます。
改行コードのデータを作るのではなく、空要素のまま処理するか、空文字のデータ作る方が望ましいかと思います。

Comments

[ka999]

＞なぜ-1になるかというとReadLineは改行コードを含まず読み込むからです。
すごく納得です。
＞他の行とデータ構成が違ってしまいます。
というのは、改行コードの種類が変わるってことですか？vbCrLf、vbCr、vbLfのような？もしくは別の何かがありますか？

[ttyp03]

いえ、違います。
データがある行には改行コードがつきません。
それなのにあえて改行コードを埋め込むと、データがある行と整合性が取れなくなるということです。

[ttyp03]

ちょっと誤解される書き方だったので訂正。
X データがある行には改行コードがつきません。
O ReadLineでの読み込みには改行コードがつきません。

[ka999]

回答ありがとうございました。
空要素のまま処理する方向をメインに試してみようと思います。

Answer 2

UBound が -1 を返すということは配列に要素がない（要素数0）という意味だと思います。

hairetu(3) はCSVの4行目なので、空文字列なので要素数0になります。

Split("",",")は要素数0の配列になります。

下記のコードを試してみてください。意味が分かると思います。

ary1 = Split("",",")
MsgBox UBound(ary1) '-1 要素数0の配列

ary2 = Split(" ",",")
MsgBox UBound(ary2) '0 要素数1の配列

str = ""
MsgBox UBound(str) '配列でないので型が違うというエラー

hairetu(3)(0)に改行（もしくは改行コードvbCrLf）を格納するにはどのような方法がありますか？

'前略

        dataLine = inputFile.ReadLine
        If dataLine = "" Then dataLine = vbCrLf
        Redim Preserve strArr(i)
        strArr(i) = Split(dataLine, ",") 
        i = i + 1

'後略

ttyp03さんの回答にあるようにこの行だけ改行コードを入れるのは、他の行との整合性がとれないので、あまりよくないですね。
要素数0のままにしておくか、空文字列の配列を格納するようにしたほうがいいですね。

'前略

        dataLine = inputFile.ReadLine
        Redim Preserve strArr(i)
        If dataLine = "" Then
            strArr(i) = Array("") 
        ELse 
            strArr(i) = Split(dataLine, ",") 
        End if
        i = i + 1
'後略

Comments

[ka999]

回答ありがとうございます。
要素ゼロの時に-1よくわかりました。

[radames1000]

内容については異論ないのですが最初のvbsの誤記だけ
MsbBox⇒MsgBox
最後のUBound(ary2)はUBound(str)だと思います。

[hatena19]

あ、ミスってますね（汗）
ご指摘ありがとうございます。
修正して置きます。

[ka999]

わかりやすく、丁寧に解説していただけていたのでベストアンサーにさせていただきます。また、ほかの方の回答、コメントも合わせて参考にさせていただきます。

Answer 3

ここは

msgbox UBound(hairetu(3)) '-1と表示される

こうだと思います。

msgbox UBound(hairetu)

Uboundは要素がなければ-1を返すはずです。
参考になるところを探そうと思いましたが本日は時間切れです。
⇒他の方が詳しく書かれていますのでそちらをご確認ください。

Comments

[ka999]

回答ありがとうございます。
```VBScript
msgbox UBound(hairetu) '5と表示される
```
表示されるのは５でした。今回の例だとtest.csvの縦の最大インデックス番号の5が表示されていると考えています。
よろしければ、test.csvの間の空いた部分を指す(のかな？)、-1の意味を解説していただきたいです。よろしくお願いします。

[ka999]

追記ありがとうございます。
＞Uboundは要素がなければ-1を返すはずです。
とのことでこちらでももう少し調べてみます。