共有ブックに新規データ行をかぶらないように追加したい

Question

Excelで、共有したブックに複数で書き込みをしています。IDで管理していて、既存のIDがあるときはフォームにそのデータを表示して、参照または修正して保存しています。
しかし、新規データ行が発生した場合には最終行の取合いになり、競合して上書きされることがあるようです。運用上フォームは立ち上げっぱなしの場合が多く、新規データ行が発生した時にはブックを(保存せずに)強制的に終了させて、手動でもう一度立ち上げて最新のブックに新規データを書込んでもらっているのが現状です。新規データが発生した時に１箇所の書込みは1人しかできないようするのに、もっと良い方法はないでしょうか。

Answer 1

(1) プログラムファイルが存在するフォルダに、次のテキストファイルを作成します。
RowNum.txt
このテキストファイルに、共有ブックの最終行の行番号を７桁で１行だけ登録しておきます。

(2) 次のプロシジャを標準モジュールに登録します。

Function f_lngGetRowNum() As Long
On Error GoTo f_lngGetRowNum_Err
      
    Dim lngGetRowNum As Long
    Dim strFileName As String
    Dim intFileNum As Integer
    Dim strRowNum As String * 7
    
    strFileName = ThisWorkbook.Path & "\RowNum.txt"
    intFileNum = FreeFile
    
    Open strFileName For Binary Lock Read Write As #intFileNum
    Get #intFileNum, 1, strRowNum
    
    lngGetRowNum = CLng(strRowNum) + 1
    strRowNum = Format(lngGetRowNum, String(7, "0"))
    
    Put #intFileNum, 1, strRowNum
    Close #intFileNum

    f_lngGetRowNum = lngGetRowNum


f_lngGetRowNum_Exit:
    Exit Function

f_lngGetRowNum_Err:
    f_lngGetRowNum = 0
    Resume f_lngGetRowNum_Exit

End Function

このプロシジャは、RowNum.txtを排他的に開き、中の７桁の数字に１を加えて更新します。
戻り値は、その１を加えた値です。
でも、RowNum.txtが別プロセスで開かれていると、更新せずに０を返します。

(3) 新規データが発生した場合には、上記プロシジャで、その新規データを書き込むべき行番号を取得します。
０が返ってきたときは、ユーザーに少し待つよう促します。

以上でいかがでしょうか。

Comments

[yoko4401]

ありがとうございます!
新規IDを別ファイルに一時保存して再起動をかけることは思いついたのですが、再起動のロスタイムが不評で、直接シートに書き込む輩が出る始末でした。最終行を別に管理する事は思いつきませんでした。
やってみます!ありがとうございます。