EXCEL VBAからWordPressのRESTAPIを使用して投稿したい

Question

前提・実現したいこと

EXCEL VBAのVBAを使用してWordPressのRESTAPIにアクセスして、更新をしたいと思います。

認証まではできたのですが、
JSONリクエストを送信しているのですが、エラーコードを見ている限り、
「コンテンツがない」
と言われうまく送信できません

発生している問題・エラーメッセージ

{"code":"empty_content","message":"\u672c\u6587\u3001\u30bf\u30a4\u30c8\u30eb\u3001\u629c\u7c8b\u304c\u7a7a\u6b04\u3067\u3059\u3002","data":{"status":400}}

{"code":"empty_content","message":"本文、タイトル、抜粋が空欄です。","data":{"status":400}}

該当のソースコード

Sub HTTPリクエスト()


  URL = "https://＊＊＊＊＊＊＊＊.jp/wp-json/wp/v2/posts/"
  UserName = "＊＊＊＊＊"
  pass = "＊＊＊＊＊"
  
  Status = "draft"

   method = "POST"

   Title = "test"
   Content = "texttext"

'JSON作成

    Dim JsonObject As Object
    Set JsonObject = New Dictionary

    Dim Header As String
    Header = UserName + ":" + pass
    Header = "Basic " & EncodeToBase64(Header)


    JsonObject.Add "method", method
    
    JsonObject.Add "body", New Dictionary
        JsonObject("body").Add "title", Title
        JsonObject("body").Add "content", Content
        JsonObject("body").Add "status", Status
        
    JsonObject.Add "muteHttpExceptions", True

 ' イミディエイトウィンドウで確認（デバック用）
Debug.Print JsonConverter.ConvertToJson(JsonObject, Whitespace:=2)




Dim objHTTP As Object
Set objHTTP = CreateObject("msxml2.xmlhttp")

    objHTTP.Open "POST", URL, False
    objHTTP.setRequestHeader "Authorization", Header
    objHTTP.setRequestHeader "Content-Type", "text/plain"
    objHTTP.send JsonConverter.ConvertToJson(JsonObject)


Debug.Print objHTTP.responseText
' レスポンスコード（正常）
If objHTTP.Status = 200 Then
    MsgBox "正常に終了しました"
End If


End Sub

Public Function EncodeToBase64(ByRef text As String) As String
 
    ' オブジェクトの準備
    Dim node As Object
    Set node = CreateObject("Msxml2.DOMDocument.3.0").createElement("base64")
 
    ' エンコード
    node.DataType = "bin.base64"
    node.nodeTypedValue = ConvertToBinary(text)
 
    ' 関数で取り除けない改行を削除して返却
    EncodeToBase64 = Replace(node.text, vbLf, "")
End Function
 
' *==============================================================
' * 文字列をバイナリデータに変換します
' *
' * @param text 変換する値
' * @return バイナリデータ
' *==============================================================
Public Function ConvertToBinary(ByRef text As String)
 
    ' オブジェクトの準備
    Dim BinaryStream As Object
    Set BinaryStream = CreateObject("ADODB.Stream")
 
    ' Streamの設定
    With BinaryStream
        .Type = 2
        .Charset = "us-ascii"
        .Open
        .WriteText text
        .Position = 0
        .Type = 1
        .Position = 0
    End With
 
    ConvertToBinary = BinaryStream.Read
End Function

###送信しているJson (JsonObject の中身)

{
  "method": "POST",
  "body": {
    "title": "test",
    "content": "texttext",
    "status": "draft"
  },
  "muteHttpExceptions": true
}

試したこと

元は
GASから更新しておりこちらを参考にEXCELで作成しました
https://teratail.com/questions/211650

補足情報（FW/ツールのバージョンなど）

参考にしました。
WordPressRESTAPI認証

https://ja.wp-api.org/guide/authentication/
EXCEL(VBA)から、JSONデータをHTTP送信してみよう。
https://doruby.jp/users/ookouchi/entries/201708-EXCEL-VBA-JSON-API-MSXML2-XMLHTTP
【参照設定不要】Base64フォーマットにエンコードする
https://localbias.work/796

Comments

[CHERRY]

JSON データの構造の問題と思いますが、送信している組み立て済みのJSON データを質問に追記することは可能でしょうか？

[so_chan]

ありがとうございます。追記させていただきました。

[kuma_kuma_]

WordPressでREST APIを利用して自動投稿を行う
https://ichiro-kun.com/post/1088/
こちらの情報ですが

objHTTP.setRequestHeader "Content-Type", "application/json"
で試してみて下さい。

あと気になったのが"us-ascii"の指定
WordPressは"utf-8"だと思いますが、もし日本語が文字化けするようでしたら変更してみて下さい。

[so_chan]

ご指摘の修正とJsonの形式が誤っていたので修正したら無事に投稿できました！ありがとうございます！

Answer 1

送信するJsonを作成するときのコードを修正

    JsonObject.Add "method", method
    JsonObject.Add "title", Title
    JsonObject.Add "content", Content
    JsonObject.Add "status", Status

ヘッダーを修正

修正前

    objHTTP.setRequestHeader "Content-Type", "text/plain"

修正後

    objHTTP.setRequestHeader "Content-Type", "application/json"